Documents created by any of the iWork applications, Pages, Numbers, or Keynote, can incorporate a common set of elements, including images, shapes, lines, tables, charts, movies, and audio clips. To AppleScript and the built-in scripting support of the iWork applications, these elements are considered iWork Items, and share a common set of properties, detailed in the iWork Item class from the iWork Suite:

The iWork Suite iWork item Class

The properties in the iWork item class can be accessed and changed for any of the common iWork elements. For example, a script can get or set the position of a movie, or image, or shape, or any of the common elements.

In addition to sharing a common set of properties with the other iWork elements, each iWork element has its own set of properties, particular to that element. For example, the element-specific properties of an image are detailed in its dictionary listing, found in the iWork Suite:  (⬇ see below ) 

The iWork Suite image Class

Images are added to to the page of a document using the make command and the image file property. By default, Pages will wrap the image container to fit the added image, and then scale the image to be centered in the section of the page currently displayed in the document window.

DO THIS ►DOWNLOAD and unpack the ZIP archive containing the example images. Place the folder containing the images in your Pictures folder.

The following script example creates a photo book using selected image files. The script:

• prompts the user to select a group of image files with landscape orientation to import.
• imports each image file to its own page, centering the image file on the page.
• extracts the caption metadata from the image on places it in a newly created text item, overlaid on a translucent shape at the bottom of the image.

Simple Photo Book
Open in AppleScript Editor
01		property templateName : "Photo Card Horizontal"
02		property templateWidth : 792
03		property templateHeight : 612
04		property defaultMargin : 36
05		property textItemInset : 12
06		property defaultTypeFace : "Verdana"
07		property defaultTypeSize : 10
08
09		tell application "Pages"
10		activate
11
12		-- promput user for images
13		set theseImages to ¬
14		(choose file with prompt "Select the images to import:" with multiple selections allowed )
15
16		-- make a new page layout document
17		set thisDocument to make new document with properties ¬
18		{document template:template templateName}
19
20		tell thisDocument
21		-- delete the default template items
22		set locked of every iWork item to false
23		delete every iWork item
24
25		-- add the images to the document, each on its own page
26		repeat with i from 1 to the count of theseImages
27		set thisImageFile to item i of theseImages
28		-- extract any embedded caption metadata from the image file
29		set thisImageDescription to my extractkMDItemDescription(thisImageFile)
30		-- make a new page if needed
31		if i is not 1 then make new page
32		tell current page
33		-- import the image
34		set thisImage to make new image with properties {file:thisImageFile}
35		-- center the image on the page
36		tell thisImage
37		copy {width of it, height of it} to {imageWidth, imageHieght}
38		set its width to (templateWidth - (defaultMargin * 2))
39		copy {width of it, height of it} to {imageWidth, imageHieght}
40		set its position to ¬
41		{(templateWidth - imageWidth) div 2, (templateHeight - imageHieght) div 2}
42		end tell
43		-- if there is an image description, place over opaque background overlay
44		if thisImageDescription is not "" then
45		set thisShape to make new shape with properties ¬
46		{width:(templateWidth - (4 * defaultMargin)) ¬
47		, height:90 ¬
48		, position:{(2 * defaultMargin) ¬
49		, (templateHeight - (4 * defaultMargin))} ¬
50		, opacity:40}
51		tell thisShape
52		copy {width of it, height of it} to {shapeWidth, shapeHeight}
53		copy its position to {shapeHorizontalOffset, shapeVerticalOffset}
54		end tell
55		set thisTextItem to make new text item with properties ¬
56		{object text:thisImageDescription ¬
57		, width:(shapeWidth - (2 * textItemInset)) ¬
58		, height:(shapeHeight - (2 * textItemInset)) ¬
59		, position:{shapeHorizontalOffset + textItemInset ¬
60		, shapeVerticalOffset + textItemInset}}
61		tell object text of thisTextItem
62		set font to defaultTypeFace
63		set size to defaultTypeSize
64		set color of it to "white"
65		end tell
66		end if
67		end tell
68		end repeat
69		end tell
70		end tell
71
72		on extractkMDItemDescription(thisImageFile)
73		-- use Spotlight to extract embedded metadata
74		try
75		set thisImagePOSIXpath to the POSIX path of thisImageFile
76		set the embeddedDescription to ¬
77		do shell script "mdls -name kMDItemDescription " & ¬
78		(quoted form of thisImagePOSIXpath)
79		if embeddedDescription is "kMDItemDescription = (null)" then
80		set embeddedDescription to ""
81		else
82		set the embeddedDescription to ¬
83		(text from ((length of "kMDItemDescription = \"") + 1) to ¬
84		-2 of embeddedDescription)
85		end if
86		return embeddedDescription
87		on error
88		return ""
89		end try
90		end extractkMDItemDescription