AppleScript and Pages: Exporting Documents

Exporting Documents

Exporting Pages documents is done using the export command from the Pages Suite.

export v : Export a presentation to another file(s).

export document : The presentation to export.

to (file ) : A reference to the file to be created.

as ( epub / ‌Microsoft Word /‌ Pages 09 /‌ PDF /‌ unformatted text ) : The format in which the document is to be exported.

[ with properties (export options ) ] : An AppleScript record containing property:value pairings for the initial values for properties of the exported object.

export options n : The export options for the Pages export command.

properties

author ( text ) : The author of the exported EPUB document.

cover ( boolean ) : Should the first page be used as the cover for the exported EPUB document?

genre ( text ) : (Pages 5.6) The genre of the exported EPUB document.

language ( text ) : (Pages 5.6) The language name or ISO language code of the exported EPUB document. For ISO language codes, see Code List of ISO 639-2.

publisher ( text ) : (Pages 5.6) The publisher of the exported EPUB document.

title ( text ) : The title of the exported EUPB document.

image quality ( good/better/best ) : (Pages 5.6) The quality setting to apply to the images contained in the exported document.

password ( text ) : The password to use when the exported PDF is encrypted.

password hint ( text ) : The password hint.

NOTE: The Pages version 5.6 scripting dictionary includes enhanced metadata options for EPUB documents, as well as image compression options for images placed within the exported document.

Export Scripts

The following are script examples for each of the following export types:

Export to EPUB, Export to PDF, Export to Microsoft Word, Export to Unformatted Text

DO THIS ►DOWNLOAD a ZIP archive containing two Pages documents to use for testing the export command. Included in the archive are completed versions of Alice in Wonderland and the United States Constitution.

Export to PDF

This script movies the frontmost Pages presentation to a PDF file. Set the boolean value of the useEncryptionDefaultValue property to either true or false to determine whether you will be prompted for the password to use in encrypting the PDF file.

Export to PDF

property exportFileExtension : "pdf"

property useEncryptionDefaultValue : true

-- THE DESTINATION FOLDER

-- (see the "path" to command in the Standard Additions dictionary for other locations, such as movies folder, pictures folder, desktop folder)

set the defaultDestinationFolder to (path to documents folder)

set usePDFEncryption to useEncryptionDefaultValue

tell application "Pages"

activate

try

if not (exists document 1) then error number -128

if usePDFEncryption is true then

-- PROMPT FOR PASSWORD (OPTIONAL)

repeat

display dialog "Enter a password for the PDF file:" default answer ¬

"" buttons {"Cancel", "No Password", "OK"} ¬

default button 3 with hidden answer

copy the result to ¬

{button returned:buttonPressed, text returned:firstPassword}

if buttonPressed is "No Password" then

set usePDFEncryption to false

exit repeat

else

display dialog "Enter the password again:" default answer ¬

"" buttons {"Cancel", "No Password", "OK"} ¬

default button 3 with hidden answer

copy the result to ¬

{button returned:buttonPressed, text returned:secondPassword}

if buttonPressed is "No Password" then

set usePDFEncryption to false

exit repeat

else

if firstPassword is not secondPassword then

display dialog "Passwords do no match." buttons ¬

{"Cancel", "Try Again"} default button 2

else

set providedPassword to the firstPassword

set usePDFEncryption to true

exit repeat

end if

end repeat

end if

-- DERIVE NAME AND FILE PATH FOR NEW EXPORT FILE

set documentName to the name of the front document

if documentName ends with ".pages" then ¬

set documentName to text 1 thru -7 of documentName

tell application "Finder"

set exportItemFileName to documentName & "." & exportFileExtension

set incrementIndex to 1

repeat until not (exists document file exportItemFileName of defaultDestinationFolder)

set exportItemFileName to ¬

documentName & "-" & (incrementIndex as string) & "." & exportFileExtension

set incrementIndex to incrementIndex + 1

end repeat

end tell

set the targetFileHFSpath to (defaultDestinationFolder as string) & exportItemFileName

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

if usePDFEncryption is true then

export front document to file targetFileHFSpath ¬

as PDF with properties {password:providedPassword}

else

export front document to file targetFileHFSpath as PDF

end if

end timeout

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert "EXPORT PROBLEM" message errorMessage

end if

error number -128

end try

end tell

-- SHOW THE NEW PDF FILE

tell application "Finder"

activate

reveal document file targetFileHFSpath

end tell

Export to Microsoft Word

This script movies the frontmost Pages presentation to a Microsoft Word file.

Export to Microsoft Word

property exportFileExtension : "doc" -- docx

-- THE DESTINATION FOLDER

-- (see the "path" to command in the Standard Additions dictionary for other locations, such as movies folder, pictures folder, desktop folder)

set the defaultDestinationFolder to (path to documents folder)

tell application "Pages"

activate

try

if not (exists document 1) then error number -128

-- DERIVE NAME AND FILE PATH FOR NEW EXPORT FILE

set documentName to the name of the front document

if documentName ends with ".pages" then ¬

set documentName to text 1 thru -7 of documentName

tell application "Finder"

set newExportFileName to documentName & "." & exportFileExtension

set incrementIndex to 1

repeat until not (exists document file newExportFileName of defaultDestinationFolder)

set newExportFileName to ¬

documentName & "-" & (incrementIndex as string) & "." & exportFileExtension

set incrementIndex to incrementIndex + 1

end repeat

end tell

set the targetFileHFSpath to (defaultDestinationFolder as string) & newExportFileName

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

export front document to file targetFileHFSpath as Microsoft Word

end timeout

on error errorMessage number errorNumber

display alert "EXPORT PROBLEM" message errorMessage

error number -128

end try

end tell

-- SHOW THE NEW EXPORT FILE

tell application "Finder"

activate

reveal document file targetFileHFSpath

end tell

Export to EPUB

This script movies the frontmost Pages presentation to an EPUB file and opens the exported document with the iBooks application.

Export to EPUB

property exportFileExtension : "epub"

-- THE DESTINATION FOLDER

-- (see the "path to" command in the Standard Additions dictionary for other locations, such as movies folder, pictures folder, desktop folder)

set the defaultDestinationFolder to (path to documents folder)

tell application "Pages"

activate

try

if not (exists document 1) then error number -128

-- GET DOCUMENT NAME

set documentName to the name of the front document

if documentName ends with ".pages" then ¬

set documentName to text 1 thru -7 of documentName

-- PROMPT FOR TITLE

repeat

display dialog "Enter the title for the publication:" default answer documentName

set thisTitle to the text returned of the result

if thisTitle is not "" then exit repeat

end repeat

-- PROMPT FOR AUTHOR

repeat

display dialog "Enter the author for the publication:" default answer ""

set thisAuthor to the text returned of the result

if thisAuthor is not "" then exit repeat

end repeat

-- DETERMINE COVER

display dialog "Should the created publication use this document’s first page as a cover?" buttons ¬

{"Cancel", "No", "Yes"} default button 3

set useFirstPageForCover to the button returned of the result as boolean

-- DETERMINE FILENAME

tell application "Finder"

set newExportFileName to documentName & "." & exportFileExtension

set incrementIndex to 1

repeat until not (exists document file newExportFileName of defaultDestinationFolder)

set newExportFileName to ¬

documentName & "-" & (incrementIndex as string) & "." & exportFileExtension

set incrementIndex to incrementIndex + 1

end repeat

end tell

set the targetFileHFSpath to (defaultDestinationFolder as string) & newExportFileName

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

export front document to file targetFileHFSpath as epub ¬

with properties {title:thisTitle, author:thisAuthor, cover:useFirstPageForCover}

end timeout

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert "EXPORT PROBLEM" message errorMessage

end if

error number -128

end try

end tell

-- OPEN THE NEW EXPORT FILE

tell application "iBooks"

activate

open file targetFileHFSpath

end tell

Export to Unformatted Text

This script movies the frontmost Pages presentation to a text file.

Export to Text File

property exportFileExtension : "txt" -- text

-- THE DESTINATION FOLDER

-- (see the "path" to command in the Standard Additions dictionary for other locations, such as movies folder, pictures folder, desktop folder)

set the defaultDestinationFolder to (path to documents folder)

tell application "Pages"

activate

try

if not (exists document 1) then error number -128

-- DERIVE NAME AND FILE PATH FOR NEW EXPORT FILE

set documentName to the name of the front document

if documentName ends with ".pages" then ¬

set documentName to text 1 thru -7 of documentName

tell application "Finder"

set newExportFileName to documentName & "." & exportFileExtension

set incrementIndex to 1

repeat until not (exists document file newExportFileName of defaultDestinationFolder)

set newExportFileName to ¬

documentName & "-" & (incrementIndex as string) & "." & exportFileExtension

set incrementIndex to incrementIndex + 1

end repeat

end tell

set the targetFileHFSpath to (defaultDestinationFolder as string) & newExportFileName

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

export front document to file targetFileHFSpath as unformatted text

end timeout

on error errorMessage number errorNumber

display alert "EXPORT PROBLEM" message errorMessage

error number -128

end try

end tell

-- SHOW THE NEW EXPORT FILE

tell application "Finder"

activate

reveal document file targetFileHFSpath

end tell

TOP | CONTINUE

PAGES SCRIPTING

EXPORT TO PDF DROPLET

DOWNLOAD an example AppleScript droplet that will export dragged-on Pages documents to PDF files placed in the same folder as the Pages source files.

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.