A fundamental benefit of automation is found in its ability to perform a series of intricate procedures over and over, quickly but with precision. Take for example the task of combining a dozen files, perhaps chapters of a book, into a single document, with the contents of each file occupying its own section in the new document. If done by hand, this process could take 15 minutes, but when done with a script, it takes only seconds. That’s why professionals rank automation as such a high priority.

As a demonstration, here’s an AppleScript script for importing a set of chosen text files into a new document, with each imported file flowing into its own section.

Follow these steps:

DO THIS ►DOWNLOAD a ZIP archive containing the text of Alice in Wonderland divided into group of individual chapter files.

(A special “thank you” to Project Gutenberg for making this content available to the public!)

DO THIS ►Open the script into the Script Editor application by clicking the button at the top of the script segment at the bottom of this page:  (⬇ see below ) 

FYI: Click HERE for instructions on how to save scripts for use with the system-wide Script Menu.

DO THIS ►Run the script and a file chooser dialog will appear  (⬇ see below )  Select the text files you wish to import and click the Choose button to continue:

DO THIS ►A second dialog is displayed  (⬇ see below )  asking if you would like to manually indicate the import order for the selected files, or use the order displayed in the previous choosing dialog. For the purposes of this tutorial, click the Yes button.

DO THIS ►Since you indicated that a manual sort process was desired, a list dialog displaying the names of selected files, appears  (⬇ see below ) 

Double-click the name of the first file to import (CHAPTER I. Down the Rabbit-Hole.txt). The list will reappear, prompting you to choose the second file to import (CHAPTER II. The Pool of Tears.txt). This process continues until you’ve indicated the import order for all of the files.

TIP: For those who can’t remember the Roman Numerals for 1 through 12, they are: I, II, III, IV, V, VI, VII, VIII, IX, X, XI, XII

The script will create a new blank document and import each of the chosen files into its own section.  (⬇ see below ) 

Here’s the script:

Import Multiple Text Files
Open in AppleScript Editor
01		property defaultTemplateName : "Blank"
02
03		tell application "Pages"
04		activate
05		set chosenFiles to ¬
06		(choose file of type {"public.plain-text"} ¬
07		with prompt "Choose the text files to import:" with multiple selections allowed)
08
09		display dialog "Do you want to indicate the import order for the chosen files?" buttons ¬
10		{"Cancel", "No", "Yes"} default button 3 with icon 1
11		set performManualSort to the button returned of the result
12
13		if performManualSort is "Yes" then
14		set the fileCount to the count of chosenFiles
15		set theseFileNames to {}
16		repeat with i from 1 to the fileCount
17		set thisFile to item i of chosenFiles
18		set the end of theseFileNames to my fileNameFromAliasReference(thisFile)
19		end repeat
20		set the sourceList to chosenFiles
21		set the sortedList to {}
22		set theseDisplayNames to theseFileNames
23		repeat with i from 1 to fileCount
24		if i is fileCount then
25		set chosenFileName to theseDisplayNames -- one item left
26		else
27		set thisFileIndexString to my addOrdinalSuffix(i)
28		set chosenFileName to ¬
29		(choose from list theseDisplayNames with prompt ¬
30		"Double-click the " & thisFileIndexString & " file to import:")
31		end if
32		if chosenFileName is false then
33		error number -128
34		else
35		set chosenFileName to chosenFileName as string
36		end if
37		repeat with z from 1 to count of theseFileNames
38		if chosenFileName is item z of theseFileNames then
39		set the end of the sortedList to item z of chosenFiles
40		exit repeat
41		end if
42		end repeat
43		set theseDisplayNames to my removeItemFromList(theseDisplayNames, chosenFileName)
44		end repeat
45		set theseFiles to sortedList
46		else
47		set theseFiles to chosenFiles
48		end if
49
50		set thisDocument to ¬
51		make new document with properties ¬
52		{document template:template defaultTemplateName}
53
54		tell thisDocument
55		if document body is false then
56		display alert "INCOMPATIBLE TEMPLATE" message ¬
57		"The created document does not have a document body text flow." & ¬
58		return & return & "Choose a template that has a body text flow."
59		error number -128
60		end if
61
62		repeat with i from 1 to the count of theseFiles
63		if i is 1 then
64		set body text to (read (item i of theseFiles))
65		else
66		make new section
67		set body text of last section to (read (item i of theseFiles))
68		end if
69		end repeat
70		end tell
71
72		display notification "Import completed."
73		end tell
74
75		on fileNameFromAliasReference(thisFileAliasReference)
76		set AppleScript's text item delimiters to ":"
77		set thisFileName to the last text item of (thisFileAliasReference as string)
78		set AppleScript's text item delimiters to ""
79		return thisFileName
80		end fileNameFromAliasReference
81
82		on removeItemFromList(sourceList, targetItem)
83		set newList to {}
84		repeat with i from 1 to the count of sourceList
85		set thisItem to item i of sourceList
86		if thisItem is not targetItem then
87		set the end of newList to (item i of sourceList)
88		end if
89		end repeat
90		return newList
91		end removeItemFromList
92
93		on addOrdinalSuffix(thisInteger)
94		set thisInteger to thisInteger as integer as string
95		if thisInteger ends with "11" or ¬
96		thisInteger ends with "12" or ¬
97		thisInteger ends with "13" then
98		set the listIndex to 1
99		else
100		set the listIndex to (thisInteger mod 10) + 1
101		end if
102		set the ordinalSuffix to item listIndex of ¬
103		{"th", "st", "nd", "rd", "th", "th", "th", "th", "th", "th"}
104		return (thisInteger & ordinalSuffix)
105		end addOrdinalSuffix