AppleScript and Pages: Replacing Text Placeholders in Object Text

Replacing Text Placeholders in Object Text

AppleScript can be used to automate the task of locating and replacing text placeholders in text item containers. The following script demonstrates how a Pages template containing text placeholders can be quickly populated using automation and direct interaction with the script user.

NOTE: The following script also demonstrates how placeholder images are replaced with the content image files by changing the value of the file name property of an image.

This script acts as a production assistant by creating a filled-in document based upon a Pages template (in this example a tabbed flyer), after prompting the script user individually for key data elements to be used in the document creation. The script then automatically locates and replaces text and image placeholders with the provided references, greatly reducing the time required to finish the document.

Production Assistant

tell application "Pages"

activate

display dialog "This script will create a new tab flyer document based upon the information you supply." with icon 1

-- USER PROMPTS

-- IMAGE

set the replacementImageFile to ¬

(choose file of type "public.image" default location ¬

(path to pictures folder) with prompt "Choose the image file of the item to sell:")

-- ITEM KIND

repeat

display dialog "Enter a single word describing the kind of item to be sold:" default answer "Object"

set replacementItemKind to the text returned of the result

if replacementItemKind is not "" then exit repeat

end repeat

-- PHONE

repeat

display dialog "Enter the phone number (with area code) customers should call:" default answer "(555) 555-5555"

set replacementPhoneNumber to the text returned of the result

if replacementPhoneNumber is not "" then exit repeat

end repeat

-- ITEM PRICE

repeat

display dialog "Enter the price of item to be sold (include currency character):" default answer "$500"

set replacementSalePrice to the text returned of the result

if replacementSalePrice is not "" then exit repeat

end repeat

-- MAKE DOCUMENT USING TEMPLATE

set thisDocument to ¬

make new document with properties {document template:template "Tab Flyer"}

tell thisDocument

-- REPLACE IMAGE

set thisPlaceholderImage to the first image

set the file name of thisPlaceholderImage to replacementImageFile

-- REPLACE PHONE NUMBER

set placeholderPhoneNumber to "(123) 456-7890"

set theseTextItems to ¬

every text item whose object text contains placeholderPhoneNumber

repeat with i from 1 to the count of theseTextItems

set thisTextItem to item i of theseTextItems

tell thisTextItem

tell its object text

set (every paragraph where it is placeholderPhoneNumber) to ¬

replacementPhoneNumber

end tell

end repeat

-- ITEM NAME

set placeholderKind to "Bike"

-- banner with price

set thisTextItem to ¬

the first text item whose object text contains "Custom Fixie Bike"

tell thisTextItem

tell its object text

-- replace the text placeholders. TIP: text placeholders are treated as a single word

set the last word to replacementSalePrice

set the first word to (replacementItemKind & ": ")

end tell

-- tabs

set theseTextItems to every text item whose object text contains placeholderKind

repeat with i from 1 to the count of theseTextItems

set thisTextItem to item i of theseTextItems

tell thisTextItem

tell its object text

set (every paragraph where it contains placeholderKind) to ¬

replacementItemKind

end tell

end repeat

end tell

displayThisNotification("New Pages Document", "Template has been populated.", "")

on displayThisNotification(thisTitle, thisNotification, thisSubtitle)

tell current application

display notification thisNotification with title thisTitle subtitle thisSubtitle

end tell

end displayThisNotification

TOP | CONTINUE

PAGES SCRIPTING

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.