Here’s an example of AppleScript’s ability to transfer data between applications, to pour the source material into a newly created document, and to apply multiple formatting procedures to the text flow.

In this script example, the contents of an OmniOutliner outline document are transformed into a Pages word-processing document. The contents of each outline section become a new section in the Pages document. In addition, the script generates a table of contents for the new document.

(⬆ see above ) An Omni Outliner document containing the Constitution of the United States in outline format.

(⬇ see below ) The completed Pages document. In the process, the sections of the Omni Outliner document become sections in the Pages document. Optionally, the script can generate a Table of Contents. (Note: the tab leader formatting shown in the illustration is not part of the script processing)

DO THIS ►DOWNLOAD the example Omni OmniOutliner document.

OmniOutliner, from the Omni Group, is available for purchase from the Mac App Store, or as a trial version from the Omni Group website.

Download the example file, open and run the script.

OmniOutliner Outline to Pages Document
Open in AppleScript Editor
01		property defaultTemplateName : "Blank"
02
03		property defaultDocumentTitleTypeSize : 32
04		property defaultDocumentTitleTypeFace : "Hoefler Text"
05		property defaultDocumentTitleTypeColor : "black"
06
07		property defaultSectionTypeFace : "Times New Roman Italic"
08		property defaultSectionTypeSize : 18
09		property defaultSectionTypeColor : "black"
10
11		property defaultBodyTypeFace : "Hoefler Text"
12		property defaultBodyTypeSize : 12
13		property defaultBodyTypeColor : "gray"
14
15		property defaultTOCTitleTypeFace : "Helvetica"
16		property defaultTOCTitleTypeSize : 22
17		property defaultTOCTitleTypeColor : "black"
18
19		property defaultTOCItemTypeFace : "Hoefler Text"
20		property defaultTOCItemTypeSize : 18
21		property defaultTOCItemTypeColor : "gray"
22
23		property useSectionTitleForTOC : true
24
25
26		tell application "OmniOutliner"
27		activate
28		display dialog "This script will create a new Pages word-processing document, with each section of the frontmost OmniOutliner document becoming a new section in the Pages document." & return & return & "The name of each OmniOutliner section will be used as both the title of the newly created Pages section, and as an entry in the optionally created Table of Contents." with icon 1 buttons {"Cancel", "Include TOC", "Build"} default button 3
29		if button returned of the result is "Include TOC" then
30		set createTOC to true
31		else
32		set createTOC to false
33		end if
34		if not (exists document 1) then error number -128
35		tell the front document
36		set sourceDocumentTitle to its name
37		set the sourceDocumentSectionNames to the name of every section
38		set the sourceDocumentSectionCount to ¬
39		the count of the sourceDocumentSectionNames
40		end tell
41		end tell
42
43		tell application "Pages"
44		activate
45		set thisDocument to ¬
46		make new document with properties ¬
47		{document template:template defaultTemplateName}
48
49		tell thisDocument
50
51		if document body is false then
52		display alert "INCOMPATIBLE TEMPLATE" message "The template of this document does not have an active document body text flow."
53		error number -128
54		end if
55
56		-- TITLE PAGE
57		tell page 1
58		set body text to sourceDocumentTitle
59		tell body text
60		set font to defaultDocumentTitleTypeFace
61		set size to defaultDocumentTitleTypeSize
62		set the color of it to defaultDocumentTitleTypeColor
63		end tell
64		end tell
65
66		-- TOC PAGE OPTION
67		if createTOC is true then
68		make new section
69		set bufferIndex to 2
70		else
71		set bufferIndex to 1
72		end if
73
74		-- MAKE THE SECTIONS
75		repeat with i from 1 to (sourceDocumentSectionCount)
76		make new section
77		end repeat
78
79		-- POPULATE THE CONTENT OF THE SECTIONS
80		repeat with i from 1 to sourceDocumentSectionCount
81		tell application "OmniOutliner"
82		tell the front document
83		tell section i
84		set thisSourceDocumentSectionsText to name of it
85		set the leavesNames to the name of leaves
86		set thisSourceDocumentSectionsText to ¬
87		thisSourceDocumentSectionsText & return & ¬
88		return & my textItemsToText(leavesNames)
89		end tell
90		end tell
91		end tell
92		set pagesSectionIndex to (i + bufferIndex)
93		set body text of section pagesSectionIndex to thisSourceDocumentSectionsText
94		tell section pagesSectionIndex
95		tell body text
96		repeat with i from 1 to the count of paragraphs
97		if i is 1 then
98		set color of paragraph i to defaultSectionTypeColor
99		tell paragraph i
100		set font to defaultSectionTypeFace
101		set size to defaultSectionTypeSize
102		end tell
103		else
104		set color of paragraph i to defaultBodyTypeColor
105		tell paragraph i
106		set font to defaultBodyTypeFace
107		set size to defaultBodyTypeSize
108		end tell
109		end if
110		end repeat
111		end tell
112		end tell
113		end repeat
114
115		-- CREATE THE TOC
116		if createTOC is true then
117		set x to 2 -- title and TOC
118		set sectionStartIndexes to {}
119		set sectionTitleCounter to 1
120		set sectionDisplayNumber to 1
121		repeat with i from 2 to the count of sections
122		set the sectionStartpageIndex to x
123		set the end of the sectionStartIndexes to sectionStartpageIndex
124		if i is 2 then
125		set TOCText to "TABLE OF CONTENTS" & return
126		else
127		if useSectionTitleForTOC is true then
128		set TOCText to TOCText & return & tab & ¬
129		(item sectionTitleCounter of sourceDocumentSectionNames) & ¬
130		tab & sectionStartpageIndex
131		set sectionTitleCounter to sectionTitleCounter + 1
132		else
133		set TOCText to TOCText & return & tab & ¬
134		(item sectionTitleCounter of sourceDocumentSectionNames) & ¬
135		tab & sectionStartpageIndex
136		set sectionTitleCounter to sectionTitleCounter + 1
137		end if
138		end if
139		set x to x + (count of pages of section i)
140		end repeat
141		set body text of section 2 to TOCText
142		-- FROMAT THE TOC
143		tell body text of section 2
144		tell paragraph 1
145		set font to defaultTOCTitleTypeFace
146		set size to defaultTOCTitleTypeSize
147		set color of it to defaultTOCTitleTypeColor
148		end tell
149		tell paragraphs 2 thru -1
150		set font to defaultTOCItemTypeFace
151		set size to defaultTOCItemTypeSize
152		set color of it to defaultTOCItemTypeColor
153		end tell
154		end tell
155		end if
156		end tell
157		end tell
158		my goToPage(1)
159		my displaythisNotification("OmniOutliner to Pages", "Document created.", "")
160
161		on textItemsToText(textItems)
162		set AppleScript's text item delimiters to (return & return) -- double spaced
163		set the textBlock to textItems as string
164		set AppleScript's text item delimiters to ""
165		return textBlock
166		end textItemsToText
167
168		on displaythisNotification(thisTitle, thisNotification, thisSubtitle)
169		tell current application
170		display notification thisNotification with title thisTitle subtitle thisSubtitle
171		end tell
172		end displaythisNotification
173
174		on goToPage(pageIndex)
175		tell application "Pages"
176		activate
177		tell the front document
178		tell page pageIndex
179		set thisShape to ¬
180		make new shape with properties ¬
181		{height:12, width:12, position:{0, 0}}
182		delete thisShape
183		end tell
184		end tell
185		end tell
186		end goToPage