In Pages, there is a difference in the default behavior between creating a new image and replacing an existing placeholder image.

CREATE IMAGE: When a script creates a new image, the image container is automatically wrapped to fit the image, regardless of any sizing indicated during the execution of the make command.

REPLACE IMAGE: When a script replaces a placeholder image with an image file, the imported image is scaled and centered so that its shortest side fits within the placeholder view.

The example script on this page demonstrates image placeholder replacement by importing photos from a chosen iPhoto album into a tabloid-sized template containing rows of square image placeholders.  (⬇ see below ) 

Populate Thumbnail Template

DO THIS ►Before opening and running this script, DOWNLOAD and install the “Thumbnail Poster” template.

Here’s the script:

Populate Thumbnail Grid Template
Open in AppleScript Editor
01		property thisTemplateName : "Thumbnail Poster"
02
03		tell application "Pages"
04		activate
05		try
06		-- check for the required template
07		set the templateNames to the name of every template
08		if thisTemplateName is not in the templateNames then error number 1000
09
10		-- prompt user to pick the source album
11		set albumNames to my iPhotoalbumNames()
12		if albumNames is false then error number 1001
13		set chosenAlbum to ¬
14		(choose from list albumNames with prompt ¬
15		"Pick the album containing images to import:")
16		if chosenAlbum is false then error number -128
17
18		-- get a list of file paths to the album images
19		tell application "iPhoto"
20		-- using previews reduces time required for script to complete
21		-- use the "image path" property for higher resolution
22		set the imagePaths to ¬
23		the preview path of every photo of album (chosenAlbum as string)
24		set albumimageCount to the count of the imagePaths
25		if albumimageCount is 0 then error number 1002
26		end tell
27
28		-- make a new Pages document
29		set thisDocument to make new document with properties ¬
30		{document template:template thisTemplateName}
31		tell thisDocument
32		tell the current page
33		set imageCount to the count of images
34		repeat with i from 1 to the imageCount
35		if i is greater than albumimageCount then error number 1003
36		-- locate the image item by its description
37		set thisImage to (the first image whose description is (i as string))
38		-- convert the POSIX path to HFS file reference
39		set thisImageFile to (item i of the imagePaths) as the front POSIX file
40		-- replace the placeholder with the image
41		set file name of thisImage to thisImageFile
42		end repeat
43		end tell
44		end tell
45
46		-- notify the user
47		my displaythisNotification("New Pages Document", "Thumbnail document created.", "")
48		on error errorMessage number errorNumber
49		if errorNumber is 1000 then
50		display alert "MISSING RESOURCE" message "This script requires the installation of a Pages template titled “" & thisTemplateName & ".”" & return & return & "The template can be downloaded from: iworkautomation.com" as critical buttons {"Download", "Stop"} default button 2
51		if the button returned of the result is "Download" then
52		open location "http://iworkautomation.com/pages/image-replace.html"
53		end if
54		error number -128
55		else if errorNumber is 1001 then
56		set errorNumber to "iPhoto Issue"
57		set errorMessage to "There was a problem getting a list of albums from iPhoto."
58		else if errorNumber is 1002 then
59		set errorNumber to "iPhoto Issue"
60		set errorMessage to "The chosen album contains no photos."
61		else if errorNumber is 1003 then
62		set errorNumber to "iPhoto Issue"
63		set errorMessage to "There are more image placeholders than album images."
64		end if
65		if errorNumber is not -128 then
66		display alert (errorNumber as string) message errorMessage
67		end if
68		end try
69		end tell
70
71		on displaythisNotification(thisTitle, thisNotification, thisSubtitle)
72		tell current application
73		display notification thisNotification with title thisTitle subtitle thisSubtitle
74		end tell
75		end displaythisNotification
76
77		on iPhotoalbumNames()
78		try
79		--get a list of iPhoto albums
80		tell application "iPhoto"
81		launch
82		return (the name of every album)
83		end tell
84		on error
85		return false
86		end try
87		end iPhotoalbumNames

TIP: This template can be populated because the description for each placeholder image contains a number indicating its position in the order of placeholders on the page.