Here’s a script that combines the image editing abilities of AppleScript with Pages page item control, to create a tabloid poster of image thumbnails from a chosen iPhoto album of photos.

(⬇ see below ) A Pages tabloid document containing rows of square thumbnails of photos from a chosen iPhoto album.

Thumbnail Poster of Photos from an iPhoto Album
Open in AppleScript Editor
01		property templateName : "Type Poster Big"
02		property templateWidth : 792
03		property templateHeight : 1224
04		property defaultMargin : 36
05		-- for smaller thumbnails, adjust columnCount to higher number
06		property columnCount : 6
07
08		-- derive image dimensions, row count, and image count
09		set imageDimension to (templateWidth - (defaultMargin * 2)) div columnCount
10		set rowCount to (templateHeight - (defaultMargin * 2)) div imageDimension
11		set imageCount to rowCount * columnCount
12
13		try
14		--get a list of iPhoto albums
15		tell application "iPhoto"
16		launch
17		set albumNames to the name of every album
18		end tell
19
20		tell application "Pages"
21		activate
22		-- prompt user to pick the source album
23		set chosenAlbum to ¬
24		(choose from list albumNames with prompt ¬
25		"Pick the album containing " & imageCount & " images to import:")
26		if chosenAlbum is false then error number -128
27		-- get a list of file paths to the album images
28		tell application "iPhoto"
29		-- using previews reduces time required for script to complete
30		-- use the "image path" property for higher resolution
31		set the imagePaths to ¬
32		the preview path of every photo of album (chosenAlbum as string)
33		set albumimageCount to the count of the imagePaths
34		end tell
35		-- create a temporary folder
36		tell current application
37		set the temporaryItemsFolderpath to ¬
38		the POSIX path of (path to pictures folder)
39		set thisUUID to (do shell script "uuidgen")
40		set temporaryFolderPath to (temporaryItemsFolderpath & thisUUID)
41		do shell script "mkdir" & space & quoted form of temporaryFolderPath
42		end tell
43		-- make a new Pages document
44		set thisDocument to make new document with properties ¬
45		{document template:template templateName}
46
47		tell thisDocument
48		-- clear the document of existing items
49		set locked of every iWork item to false
50		delete every iWork item
51		-- create the grid of square image thumbnails
52		set rowOffset to defaultMargin
53		set columnOffset to defaultMargin
54		set imageCounter to 1
55		repeat with q from 1 to the rowCount
56		set rowOffset to defaultMargin
57		repeat with i from 1 to the columnCount
58		-- get the source image path
59		set thisImagePOSIXpath to (item imageCounter of imagePaths)
60		-- duplicate the source image to the temp folder
61		tell current application
62		set imageFileName to ¬
63		(do shell script "basename" & space & ¬
64		quoted form of thisImagePOSIXpath)
65		do shell script "cp" & space & quoted form of thisImagePOSIXpath & ¬
66		space & quoted form of temporaryFolderPath
67		set duplicateImageFile to ¬
68		(temporaryFolderPath & "/" & imageFileName)
69		end tell
70		-- pad the image to a square
71		set thisImageFile to my padToSquare(duplicateImageFile, true)
72		-- add the padded image to the layout
73		tell current page
74		make new image with properties ¬
75		{height:imageDimension ¬
76		, width:imageDimension ¬
77		, position:{rowOffset, columnOffset} ¬
78		, file:thisImageFile}
79		end tell
80		-- delete the padded source image file
81		tell current application
82		do shell script "rm" & space & quoted form of thisImageFile
83		end tell
84		-- increment the grid counters
85		set rowOffset to rowOffset + imageDimension
86		if imageCounter is albumimageCount then
87		set imageCounter to 1
88		else
89		set imageCounter to imageCounter + 1
90		end if
91		end repeat
92		set columnOffset to columnOffset + imageDimension
93		end repeat
94		end tell
95		end tell
96		-- delete the temp folder
97		tell current application
98		do shell script "rmdir" & space & quoted form of temporaryFolderPath
99		end tell
100		-- notify the user
101		displaythisNotification("New Pages Document", "Thumbnail document created.", "")
102		on error errorMessage number errorNumber
103		if errorNumber is not -128 then
104		tell application "Pages"
105		activate
106		display alert (errorNumber as string) message errorMessage
107		end tell
108		end if
109		end try
110
111		on displaythisNotification(thisTitle, thisNotification, thisSubtitle)
112		tell current application
113		display notification thisNotification with title thisTitle subtitle thisSubtitle
114		end tell
115		end displaythisNotification
116
117		on padToSquare(thisImageFile, applyScale)
118		set scaleDimension to 1024
119		try
120		tell application "Image Events"
121		-- start the Image Events application
122		launch
123		-- open the image file
124		set thisImage to open thisImageFile
125		-- get dimensions of the image
126		copy dimensions of thisImage to {imageWidth, imageHeight}
127		-- calculate pad dimensions
128		if imageWidth is greater than imageHeight then
129		set imageDimension to imageWidth
130		else
131		set imageDimension to imageHeight
132		end if
133		set padDimensions to {imageDimension, imageDimension}
134		-- perform padding
135		pad thisImage to dimensions padDimensions ¬
136		with pad color {65535, 65535, 65535}
137		if applyScale is true then
138		if imageDimension is greater than scaleDimension then
139		-- perform scaling
140		scale thisImage to size scaleDimension
141		end if
142		end if
143		-- save the changes
144		save thisImage with icon
145		-- purge the open image data
146		close thisImage
147		end tell
148		return thisImageFile
149		on error error_message
150		display dialog error_message
151		end try
152		end padToSquare