AppleScript and Keynote: Audio Clips

Audio Clips

Adding audio clips to a presentation can do much to increase audience comprehension by expanding the input senses to include more than just visual content. An excerpt from a famous speech, or the sounds of whales played over breathtaking underwater photography, can dramatically enliven a presentation and make it rememberable.

The terminology of the Keynote dictionary includes an audio clip class and properties for controlling its use:

The iWork Suite audio clip Class

audio clip n [inh. iWork item ] : An audio clip

elements

contained by slides, document.

properties

clip volume ( integer ) : The volume setting for the audio clip, from 0 (none) to 100 (full volume).

file name ( text r/o) : The name of the audio file.

repetition method ( none/‌loop/‌loop back and forth ) : If or how the audio clip repeats.

responds to

delete, exists

NOTE: In the current version of Keynote the audio clip class does not support the use of the make command. See the script example below for details on how to import an audio clip.

New Audio Clip at Current Slide

tell application "Keynote"

activate

try

-- PROMPT USER TO PICK AUDIO FILE

set audioFileHFSAlias to ¬

(choose file of type "public.audio" with prompt ¬

"Select the audio file to import:" default location (path to music folder))

-- CREATE DOCUMENT IF ONE DOES NOT EXIST

if not (exists document 1) then

make new document with properties ¬

{document theme:theme "Black", width:1024, height:768}

end if

tell document 1

-- IMPORT AUDIO FILE TO CURRENT SLIDE

tell the current slide

-- Keynote does not support using the audio clip class with the make verb

-- Import the audio file by using the image class as the direct parameter

-- The returned object reference will be to the created audio file

set thisAudioClip to make new image with properties {file:audioFileHFSAlias}

--> audio clip 1 of slide 1 of document "Document Name"

-- ADJUST AUDIO CLIP PROPERTIES

tell thisAudioClip

-- position property inherited from iWork Item class

set position to {48, 48}

-- audio clip properties

set clip volume to 75

set repetition method to loop

-- place the locked property at the end because

-- you can't change the properties of a locked iWork item

set locked to true

end tell

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert ("ERROR " & errorNumber as string) message errorMessage

end if

end try

end tell

Protected Audio Files

iWork applications do not allow the import of copy-protected media files. Attempting to import such items may cause an error, like this:

TIP: For an example of using text rendered to audio with slides, check out the last script example on the presenter notes page.

TOP | CONTINUE

KEYNOTE SCRIPTING

Overview
Automation Utilities

Examples

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.