AppleScript and Keynote: Movie

Movies

Adding movies to a presentation can do much to increase audience comprehension by presenting concepts and ideas in a relatable format. For example, beginning a presentation with a video of Earth from the International Space Station could be an excellent lead-in to slides examining global financial priorities and realties.

The iWork Suite movie Class

movie n [inh. iWork item ] : An audio clip

elements

contained by slides, document.

properties

file name ( text r/o) : The name of the movie file.

movie volume ( integer ) : The volume setting for the movie, from 0 (none) to 100 (full volume).

opacity ( integer ) : The opacity of the object, in percent.

reflection showing ( boolean ) : Is the movie displaying a reflection?

reflection value ( integer ) : The percentage of reflection of the movie, from 0 (none) to 100 (full).

repetition method ( none/‌loop/‌loop back and forth ) : If or how the audio clip repeats.

rotation ( integer ) : The rotation of the iWork item, in degrees from 0 to 359.

responds to

delete, exists

NOTE: In the current version of Keynote the movie class does not support the use of the make command. See the script example below for details on how to import a movie file.

New Movie at Current Slide

tell application "Keynote"

activate

try

-- PROMPT USER TO PICK MOVIE FILE

set movieFileHFSAlias to ¬

(choose file of type "public.movie" with prompt ¬

"Select the movie file to import:" default location (path to movies folder))

-- CREATE DOCUMENT IF ONE DOES NOT EXIST

if not (exists document 1) then

make new document with properties ¬

{document theme:theme "Black", width:1024, height:768}

end if

tell document 1

-- get document dimensions

set docWidth to the width

set docHeight to the height

-- IMPORT MOVIE FILE TO CURRENT SLIDE

tell the current slide

-- Keynote does not support using the movie class with the make verb

-- Import the movie file by using the image class as the direct parameter

-- The returned object reference will be to the created movie item

set thisMovie to make new image with properties {file:movieFileHFSAlias}

--> movie 1 of slide 1 of document "Document Name"

-- ADJUST MOVIE PROPERTIES

tell thisMovie

-- adjust the size and position of the movie item...

-- using properties inherited from iWork Item class

set movWidth to 720

set width to movWidth

set movHeight to height

set position to ¬

{(docWidth - movWidth) div 2, (docHeight - movHeight) div 2}

-- movie class properties

set reflection showing to true

set reflection value to 75

set movie volume to 90

set repetition method to none

-- place the locked property at the end because

-- you can't change the properties of a locked iWork item

set locked to true

end tell

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert ("ERROR " & errorNumber as string) message errorMessage

end if

end try

end tell

Protected Video Files

iWork applications do not allow the import of copy-protected media files. Attempting to import such items may cause an error, like this:

TOP | CONTINUE

KEYNOTE SCRIPTING

Overview
Automation Utilities

Examples

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.