Scripts use the save command, from the Standard Suite, to save Pages documents to files on disk.

To save a document with a specific name and location, include the optional in parameter with the save command, and follow the parameter with a reference to the file to be created. This reference can be in an HFS file format or UNIX POSIX path format. Be sure to include the file extension “pages” with the file name.

save document 1 in file "Macintosh HD:Users:Johnny:Desktop:Report.pages"

save document 1 in "/Users/Johnny/Desktop/Report.pages"

Examples for exporting saved Pages documents in other formats, such as PDF, Microsoft Word, or EPUB, are detailed in the Exporting Documents page.

Make and Save Document
Open in AppleScript Editor
01		-- Create a new document and save it into the Documents folder
02
03		-- generate the default file name
04		set todaysDate to (current date)
05		set the nameToUse to ¬
06		("Monthly Report - " & (month of todaysDate) as string) & ¬
07		space & (year of todaysDate) as string
08		--> "Monthly Report - December 2014"
09
10		-- make sure the file name is not in use
11		set the destinationFolderHFSpath to ¬
12		(path to the documents folder) as string
13		repeat with i from 0 to 100
14		if i is 0 then
15		set incrementText to ""
16		else
17		set incrementText to "-" & (i as string)
18		end if
19		set thisFileName to nameToUse & incrementText & ".pages"
20		set thisFilepath to destinationFolderHFSpath & thisFileName
21		tell application "Finder"
22		if not (exists document file thisFilepath) then exit repeat
23		end tell
24		end repeat
25
26		tell application "Pages"
27		activate
28		-- create a new document and store its reference in a variable
29		set thisDocument to make new document with properties ¬
30		{document template:template "Blank"}
31
32		-- save the document
33		save thisDocument in file thisFilepath
34		end tell

TIP: The script above uses the path to command to generate a disk reference to a standard user folder. Enumerations for other standard path to command locations include: documents folder/‌downloads folder/home folder/movies folder/music folder/‌pictures folder/public folder/temporary items/shared documents. For more information, view the path to command in the Standard Additions scripting dictionary.