AppleScript and Keynote: Images

Images

When it comes to presentations, the old adage of “A picture is worth a thousand words” is sacrosanct. Nothing gets the point across like a compelling image. So it’s quite reasonable to expect automations of Keynote to encounter plenty of image-based tasks. Not to worry, the AppleScript support in Keynote provides ample controls for creating unforgettable presentations.

Keynote Scripting Terminology for Images

Documents created by any of the iWork applications, Pages, Numbers, or Keynote, can incorporate a common set of elements, including images, shapes, lines, tables, charts, movies, and audio clips. To AppleScript and the built-in scripting support of the iWork applications, these elements are considered iWork Items, and share a common set of properties, detailed in the iWork Item class from the iWork Suite:

The iWork Suite iWork item Class

iWork item n [inh. iWork item ] : An item which supports formatting.

elements

contained by slides, document.

properties

height ( integer ) : The height of the iWork item.

locked ( boolean ) : Whether the object is locked.

parent ( iWork container r/o ) : The iWork container containing this iWork item.

position ( point ) : The horizontal and vertical coordinates of the top left point of the iWork item.

width ( integer ) : The width of the iWork item.

responds to

delete, exists

The properties in the iWork item class can be accessed and changed for any of the common iWork elements. For example, a script can get or set the position of a movie, or image, or shape, or any of the common elements.

In addition to sharing a common set of properties with the other iWork elements, each iWork element has its own set of properties, particular to that element. For example, the element-specific properties of an image are detailed in its dictionary listing, found in the iWork Suite: (⬇ see below )

The iWork Suite image Class

image n [inh. iWork item ] : An image container.

elements

contained by slides, document.

properties

description ( text ) : Text associated with the image, can be read aloud by VoiceOver.

file ( file , r/o) : The image file. This property is a required parameter when used with the make command to create a new image item on a slide. Use the file name property to retrieve the name of the image, or to replace the currently displayed image.

file name ( text or file ) : When used with the get command, the value of this property is the file name of the image file currently displayed in the image container. When this property is used with the set command, the value of the property is a file reference (in HFS alias format) to the image file to be used to replace the currently displayed image.

opacity ( integer ) : The opacity of the image, in percent (0 to 100).

reflection showing ( boolean ) : Is the image displaying a reflection?

reflection value ( integer ) : The percentage of reflection of the image, from 0 (none) to 100 (full).

rotation ( integer ) : The rotation of the image item, in degrees from 0 to 359.

responds to

delete, exists, make

Adding an Image to a Slide

The following script demonstrates how to use the make command to create a new image item on a slide, and then manipulate its basic sizing properties to adjust the image to encompass the entire slide, as shown in the screen capture shown below:

New Presentation with Random Image

-- GET THE CURRENT SCREEN DIMENSIONS

tell application "Finder"

copy the bounds of the window of the desktop to {x, y, screenWidth, screenHeight}

end tell

-- CREATE A NEW PRESENTATION

tell application "Keynote"

activate

if playing is true then tell the front document to stop

-- CREATE THE DOCUMENT

set thisDocument to make new document with properties ¬

{document theme:theme "Black", width:screenWidth, height:screenHeight}

tell thisDocument

set the base slide of the first slide to master slide "Blank"

-- GET THE RANDOM IMAGE

copy my getRandomDesktopPicture() to {thisImageFileName, thisImageFile}

-- trim the file extension (.jpg) from the file name

set thisImageName to text 1 thru -5 of thisImageFileName

-- ADD THE IMAGE FILE TO THE FIRST SLIDE

tell the first slide

-- IMPORT THE DESKTOP IMAGE

set thisImage to ¬

make new image with properties {file:thisImageFile}

tell thisImage

set thisItemHeight to its height

if thisItemHeight is not screenHeight then

-- FILL IMAGE TO SLIDE HEIGHT AND CENTER

set height of it to screenHeight

set thisItemWidth to its width

set the position of it to {((screenWidth - thisItemWidth) div 2), 0}

end if

end tell

-- CREATE A TEXT OVERLAY DISPLAYING IMAGE NAME

set thisTitleBox to ¬

make new text item with properties {object text:thisImageName}

tell thisTitleBox

set font of object text of it to "Times New Roman Italic"

set thisItemHeight to its height

copy position of it to {horizontalPosition, verticalPositon}

set position of it to {horizontalPosition, screenHeight - (thisItemHeight * 2)}

end tell

-- START PLAYING THE PRESENTATION FROM THE BEGINNING

start thisDocument from first slide of thisDocument

end tell

on getRandomDesktopPicture()

-- GET A RANDOM IMAGE FROM THE DESKTOP PICTURES FOLDER

set desktopPicturesFolder to (path to desktop pictures folder)

set the imageFileNames to every paragraph of ¬

(do shell script "ls " & quoted form of POSIX path of desktopPicturesFolder)

--> RETURNS: {"Abstract.jpg", "Antelope Canyon.jpg", "Bahamas Aerial.jpg", etc.}

set thisImageFileName to some item of the imageFileNames

--> RETURNS: "Mountain Range.jpg"

set thisImageFile to ((desktopPicturesFolder as string) & thisImageFileName) as alias

--> RETURNS: alias "Macintosh HD:Library:Desktop Pictures:Mountain Range.jpg"

return {thisImageFileName, thisImageFile}

end getRandomDesktopPicture

TOP | CONTINUE

KEYNOTE SCRIPTING

Overview
Automation Utilities

Examples

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.