AppleScript and Keynote: Themes

Keynote Themes

The theme class is a top-level element of the Keynote application. It contains no other elements, and has two properties. The choice of theme determines the overall look of a presentation, as well as the document dimensions, and selection of master pages.

The Keynote Suite Theme Class

theme n : A collection of master slides, with shared design intents and elements.

elements

contained by application.

properties

id (text, r/o) : The unique identifier for this application element.

name (text, r/o) : The name of the theme, as it is displayed in the application’s user interface.

The pages of this topic section detail how to access the properties of all installed themes, all application themes, and all user-created themes. Example scripts detail how to create documents using a specified theme.

The Theme ID Property

The id property of a theme is a text string that uniquely identifies the theme to the Keynote application.

The following script retrieves the id of every theme:

IMPORTANT TIP: Learn how to save and run your favorite scripts using the system-wide Script Menu.

Get the ID of Every Theme

tell application "Keynote"

get the id of every theme

--> RETURNS: {"Application/Black/Standard", "Application/White/Standard", "Application/Gradient/Standard", "Application/New_Template1/Standard", "Application/New_Template4/Standard", "Application/New_Template2/Standard", "Application/New_Template3/Standard", "Application/New_Template5/Standard", "Application/New_Template6/Standard", "Application/Showroom/Standard", "Application/Renaissance/Standard", "Application/PhotoPortfolio/Standard", "Application/Editorial/Standard", "Application/Kyoto/Standard", "Application/BrushedCanvas/Standard", "Application/Typeset/Standard", "Application/Moroccan/Standard", "Application/Craft/Standard", "Application/Industrial/Standard", "Application/ModernPortfolio/Standard", "Application/Harmony/Standard", "Application/GraphPaper/Standard", "Application/Blueprint/Standard", "Application/Formal/Standard", "Application/LeatherBook/Standard", "Application/Vintage/Standard", "Application/HardCover/Standard", "Application/LinenBook/Standard", "Application/Chalkboard/Standard", "Application/Parchment/Standard", "User/C34CF6EC-2BC4-4DE0-9A3B-35BA88F15B2C"}

end tell

In Keynote, there are two kinds of themes: those that come with the application, and those created and saved by the user.

The id for an application theme begins with the term: “Application”

"Application/ModernPortfolio/Standard"

The id for a user-created theme begins with the term: “User”

"User/C34CF6EC-2BC4-4DE0-9A3B-35BA88F15B2C"

The design of theme ids allows for specialized searches, as shown later on this page.

The Theme Name Property

The name property of a theme is a text string that is the name of the theme as it is displayed in the Keynote application interface.

The following script retrieves the name of every theme:

Get the Name of Every Theme

tell application "Keynote"

get the name of every theme

--> RETURNS: {"Black", "White", "Gradient", "Photo Essay", "Classic", "Slate", "Cream Paper", "Artisan", "Improv", "Showroom", "Renaissance", "Photo Portfolio", "Editorial", "Kyoto", "Brushed Canvas", "Typeset", "Moroccan", "Craft", "Industrial", "Modern Portfolio", "Harmony", "Graph Paper", "Blueprint", "Formal", "Leather Book", "Vintage", "Hard Cover", "Linen Book", "Chalkboard", "Parchment", "Sal Theme"}

end tell

Application|User Themes

A script can use the unique design of the id property to retrieve only themes of a specific type.

The following script retrieves the name of every application theme:

Get the Name of All Application Themes

tell application "Keynote"

set applicationThemeNames to the name of every theme whose id of it begins with "Application/"

end tell

The following script retrieves the name of every user theme:

Get the Name of All User Themes

tell application "Keynote"

set userThemeNames to the name of every theme whose id of it begins with "User/"

--> RETURNS: {"Sal Theme"}

end tell

Check for Theme

A principle of good “defensive” script writing is to never assume anything, always check for resources. Here’s a script that checks to make sure a specific theme is intalled:

Check for Theme

property thisThemeName : "Black"

tell application "Keynote"

activate

try

-- GET THE THEME NAMES

set the themeNames to the name of every theme

-- CHECK FOR THEME

if thisThemeName is not in the themeNames then

error "The theme “" & thisThemeName & "” is not installed on this computer."

end if

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert ("ERROR " & errorNumber) message errorMessage

end if

end try

end tell

TOP | CONTINUE

KEYNOTE SCRIPTING

Overview
Automation Utilities

Examples

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.