AppleScript and Keynote: Add Image Descriptions

Add Image Descriptions

Here are two scripts for adding descriptions over or below images in a Keynote presentation.

Add Descriptions Under Images

This script positions image descriptions below the source image frame. If an image has no description, no text container is added. There are two options for controlling the process:

You can choose to process all images on all slides, or just the images on the current slide.

The font size for the descriptions can be a fixed size or be adjusted based upon the ratio of text length and image width.

Short descriptions:

Long descriptions:

Set the value for the default font family and size properties to suite your requirements.

Add Descriptions Under Images

property offsetPadding : 8

property textTypeface : "Helvetica Neue Medium"

property textFontSizeFixed : 24

property textFontSizeLarge : 36

property textFontSizeMedium : 24

property textFontSizeSmall : 18

property textRGBColorValues : {65535, 65535, 65535}

tell application "Keynote"

activate

if playing is true then tell the front document to stop

if not (exists document 1) then error number -128

tell the front document

set documentWidth to its width

set documentHeight to its height

display dialog "Add descriptions below images on all slides, or just the current slide?" buttons {"Cancel", "All Slides", "Current Slide"} default button 3 with icon 1

set targetScope to button returned of the result

log ("targetScope: " & targetScope)

if the targetScope is "All Slides" then

set theseSlides to every slide whose skipped is false

else

set theseSlides to {}

set the end of theseSlides to the current slide

end if

display dialog "Use fixed or adjustable size for the font size?" buttons {"Cancel", "Adjustable", "Fixed"} default button 3 with icon 1

set fontSizeMethod to the button returned of the result

log ("fontSizeMethod: " & fontSizeMethod)

repeat with i from 1 to the count of theseSlides

set thisSlide to item i of theseSlides

set imageCount to the count of images of thisSlide

repeat with q from 1 to the imageCount

set thisImage to image q of thisSlide

set thisDescription to the description of thisImage

if thisDescription is not "" then

copy (my deriveBoundsOfVisibleImageMaskFor(thisImage)) to {x, y, x1, y1}

tell thisSlide

set thisTextItem to make new text item with properties {position:{x, y}, width:(x1 - x), object text:thisDescription}

end tell

tell thisTextItem

tell object text

set font to textTypeface

if fontSizeMethod is "Adjustable" then

set fontSizeFactor to (x1 - x) div (length of thisDescription)

log "fontSizeFactor: " & fontSizeFactor

if fontSizeFactor is less than 25 then

set textFontSize to textFontSizeSmall

else if fontSizeFactor is less than 35 then

set textFontSize to textFontSizeMedium

else

set textFontSize to textFontSizeLarge

end if

else

set textFontSize to textFontSizeFixed

end if

set size to textFontSize

-- Always use “of it” when setting the value of the color property

set color of it to textRGBColorValues

end tell

-- position the text item below the host image

set textItemHeight to its height

copy its position to {tx, ty}

set its position to {tx, (y1 + offsetPadding)}

end tell

end if

end repeat

end tell

on deriveBoundsOfVisibleImageMaskFor(thisImage)

tell application "Keynote"

tell the front document

set documentWidth to its width

set documentHeight to its height

copy position of thisImage to {imageMaskTopLeftHorizontalOffset, imageMaskTopLeftVerticalOffset}

set imageMaskWidth to width of thisImage

set imageMaskHeight to height of thisImage

-- derive the top left horizontal offset of the visible image mask

if imageMaskTopLeftHorizontalOffset is less than 0 then

set visbleImageMaskTopLeftHorizontalOffset to 0

else

set visbleImageMaskTopLeftHorizontalOffset to imageMaskTopLeftHorizontalOffset

end if

-- derive the bottom right horizontal offset of the visible image mask

set imageMaskBottomRightHorizontalOffset to imageMaskTopLeftHorizontalOffset + imageMaskWidth

if imageMaskBottomRightHorizontalOffset is greater than documentWidth then

set visbleImageMaskBottomRightHorizontalOffset to documentWidth

else

set visbleImageMaskBottomRightHorizontalOffset to imageMaskBottomRightHorizontalOffset

end if

100

-- derive the width of the visible image mask

101

set visbleImageMaskWidth to visbleImageMaskBottomRightHorizontalOffset - visbleImageMaskTopLeftHorizontalOffset

102

103

log "visbleImageMaskWidth: " & visbleImageMaskWidth

104

105

-- derive the top left vertical offset of the visible image mask

106

if imageMaskTopLeftVerticalOffset is less than 0 then

107

set visbleImageMaskTopLeftVerticalOffset to 0

108

else

109

set visbleImageMaskTopLeftVerticalOffset to imageMaskTopLeftVerticalOffset

110

end if

111

112

log "visbleImageMaskTopLeftVerticalOffset: " & visbleImageMaskTopLeftVerticalOffset

113

114

-- derive the bottom right vertical offset of the visible image mask

115

set imageMaskBottomRightVerticalOffset to imageMaskTopLeftVerticalOffset + imageMaskHeight

116

if imageMaskBottomRightVerticalOffset is greater than documentHeight then

117

set visibleImageMaskBottomRightVerticalOffset to documentHeight

118

else

119

set visibleImageMaskBottomRightVerticalOffset to imageMaskBottomRightVerticalOffset

120

end if

121

122

log "visibleImageMaskBottomRightVerticalOffset: " & visibleImageMaskBottomRightVerticalOffset

123

124

-- derive the height of the visible image mask

125

set visbleImageMaskHeight to visibleImageMaskBottomRightVerticalOffset - visbleImageMaskTopLeftVerticalOffset

126

127

log "visbleImageMaskheight: " & visbleImageMaskHeight

128

129

-- return bounds of the visible image mask

130

return {visbleImageMaskTopLeftHorizontalOffset, visbleImageMaskTopLeftVerticalOffset, visbleImageMaskBottomRightHorizontalOffset, visibleImageMaskBottomRightVerticalOffset}

131

end tell

132

end tell

133

end deriveBoundsOfVisibleImageMaskFor

Overlay Image Descriptions

Rather than place the image description below the source image, the following script overlays the description over the bottom of the source image.

Overlay Image Descriptions

property overlayPadding : 18

property textOverlayTypeface : "Helvetica"

property textFontSizeFixed : 28

property textOverlayFontSizeLarge : 36

property textOverlayFontSizeMedium : 24

property textOverlayFontSizeSmall : 18

property textOverlayRGBColorValues : {65535, 65535, 65535}

tell application "Keynote"

activate

if not (exists document 1) then error number -128

if playing is true then stop every document

display dialog "Overlay the description or file name on every image in this presentation?" buttons {"Cancel", "File Name", "Description"} default button 3 with icon 1

set chosenMetadata to the button returned of the result

log ("chosenMetadata: " & chosenMetadata)

display dialog "Overlay descriptions on all slides, or just the current slide?" buttons {"Cancel", "All Slides", "Current Slide"} default button 3 with icon 1

set targetScope to button returned of the result

log ("targetScope: " & targetScope)

if the targetScope is "All Slides" then

set theseSlides to every slide whose skipped is false

else

set theseSlides to {}

set the end of theseSlides to the current slide of document 1

end if

display dialog "Use fixed or adjustable size for the font size?" buttons {"Cancel", "Adjustable", "Fixed"} default button 3 with icon 1

set fontSizeMethod to the button returned of the result

log ("fontSizeMethod: " & fontSizeMethod)

tell the front document

set documentWidth to its width

set documentHeight to its height

repeat with i from 1 to the count of theseSlides

set thisSlide to item i of theseSlides

set imageCount to the count of images of thisSlide

repeat with q from 1 to the imageCount

set thisImage to image q of thisSlide

if chosenMetadata is "Description" then

set thisDescription to the description of thisImage

else

set thisDescription to the file name of thisImage

end if

if thisDescription is not "" then

copy (my deriveBoundsOfVisibleImageMaskFor(thisImage)) to {x, y, x1, y1}

tell thisSlide

set thisTextItem to make new text item with properties {position:{x, y}, width:(x1 - x), object text:thisDescription}

end tell

tell thisTextItem

tell object text

set font to textOverlayTypeface

if fontSizeMethod is "Adjustable" then

set fontSizeFactor to (x1 - x) div (length of thisDescription)

log "fontSizeFactor: " & fontSizeFactor

if fontSizeFactor is less than 20 then

set textOverlayFontSize to textOverlayFontSizeSmall

else if fontSizeFactor is less than 25 then

set textOverlayFontSize to textOverlayFontSizeMedium

else

set textOverlayFontSize to textOverlayFontSizeLarge

end if

else

set textOverlayFontSize to textFontSizeFixed

end if

set size to textOverlayFontSize

set color of it to textOverlayRGBColorValues

end tell

-- position the text overlay at bottom of host image

set textItemHeight to its height

copy its position to {tx, ty}

set its position to {tx, (y1 - textItemHeight - overlayPadding)}

end tell

end if

end repeat

end tell

on deriveBoundsOfVisibleImageMaskFor(thisImage)

tell application "Keynote"

tell the front document

set documentWidth to its width

set documentHeight to its height

copy position of thisImage to {imageMaskTopLeftHorizontalOffset, imageMaskTopLeftVerticalOffset}

set imageMaskWidth to width of thisImage

set imageMaskHeight to height of thisImage

-- derive the top left horizontal offset of the visible image mask

if imageMaskTopLeftHorizontalOffset is less than 0 then

set visbleImageMaskTopLeftHorizontalOffset to 0

else

set visbleImageMaskTopLeftHorizontalOffset to imageMaskTopLeftHorizontalOffset

end if

-- derive the bottom right horizontal offset of the visible image mask

set imageMaskBottomRightHorizontalOffset to imageMaskTopLeftHorizontalOffset + imageMaskWidth

if imageMaskBottomRightHorizontalOffset is greater than documentWidth then

set visbleImageMaskBottomRightHorizontalOffset to documentWidth

else

set visbleImageMaskBottomRightHorizontalOffset to imageMaskBottomRightHorizontalOffset

end if

100

101

-- derive the width of the visible image mask

102

set visbleImageMaskWidth to visbleImageMaskBottomRightHorizontalOffset - visbleImageMaskTopLeftHorizontalOffset

103

104

log "visbleImageMaskWidth: " & visbleImageMaskWidth

105

106

-- derive the top left vertical offset of the visible image mask

107

if imageMaskTopLeftVerticalOffset is less than 0 then

108

set visbleImageMaskTopLeftVerticalOffset to 0

109

else

110

set visbleImageMaskTopLeftVerticalOffset to imageMaskTopLeftVerticalOffset

111

end if

112

113

log "visbleImageMaskTopLeftVerticalOffset: " & visbleImageMaskTopLeftVerticalOffset

114

115

-- derive the bottom right vertical offset of the visible image mask

116

set imageMaskBottomRightVerticalOffset to imageMaskTopLeftVerticalOffset + imageMaskHeight

117

if imageMaskBottomRightVerticalOffset is greater than documentHeight then

118

set visibleImageMaskBottomRightVerticalOffset to documentHeight

119

else

120

set visibleImageMaskBottomRightVerticalOffset to imageMaskBottomRightVerticalOffset

121

end if

122

123

log "visibleImageMaskBottomRightVerticalOffset: " & visibleImageMaskBottomRightVerticalOffset

124

125

-- derive the height of the visible image mask

126

set visbleImageMaskHeight to visibleImageMaskBottomRightVerticalOffset - visbleImageMaskTopLeftVerticalOffset

127

128

log "visbleImageMaskheight: " & visbleImageMaskHeight

129

130

-- return bounds of the visible image mask

131

return {visbleImageMaskTopLeftHorizontalOffset, visbleImageMaskTopLeftVerticalOffset, visbleImageMaskBottomRightHorizontalOffset, visibleImageMaskBottomRightVerticalOffset}

132

end tell

133

end tell

134

end deriveBoundsOfVisibleImageMaskFor

TOP | CONTINUE

KEYNOTE SCRIPTING

Overview
Automation Utilities

Examples

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.