The basic properties of an image, such as reflection showing, and its inherited properties from being an iWork item, such as position and height, provide numerous opportunities for the creative display of images in a presentation.

The example script on this page, creates a new presentation with a slide that displays a random desktop picture. The picture is used twice: once as a full-slide faded background image; and as a smaller, centered, full-opacity version that displays a reflection of itself.  (⬇ see below ) 

The following script demonstrates how to manipulate nearly all of the properties of an image (The rotation property is not included in this example):

Image on Faded Background Version
Open in AppleScript Editor
01		-- USER ADJUSTABLE VALUES
02		property backgroundImageOpacity : 20
03		property foregroundImageReflectionValue : 85
04		property textLabelTypeface : "Zapfino"
05		property textLabelSize : 36
06		property textLabelOffsetPercentage : 85
07
08		-- GET THE CURRENT SCREEN DIMENSIONS
09		tell application "Finder"
10		copy the bounds of the window of the desktop to {x, y, screenWidth, screenHeight}
11		end tell
12
13		-- CREATE A NEW PRESENTATION
14		tell application "Keynote"
15		activate
16		if playing is true then tell the front document to stop
17
18		-- CREATE THE DOCUMENT
19		set thisDocument to make new document with properties ¬
20		{document theme:theme "Black", width:screenWidth, height:screenHeight}
21
22		tell thisDocument
23		set the base slide of the first slide to master slide "Blank"
24
25		-- GET THE RANDOM IMAGE
26		copy my getRandomDesktopPicture() to {thisImageFileName, thisImageFile}
27		-- trim the file extension (.jpg) from the file name
28		set thisImageName to text 1 thru -5 of thisImageFileName
29
30		-- ADD THE IMAGE FILE TO THE FIRST SLIDE
31		tell the first slide
32		-- IMPORT THE DESKTOP IMAGE
33		set thisImage to ¬
34		make new image with properties {file:thisImageFile}
35		tell thisImage
36		set thisItemHeight to its height
37		if thisItemHeight is not screenHeight then
38		-- FILL IMAGE TO SLIDE HEIGHT AND CENTER
39		set height of it to screenHeight
40		set thisItemWidth to its width
41		set the position of it to {((screenWidth - thisItemWidth) div 2), 0}
42		end if
43		-- fade the background image
44		set its opacity to backgroundImageOpacity
45		-- add A VoiceOver description
46		set its description to ¬
47		"A faded full-screen version of the image named “" & ¬
48		thisImageName & ".”"
49		end tell
50
51		-- IMPORT THE SAME DESKTOP IMAGE
52		set thisImage to ¬
53		make new image with properties {file:thisImageFile}
54		-- ADJUST THE IMAGE TO REDUCED SIZE IN UPPER CENTER
55		set smallImageWidth to (screenWidth div 2)
56		tell thisImage
57		set width to smallImageWidth
58		set newHeight to its height
59		set the position of thisImage to ¬
60		{(screenWidth - smallImageWidth) div 2, screenHeight div 4}
61		-- set image properties
62		set reflection showing to true
63		set reflection value to foregroundImageReflectionValue
64		copy position to {smallImageHorizOffset, smallImageVertOffset}
65		-- add A VoiceOver description
66		set its description to "An image named “" & thisImageName & ".”"
67		end tell
68
69		-- CREATE A TEXT OVERLAY DISPLAYING IMAGE NAME
70		set thisTitleBox to ¬
71		make new text item with properties {object text:thisImageName}
72		tell thisTitleBox
73		set font of object text of it to textLabelTypeface
74		set size of object text of it to textLabelSize
75		set thisItemHeight to its height
76		set thisItemWidth to its width
77		-- place above smaller image
78		set thisOffsetPercentageFactor to textLabelOffsetPercentage * 0.01
79		set position of it to ¬
80		{(screenWidth - thisItemWidth) div 2 ¬
81		, ((screenHeight div 4) - ¬
82		(thisItemHeight * thisOffsetPercentageFactor))}
83		end tell
84		-- lock all of the items
85		set locked of every iWork item to true
86		end tell
87		end tell
88
89		-- START PLAYING THE PRESENTATION FROM THE BEGINNING
90		start thisDocument from first slide of thisDocument
91		end tell
92
93		on getRandomDesktopPicture()
94		-- GET A RANDOM IMAGE FROM THE DESKTOP PICTURES FOLDER
95		set desktopPicturesFolder to (path to desktop pictures folder)
96		set the imageFileNames to every paragraph of ¬
97		(do shell script "ls " & quoted form of POSIX path of desktopPicturesFolder)
98		--> RETURNS: {"Abstract.jpg", "Antelope Canyon.jpg", "Bahamas Aerial.jpg", etc.}
99		set thisImageFileName to some item of the imageFileNames
100		--> RETURNS: "Mountain Range.jpg"
101		set thisImageFile to ((desktopPicturesFolder as string) & thisImageFileName) as alias
102		--> RETURNS: alias "Macintosh HD:Library:Desktop Pictures:Mountain Range.jpg"
103		return {thisImageFileName, thisImageFile}
104		end getRandomDesktopPicture