This short tutorial demonstrates a useful technique for creating a presentation that incorporates images from online sources. Using this technique, linked images in a presentation can be updated periodically throughout the presentation development process.

NOTE: The online images used with the technique demonstrated below, can be from your company’s website, or servers, or from a website that provides royalty-free images to the public, such as HubbleSite.org. Be sure that you have checked the assigned rights of the images you use in your presentations.

Tagged Placeholders

The following describes how image placeholders in slides can be tagged with URLs to online source images.

(1) Image Placeholder • The image placeholder selected in the slide. Placeholders are identified with by their circular icon overlay of an image.

(2) Format Pane > Image Settings Tab • The Image Settings tab is selected in the Format pane.

(3) Image Description • The Description field usually contains the text to be read by the VoiceOver application. For the purposes of this presentation development technique, the description is replaced with a URL to the image file to be downloaded to the computer, and then used as the replacement for the placeholder. NOTE: the example script provides the option to replace the image URL with the embedded description from the replacement image file (if it has one).

The Example Tutorial

DO THIS ►DOWNLOAD and open the example Keynote presentation  (⬆ see above )  that has been pre-tagged with image URLs.

DO THIS ►With an active internet connection, open the example script  (⬇ see below )  in the AppleScript Editor application and run it.

The example script provided below is designed to examine each slide of a presentation for images whose description is a URL. If a URL is found by the script, it will attempt to download the online image to disk and then replace the placeholder image with the downloaded file.

NOTE: If the script property replaceDescriptionWithURL is set to true, then the script can be run over and over to get the latest version of the image from its URL.

Replace Placeholders with Images from URLs
Open in AppleScript Editor
01		-- The value of this property deternines whether the description for the new image should be its source URL or embedded description metadata (if any)
02		property replaceDescriptionWithURL : true
03
04		tell application "Keynote"
05		activate
06		if not (exists front document) then error number -128
07		tell the front document
08		-- check each slide for images whose description is a URL
09		repeat with i from 1 to the count of slides
10		tell slide i
11		repeat with q from 1 to the count of images
12		tell image q
13		set currentDescription to the description
14		end tell
15		if currentDescription contains "://" then
16		set newImageFile to my fileFromURL(currentDescription)
17		if newImageFile is not false then
18		set file name of image q to newImageFile
19		if replaceDescriptionWithURL is true then
20		set description of image q to currentDescription
21		else -- attempt to retrieve embedded description
22		set embeddedDescription to my extractkMDItemDescription(newImageFile)
23		set description of image q to embeddedDescription
24		end if
25		end if
26		end if
27		end repeat
28		end tell
29		end repeat
30		end tell
31		start the front document from the first slide of the front document
32		end tell
33
34		on fileFromURL(currentDescription)
35		try
36		-- get the name of the file from the URL
37		set the fileName to do shell script "basename " & currentDescription
38		-- derive a path to the temp folder into which the image will be downloaded
39		set the temporaryItemsFolder to ¬
40		the POSIX path of (path to the temporary items folder)
41		set the targetFile to (temporaryItemsFolder & fileName)
42		-- download the image
43		do shell script "curl" & space & currentDescription & space & "-o" & ¬
44		space & quoted form of targetFile
45		-- return an HFS alias file reference to the image file
46		return targetFile as POSIX file as alias
47		on error
48		return false
49		end try
50		end fileFromURL
51
52		on extractkMDItemDescription(thisImageFile)
53		-- uses Spotlight to retrieve embedded description metadata (if any)
54		try
55		set thisImagePOSIXpath to the POSIX path of thisImageFile
56		set the embeddedDescription to ¬
57		do shell script "mdls -name kMDItemDescription " & ¬
58		(quoted form of thisImagePOSIXPath)
59		if embeddedDescription is "kMDItemDescription = (null)" then
60		set embeddedDescription to ""
61		else
62		set the embeddedDescription to ¬
63		(text from ((length of "kMDItemDescription = \"") + 1) to ¬
64		-2 of embeddedDescription)
65		end if
66		return embeddedDescription
67		on error
68		return ""
69		end try
70		end extractkMDItemDescription

(⬇ see below ) A slide with the imported images: