Whether they are visible or not, every Keynote slide incorporates, by default, two text containers: one for the slide title; and one for the slide body. The visibility of these text items is determined by the state of the Appearance checkboxes in the Slide Layout pane of the Format tab.  (⬇ see image below ) 

The dictionary entry for the slide class contains properties for determining visibility of these default text items, and well references to the objects, enabling the ability to set and format their text contents.

The Default Text Item Properties (Excerpt from Slide Class)

Master Slides and Default Text Items

The following illustrations show how default text items are used in standard master slide designs:

(⬆ see above )  Title & Subtitle • This slide master design incorporates a default text item for the title  1  and a default text item for the subtitle  2  . Their visibility is determined by the status of their corresponding checkboxes.

(⬆ see above )  Title – Center • This slide master design incorporates a default text item for the title  1  and no default text item for a subtitle or body. Note that the checkbox for controlling the default body text item is unselected  2  .

(⬆ see above )  Title, Bullets & Photo • This slide master design incorporates a default text item for the title  1  and a default text item for the bullet list  2  .

(⬆ see above )  Blank • This slide master design incorporates no default text items, as indicated by the corresponding checkboxes for title  1  and body  2  .

A slide’s default text items are elements of the text item class, inheriting from iWork items of the iWork Suite. The object text property of the text item class represents the text contents of the text item. Change the value of this property, and you change the contents of the text item. Unless specified otherwise, the formatting of a default text item assumes the styling of its related master slide.

NOTE: see the text item topic for details on applying styling to object text.

Text Item Properties (Excerpt from Text Item Class)

The following script demonstrates how to set the content of the default text items of created slides:

Setting Default Text Items Example
Open in AppleScript Editor
01		property thisThemeName : "Black"
02
03		tell application "Keynote"
04		activate
05		try
06		-- GET THE THEME NAMES
07		set the themeNames to the name of every theme
08
09		-- CHECK FOR THEME
10		if thisThemeName is not in the themeNames then
11		error "The theme “" & thisThemeName & "” is not installed on this computer."
12		end if
13
14		-- MAKE NEW PRESENTATION
15		set thisDocument to ¬
16		make new document with properties ¬
17		{document theme:theme thisThemeName, width:1920, height:1080}
18
19		tell thisDocument
20		-- FORMAT THE FIRST SLIDE
21		set the base slide of the first slide to master slide "Title & Subtitle"
22		tell the first slide
23		set the object text of the default title item to "My Presentation"
24		set the object text of the default body item to "Fun Stuff for You to Know"
25		end tell
26
27		-- ADD INFORMATION SLIDE
28		set thisSlide to make new slide with properties ¬
29		{base slide:master slide "Title & Bullets"}
30		tell thisSlide
31		set the object text of the default title item to "Main Point"
32		set the object text of the default body item to ¬
33		"Bullet Point 1" & return & "Bullet Point 2" & return & "Bullet Point 3"
34		end tell
35
36		-- ADD CLOSING SLIDE
37		set thisSlide to make new slide with properties ¬
38		{base slide:master slide "Title - Center"}
39		tell thisSlide
40		set the object text of the default title item to "Thank You!"
41		end tell
42
43		end tell
44
45		-- PLAY THE PRESENTATION
46		start thisDocument from the first slide of thisDocument
47
48		on error errorMessage number errorNumber
49		if errorNumber is not -128 then
50		display alert ("ERROR " & errorNumber) message errorMessage
51		end if
52		end try
53		end tell