Transitions are visual effects that play as a presentation moves from one slide to the next. Subtle or dramatic, transitions really impact how a presentation is received by its audience.

The Keynote scripting dictionary contains no specific transition class. Instead, transitions are implemented as a slide property whose name is transition properties. The value of the transition properties property is an AppleScript record, called transition settings, listing the transition’s parameters and their corresponding values.

To apply a transition to a slide, you simply change the transition settings of the transition properties property (try saying that over and over). You can change one, two, three, or all of the transition settings in one statement.

Here’s an example script statement for setting a transition for a slide:

  set the transition properties of the current slide to {transition effect:wipe, transition duration:2.0, transition delay:0, automatic transition:false}

An here are the relevant excerpts from the Keynote scripting dictionary:

The Transition Properties Property (Excerpt from Slide Class)

Slide Transition Settings

(⬇ see below )  Transition Settings Controls • The transition settings properties match the controls in the Keynote interface: Transition Effect  1  ; Transition Duration  2  ; Automatic Transition  3  ; Transition Delay  4  .

The following example script demonstrates how to apply transitions to existing and created slides:

Slide Transition Example Script
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		try
04		set thisDocument to ¬
05		make new document with properties {document theme:theme "Black", width:1024, height:768}
06
07		tell thisDocument
08
09		tell the first slide
10		set the base slide to master slide "Title & Subtitle" of thisDocument
11		set the transition properties to ¬
12		{transition effect:doorway, transition duration:2.0, transition delay:1.5, automatic transition:true}
13		set the object text of the default title item to "My Presentation"
14		set the object text of the default body item to "Fun Stuff for You to Know"
15		end tell
16
17		set thisSlide to make new slide with properties {base slide:master slide "Title & Bullets"}
18		tell thisSlide
19		set transition properties to ¬
20		{transition effect:dissolve, transition duration:2.0, transition delay:1.5, automatic transition:true}
21		set the object text of the default title item to "Main Topic"
22		set the object text of the default body item to ¬
23		"Bullet Point 1" & return & "Bullet Point 2" & return & "Bullet Point 3"
24		end tell
25		end tell
26
27		-- PLAY THE PRESENTATION
28		start thisDocument from the first slide of thisDocument
29
30		on error errorMessage number errorNumber
31		if errorNumber is not -128 then
32		display alert ("ERROR " & errorNumber) as string message errorMessage
33		end if
34		end try
35		end tell