AppleScript and Keynote: Styling Tables

Styling Tables

The range class is the heart of table scripting support in Keynote. This class contains the essential style and format properties inherited and shared by cells, rows, and columns. What that means is that a script can use any of the range properties listed below when it targets a cell or a row or a column.

range n : A range of cells in a table

elements

contains cells, columns, rows; contained by tables.

properties

alignment ( auto align/‌center/‌justify/‌left/‌right ) : The horizontal alignment of content in the range’s cells.

background color ( color ) : The background color of the range’s cells. Expressed as a list of RGB (Red, Green, Blue) values, from 0 to 65535. For example, the color red is: {65535, 0, 0}

font name ( text ) : The font of the range’s cells. Can be the PostScript name (TimesNewRomanPS-ItalicMT), or the full name (Times New Roman Italic). TIP: Use the Font Book application to get the information about a typeface.

font size ( real ) : The font size (in points) of the range’s cells. ex: 12.5

format ( automatic/‌checkbox/‌currency/‌date and time/‌fraction/‌number/‌percent/‌pop up menu/‌scientific/‌slider/‌stepper/‌text/‌duration/‌rating/‌numeral system ) : The cell format of the range’s cells. Default format is automatic.

name ( text, r/o ) : The range’s coordinates. A text string expressed as colon-delimited cell IDs. ex: "A2:F6"

text color ( color ) : The text color of the range’s cells. Expressed as a list of RGB (Red, Green, Blue) values, from 0 to 65535. For example, the color yellow is: {65535, 65535, 0}

text wrap ( boolean ) : Whether text should wrap in the range’s cells.

vertical alignment ( bottom/‌center/‌top ) : The vertical alignment of content in the range’s cells.

responds to

clear, add column after, add column before, add row above, add row below, merge, unmerge.

In Keynote, and in Keynote scripting, ranges are a collection of contiguous cells. Cells are referenced in scripts by their index or by name.

TIP: For a detailed overview of ranges, see the Numbers ranges documentation on this website.

IMPORTANT TIP: Learn how to save and run your favorite scripts using the system-wide Script Menu.

Create a Styled Table

tell application "Keynote"

activate

tell document 1

set documentWidth to its width

set documentHeight to its height

tell current slide

-- make a new table

set thisTable to ¬

make new table with properties ¬

{header column count:1 ¬

, header row count:1 ¬

, row count:4 ¬

, column count:4 ¬

, name:"ACME Widget Prices"}

tell thisTable

-- set the vertical alignment of all table cells

set vertical alignment of cell range to center

-- set the properties of the headers

tell first row

-- cell properties

set the background color to {26214, 26214, 39321}

set height to 48

-- text properties

set the font name to "Impact"

set the font size to 32

set text color to {65535, 65535, 65535}

set the alignment to center

end tell

tell first column

-- cell properties

set the background color to {26214, 26214, 39321}

set width to 150

-- text properties

set the font name to "Impact"

set the font size to 32

set text color to {65535, 65535, 65535}

set the alignment to right

end tell

-- set header content

set headerColumnTitles to {"", "JAPAN", "USA", "EUROPE"}

set headerRowTitles to {"", "WIDGET A", "WIDGET B", "WIDGET C"}

tell the first row

repeat with i from 1 to the count of cells

set the value of cell i to item i of headerColumnTitles

end repeat

end tell

tell the first column

repeat with i from 1 to the count of cells

set the value of cell i to item i of headerRowTitles

end repeat

end tell

-- set content range properties

set nameOfLastCell to the name of the last cell

set contentRange to ("B2:" & nameOfLastCell)

tell range contentRange

set rangeCellIDs to the name of every cell

-- cell properties

set the background color to {65535, 65535, 65535}

-- text properties

set the font name to "Helvetica"

set the font size to 32

set text color to {0, 0, 0}

set the alignment to center

set format to text

end tell

-- set content range content

set the pricingData to ¬

{"¥121280", "$1495", "€1170", "¥190238", "$2345", "€1835", "¥263656", "$3250", "€2542"}

repeat with i from 1 to the count of rangeCellIDs

tell cell (item i of rangeCellIDs)

set the value to (item i of pricingData)

set format to currency

end tell

end repeat

-- set table properties

set tableWidth to its width

set tableHeight to its height

set position to ¬

{(documentWidth - tableWidth) div 2 ¬

, (documentHeight - tableHeight) div 2}

end tell

(⬇ see below ) A styled table created with the example script:

TOP | CONTINUE

KEYNOTE SCRIPTING

Overview
Automation Utilities

Examples

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.