One of the valuable aspects of the scripting support in Keynote, is AppleScript’s unique ability to manipulate, with a single script statement, the properties of slide objects that are placed throughout the document. For example, you can set the playback settings for every audio clip in a presentation with this script:

Set Global Playback Method for Audio Clips
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		if not (exists document 1) then error number -128
04		set the playbackMethods to {"normal", "loop", "loop back and forth"}
05		set thisValue to ¬
06		choose from list playbackMethods with prompt ¬
07		"Set the playback method of every audio clip to:"
08		if thisValue is false then error number -128
09		tell the front document
10		if thisValue is {"normal"} then
11		set repetition method of ¬
12		every audio clip of every slide to none
13		else if thisValue is {"loop"} then
14		set repetition method of ¬
15		every audio clip of every slide to loop
16		else
17		set repetition method of ¬
18		every audio clip of every slide to loop back and forth
19		end if
20		end tell
21		end tell

Or set the volume of all audio clips to the same setting with this script:

Set Global Volume Setting for Audio Clips
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		if not (exists document 1) then error number -128
04		tell the front document
05		repeat
06		display dialog "Enter a volume (from 0 to 100) to apply to all audio clips in this document:" default answer "100"
07		try
08		set thisValue to the text returned of the result as integer
09		if thisValue is greater than or equal to 0 and ¬
10		thisValue is less than or equal to 100 then exit repeat
11		end try
12		end repeat
13		set clip volume of every audio clip of every slide to thisValue
14		end tell
15		end tell

Make a slight change to the audio clip volume-setting script  (⬆ see above )  and it targets all of the movies in a presentation:  (⬇ see below ) 

Set Global Volume Setting for Movies
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		if not (exists document 1) then error number -128
04		tell the front document
05		repeat
06		display dialog "Enter a volume (from 0 to 100) to apply to all movies in this document:" default answer "100"
07		try
08		set thisValue to the text returned of the result as integer
09		if thisValue is greater than or equal to 0 and ¬
10		thisValue is less than or equal to 100 then exit repeat
11		end try
12		end repeat
13		set movie volume of every movie of every slide to thisValue
14		end tell
15		end tell

Other properties for movies that can be set globally include: locked, position, opacity, width, reflection showing, reflection value, and rotation.

Other properties for audio clips that can be set globally include: locked, and position.

You can even create a script that sets multiple properties for every movie, audio clip, image, shape, line, table, chart, etc., as with this script that sets multiple movie properties globally:

Set Multiple Movie Properties Globally
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		if not (exists document 1) then error number -128
04		tell the front document
05		set documentWidth to its width
06
07		tell every movie of every slide
08		-- unlock first so properties can be changed
09		set locked to false
10		-- change other properties
11		set width to 720
12		set reflection showing to true
13		set reflection value to 80
14		set repetition method to none
15		set movie volume to 75
16		set position to {(documentWidth - 720) div 2, 144}
17		-- set locked property
18		set locked to true
19		end tell
20		end tell
21		end tell