Each installed Keynote theme contains a set of slide designs, called master slides.

The Master Slide Class

Every slide added to a presentation is based upon the one of the parent theme’s master slides. The value of a slide’s base slide property is a reference to the master slide that the created slide was based upon.

The Base Slide Property (Excerpt from Slide Class)

The base slide property can be used in the making of a new slide, as well as be used to change the master slide of an existing slide.

The following script demonstrates how to use the base slide property to create a new slide based upon a specific master slide.

Note that getting a list of the names of the master slides of a document (line 08) returns a list of the names of the master slides of the application theme applied to the document.

New Slide using Master Slide
Open in AppleScript Editor
01		property thisMasterSlideName : "Photo - 3 Up"
02
03		tell application "Keynote"
04		activate
05		tell document 1
06
07		-- GET A LIST OF THE NAMES OF THE MASTER SLIDES OF A DOCUMENT
08		set the masterSlideNames to the name of every master slide
09		--> {"Title & Subtitle", "Photo - Horizontal", "Title - Center", "Photo - Vertical", "Title - Top", "Title & Bullets", "Title, Bullets & Photo", "Bullets", "Photo - 3 Up", "Quote", "Photo", "Blank"}
10
11		-- IF THE MASTER SLIDE IS INCLUDED IN THE CURRENT THEME...
12		-- CREATE A NEW SLIDE WITH MASTER
13		if thisMasterSlideName is in the masterSlideNames then
14		set thisSlide to ¬
15		make new slide with properties {base slide:master slide thisMasterSlideName}
16		end if
17		end tell
18		end tell

To change the master slide applied to a slide, change the value of the slide’s base slide property to a reference to another master slide.

Change the Master Slide of the Current Slide (correct method)
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		try
04		if not (exists document 1) then error number -128
05
06		tell document 1
07
08		set the base slide of the current slide to master slide "Title - Center"
09
10		end tell
11		on error errorMessage number errorNumber
12		if errorNumber is not -128 then
13		display alert ("ERROR " & errorNumber) message errorMessage
14		end if
15		end try
16		end tell

Master slides are an element of the document class, not the slide class. If a reference to a master slide is constructed within a tell block targeting a slide (line 09), the script will error because the constructed reference to the master slide is invalid.  (⬇ see below ) 

Change the Master Slide of the Current Slide (incorrect method)
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		try
04		if not (exists document 1) then error number -128
05
06		tell document 1
07
08		tell the current slide
09		set the base slide to master slide "Title - Center"
10		end tell
11
12		end tell
13		on error errorMessage number errorNumber
14		if errornumber is not -128 then
15		display alert ("ERROR " & errorNumber) message errorMessage
16		end if
17		end try
18		end tell

A solution for using a reference to a master slide within a tell block targeting a slide, is to create the reference OUTSIDE of the slide tell block, store it in a variable, and then use the variable inside the tell block:  (⬇ see below ) 

Change the Master Slide of the Current Slide (alternate method)
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		try
04		if not (exists document 1) then error number -128
05
06		tell document 1
07
08		set thisMasterSlide to master slide "Title - Center"
09		tell the current slide
10		set the base slide to thisMasterSlide
11		end tell
12
13		end tell
14		on error errorMessage number errorNumber
15		if errorNumber is not -128 then
16		display alert ("ERROR " & errorNumber) message errorMessage
17		end if
18		end try
19		end tell