In addition to opening, creating, editing, and closing Keynote documents, Keynote scripting support includes the ability to control the playback of presentations, using the following commands excerpted from the Keynote Compatibility Suite:

Here’s an example script that uses some the playback commands to play, advance, and stop a very short presentation:

Create, Play, Advance, and Stop Presentation
Open in Script Editor
01		tell application "Keynote"
02		activate
03
04		set thisDocument to ¬
05		make new document with properties ¬
06		{document theme:theme "Black", width:1024, height:768}
07
08		tell thisDocument
09		set thisMasterSlide to master slide "Title - Center"
10		tell the first slide
11		set the base slide to thisMasterSlide
12		set the object text of the default title item to "HELLO"
13		end tell
14		set thisSlide to ¬
15		make new slide with properties {base slide:thisMasterSlide}
16		tell thisSlide
17		set the object text of the default title item to "GOODBYE"
18		end tell
19		end tell
20
21		-- begin presenting
22		start thisDocument from the first slide of thisDocument
23		delay 2
24		-- show the next slide or build
25		show next
26		delay 2
27		-- stop the presentation
28		stop thisDocument
29		end tell

TIP: For a more complex playback example that involves a script presenting a document while speaking its presenter notes, check out the Simple Play and Say script on the Presenter Notes page.

Hands-Free Playback Control Scripts

Scripts can be used to control the playing of Keynote documents in many scenarios, such as on a schedule or remotely. Using the intrinsic application properties outlined in the Application section of this documentation, a script can “sense” the current running and playback status of the Keynote application and act accordingly.

The following script will only execute its command if the Keynote application is already running. Running this script will not cause Keynote to activate if it is not already open.

Stop Presentation
Open in Script Editor
01		-- IF KEYNOTE IS ACTIVE AND PLAYING THEN STOP IT
02		if running of application "Keynote" is true then
03		tell application "Keynote"
04		if playing is true then stop the front document
05		end tell
06		end if

And a script for presenting the front document. It will start the presentation only if Keynote is open with a document open. The script will not execute its command if Keynote is already playing a document:

Start Presentation
Open in Script Editor
01		-- IF KEYNOTE IS ACTIVE AND NOT PLAYING THEN START IT
02		if running of application "Keynote" is true then
03		tell application "Keynote"
04		activate
05		try
06		if playing is false then start the front document
07		end try
08		end tell
09		end if

Moving to a Specific Slide

As of Keynote 7.1, you can now set the value of the current slide property of a document.

1) Set the Current Slide
Open in Script Editor
01		tell application id "com.apple.iWork.Keynote"
02		activate
03		tell the front document
04		set the current slide to the first slide
05		end tell
06		end tell

Be aware that the index of slide does not take into account whether a slide is skipped or not:

2) Set the Current Slide
Open in Script Editor
01		tell application id "com.apple.iWork.Keynote"
02		activate
03		tell the front document
04		set the current slide to slide 2
05		end tell
06		end tell

So to ignore any skipped slides, use the slide number property when setting the value of the current slide property:

3) Set Current Slide using Slide Number Property
Open in Script Editor
01		tell application id "com.apple.iWork.Keynote"
02		activate
03		tell the front document
04		set the current slide to the first slide whose slide number is 2
05		end tell
06		end tell

NOTE: If you are using a version of Keynote prior to 7.1, to have a script select a specific slide in the presentation, use one of the sub-routines below:

These sub-routines force the display of a specific slide by creating and deleting a small shape on the slide:

Select Specific Slide Sub-Routines
Open in Script Editor
01		tell application "Keynote"
02		tell the front document
03		my goToSlideByIndex(-1) -- last slide is: -1
04		delay 2
05		my goToSlideByReference(the first slide)
06		end tell
07		end tell
08
09		on goToSlideByIndex(slideIndex)
10		tell application "Keynote"
11		activate
12		tell the front document
13		tell slide slideIndex
14		set thisShape to ¬
15		make new shape with properties ¬
16		{height:12, width:12, position:{0, 0}}
17		delete thisShape
18		end tell
19		end tell
20		end tell
21		end goToSlideByIndex
22
23		on goToSlideByReference(slideReference)
24		tell application "Keynote"
25		activate
26		tell the front document
27		tell slideReference
28		set thisShape to ¬
29		make new shape with properties ¬
30		{height:12, width:12, position:{0, 0}}
31		delete thisShape
32		end tell
33		end tell
34		end tell
35		end goToSlideByReference

The subroutine shown below evokes Keynote’s slide switcher interface::

Select Specific Slide
Open in Script Editor
01		tell application "Keynote"
02		activate
03		if not (exists document 1) then error number -128
04		tell document 1
05		my moveToSlide(last slide)
06		delay 2
07		my moveToSlide(first slide)
08		end tell
09		end tell
10
11		on moveToSlide(thisSlide)
12		tell application "Keynote"
13		tell the front document
14		if thisSlide is last slide then
15		start from slide before last slide
16		tell application "Keynote"
17		show slide switcher
18		move slide switcher forward
19		accept slide switcher
20		stop front document
21		end tell
22		else
23		set thisSlideNumber to slide number of thisSlide
24		start from slide (thisSlideNumber + 1)
25		tell application "Keynote"
26		show slide switcher
27		move slide switcher backward
28		accept slide switcher
29		stop front document
30		end tell
31		end if
32		end tell
33		end tell
34		end moveToSlide

IMPORTANT TIP: Learn how to save and run your favorite scripts using the system-wide Script Menu.