AppleScript and Keynote: Text Item Styling

Text Item Styling

The iWork Text Suite provides the classes and properties for manipulating text in all iWork applications. Using this suite a script can set the font (typeface), size, and color of the object text placed within text items and shapes, as demonstrated in this video of a presentation created by the example script from this page:

Here is the dictionary listing for the iWork Text Suite:

The iWork Text Suite

rich text n pl rich text : This provides the base rich text class for all iWork applications.

elements

contains characters, paragraphs, words

properties

color ( RGB color | text ) : The color of the font. Expressed as an RGB value consisting of a list of three color values from 0 to 65535. ex: Blue = {0, 0, 65535}. In addition, the lowercase names of the following standard colors can be used in place of RGB color value lists: "black", "blue", "brown", "cyan", "green", "magenta", "orange", "purple", "red", "yellow", and "white".

font ( text ) : The name of the font. Can be the PostScript name, such as: “TimesNewRomanPS-ItalicMT”, or display name: “Times New Roman Italic”. TIP: Use the Font Book application get the information about a typeface.

size ( integer ) : The size of the font (in points).

character n [inh. rich text ] : One of some text’s characters.

elements

contained by rich text, paragraphs, words.

paragraph n [inh. rich text ] : One of some text’s paragraphs.

elements

contained by rich text.

word n [inh. rich text ] : One of some text’s words.

elements

contained by rich text, paragraphs.

The following script demonstrates how to apply styling to a text item’s object text:

Styling Text

tell application "Keynote"

activate

set thisDocument to ¬

make new document with properties ¬

{document theme:theme "Black", width:1920, height:1080}

tell thisDocument

set documentHeight to its height

set the base slide of the first slide to master slide "Blank"

tell slide 1

-- create a new text item

set thisDisplayText to "Abracadabra"

set thisTextItem to ¬

make new text item with properties {object text:thisDisplayText}

tell thisTextItem

-- set type size

set the size of its object text to 144

-- set typeface

set the font of its object text to "Zapfino"

-- adjust its vertical positon

copy its position to {currentHorizontal, currentVertical}

set its position to {currentHorizontal, documentHeight div 3}

end tell

duplicate slide 1 to after slide 1

tell slide 2

set thisTextItem to its first text item

tell thisTextItem

-- set color

repeat with i from 1 to the length of thisDisplayText

set thisRGBColorValue to my generateRandomRGBColorValue()

set the color of character i of object text to thisRGBColorValue

end repeat

end tell

set the transition properties of the first slide to ¬

{transition effect:sparkle, transition duration:2.0 ¬

, transition delay:1.0, automatic transition:true}

end tell

start thisDocument from first slide of thisDocument

end tell

on generateRandomRGBColorValue()

set RedValue to random number from 0 to 65535

set GreenValue to random number from 0 to 65535

set BlueValue to random number from 0 to 65535

return {RedValue, GreenValue, BlueValue}

end generateRandomRGBColorValue

TIP: For examples of styling the object text of a shape, select the Shape topic from the Navigation Menu at the top right of this page.

TOP | CONTINUE

KEYNOTE SCRIPTING

Overview
Automation Utilities

Examples

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.