All iWork applications share a common set of elements: audio clips, movies, images, lines, shapes, tables, charts, and text items. And in each application, the controls and behaviors for each of the common elements are exactly the same, most of the time.

A text item is designed with a slightly different behavior than text boxes which also contain text but display eight adjustment handles. Given that it is a presentation program, the use of text in Keynote is nearly always for display (titles, subtitles, banners, headlines) or for minimal description (bullets, labels). It’s difficult to imagine a reason for laying out a long text document in Keynote (although it is possible).

The behavior of text items added with the Text button or Insert > Text Box menu, or via a script, are different than the text items (boxes) designated as the default title item or the default body item that display eight adjustment handles. These added text items offer no controls for adjusting vertical sizing, and by default, will horizontally scale to fit the text they contain.

NOTE: In Keynote and the other iWork applications, “simplified” text items can be converted to text boxes (showing eight handles) by adjusting their column count (in the Format > Text > Layout sidebar) from 1 to 2 and then back to 1, or by selecting the text item, choosing Format > Shapes and Lines > Make Editable, and then de-selecting the text item. Also note that the current Keynote scripting dictionary does not provide a means to remove the simplified behavior.

(⬆ see above ) A slide showing the two types of text items in Keynote:  1  the slide’s default title item and  2  default body item, and  3  and an added text item with simplified controls.

Whether they are visible or not, every Keynote slide incorporates two built-in default text items: one for the slide title  1   (⬇ see below )  and one for the slide body  2 . For some slides, the default body item are formatted as bullets  3 . The visibility of these text items is determined by the state of the Appearance checkboxes in the Slide Layout pane of the Format tab.

Here’s a script demonstrating how to set the text for the contents of a slide’s default text items:

Default Text Items
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		set thisDocument to ¬
04		make new document with properties {document theme:theme "Black"}
05		tell thisDocument
06		set the base slide of the first slide to master slide "Title & Subtitle"
07		tell first slide
08		-- set the title
09		set the object text of the default title item to "TITLE"
10		-- set the subtitle
11		set the object text of the default body item to "BODY SUBTITLE"
12		end tell
13		set thisSlide to ¬
14		make new slide with properties {base slide:master slide "Title & Bullets"}
15		tell thisSlide
16		-- set the title
17		set the object text of the default title item to "TITLE"
18		-- set a bullet list
19		set the object text of the default body item to ¬
20		"Bullet Point 1" & return & "Bullet Point 2" & return & "Bullet Point 3"
21		end tell
22		end tell
23		end tell

For information about how default text items are incorporated into slide designs, see the section in the Slide topic about default text items.

The example script below demonstrates the behaviors associated with scripting a text item with simplified controls.

Simplified Text Item Behaviors
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		set thisDocument to ¬
04		make new document with properties ¬
05		{document theme:theme "Black", width:1024, height:768}
06		tell thisDocument
07		set base slide of the first slide to master slide "Blank"
08		set the documentWidth to its width
09		tell the first slide
10		-- Make simple text item
11		set thisTextItem to ¬
12		make new text item with properties {object text:"HELLO"}
13		delay 5
14		-- Change the object text, text item expands, stays centered
15		set object text of thisTextItem to "HOW NOW BROWN COW"
16		delay 5
17		-- Change object text to trigger default wrapping and sizing behavior
18		set object text of thisTextItem to "Integer posuere erat a ante venenatis dapibus posuere velit aliquet. Praesent commodo cursus magna, vel scelerisque nisl consectetur et. Cras justo odio, dapibus ac facilisis in, egestas eget quam. Integer posuere erat a ante venenatis dapibus posuere velit aliquet. Sed posuere consectetur est at lobortis. Cras mattis consectetur purus sit amet fermentum."
19		delay 5
20		-- Change the width of the text item. Note item does not auto-center.
21		set the width of thisTextItem to (documentWidth * 0.75)
22		delay 5
23		-- Get the current position of the text item
24		copy the position of thisTextItem to {thisHorizontalValue, thisVerticalValue}
25		-- Adjust postion to be centered, keeping the current vertical offset.
26		set position of thisTextItem to {(documentWidth * 0.25) div 2, thisVerticalValue}
27		end tell
28		end tell
29		end tell

(⬇ see below ) The example creates a new item. The text item is created using the theme’s default paragraph style (caption in this example) which determines font, color, text size, and text alignment (centered) for the simplified text item. In addition, the text item is automatically centered horizontally and vertically in the slide:

(⬇ see below ) The script changes the contents of the text item and the text item shrinks to fit the new width of the text:

(⬇ see below ) The script replaces the shorter text contents with a paragraph that is longer than the width of the slide. The text item automatically expands to fit the width of the slide, then wraps the paragraph to be multiple lines. In addition, the simplified text item remains vertically centered on the slide:

(⬇ see below ) The script then adjusts the width of the text item to be 3/4 the width of the slide. Note that the slide does not auto-center horizontally:

(⬇ see below ) The script then horizontally centers the text item on the slide , using the text item’s current vertical positon: