AppleScript and Numbers: Images

Images

When it comes to making convincing documents, the old adage of “A picture is worth a thousand words” is sacrosanct. Nothing gets the point across like a compelling image. Not to worry, the AppleScript support in Numbers provides ample controls for creating unforgettable documents.

Scripting Terminology for Images

Documents created by any of the iWork applications, Pages, Numbers, or Keynote, can incorporate a common set of elements, including images, shapes, lines, tables, charts, movies, and audio clips. To AppleScript and the built-in scripting support of the iWork applications, these elements are considered iWork Items, and share a common set of properties, detailed in the iWork Item class from the iWork Suite:

The iWork Suite iWork item Class

iWork item n [inh. iWork item ] : An item which supports formatting.

elements

contained by slides, document.

properties

height ( integer ) : The height of the iWork item.

locked ( boolean ) : Whether the object is locked.

parent ( iWork container r/o ) : The iWork container containing this iWork item.

position ( point ) : The horizontal and vertical coordinates of the top left point of the iWork item.

width ( integer ) : The width of the iWork item.

responds to

delete, exists

The properties in the iWork item class can be accessed and changed for any of the common iWork elements. For example, a script can get or set the position of a movie, or image, or shape, or any of the common elements.

In addition to sharing a common set of properties with the other iWork elements, each iWork element has its own set of properties, particular to that element. For example, the element-specific properties of an image are detailed in its dictionary listing, found in the iWork Suite: (⬇ see below )

The iWork Suite image Class

image n [inh. iWork item ] : An image container.

elements

contained by slides, document.

properties

description ( text ) : Text associated with the image, can be read aloud by VoiceOver.

file ( file , r/o) : The image file. This property is a required parameter when used with the make command to create a new image item on a slide. Use the file name property to retrieve the name of the image, or to replace the currently displayed image.

file name ( text or file ) : When used with the get command, the value of this property is the file name of the image file currently displayed in the image container. When this property is used with the set command, the value of the property is a file reference (in HFS alias format) to the image file to be used to replace the currently displayed image.

opacity ( integer ) : The opacity of the image, in percent (0 to 100).

reflection showing ( boolean ) : Is the image displaying a reflection?

reflection value ( integer ) : The percentage of reflection of the image, from 0 (none) to 100 (full).

rotation ( integer ) : The rotation of the image item, in degrees from 0 to 359.

responds to

delete, exists, make

Here’s an example script that creates a new document with a new table overlaid on a decorative background image. It incorporates the use of many of the image properties, as well as those for text items.

Layout with Decorative Background Image

property defaultImageWidth : 792 -- in points

property defaultTypeSize : 36

tell application "Numbers"

activate

-- CREATE THE DOCUMENT

set thisDocument to make new document with properties ¬

{document template:template "Blank"}

tell thisDocument

-- GET THE RANDOM IMAGE

copy my getRandomDesktopPicture() to {thisImageFileName, thisImageFile}

-- trim the file extension (.jpg) from the file name

set thisImageName to text 1 thru -5 of thisImageFileName

-- ADD THE IMAGE FILE TO THE FIRST SLIDE

tell the active sheet

-- CLEAR THE CANVAS

delete every table

-- IMPORT THE DESKTOP IMAGE

set thisImage to ¬

make new image with properties {file:thisImageFile}

tell thisImage

set width to defaultImageWidth

set position to {0, 0}

set opacity to 100

set imageWidth to its width

set imageHeight to its height

copy position of it to {imageHPosition, imageVPositon}

end tell

-- CREATE A TEXT OVERLAY DISPLAYING IMAGE NAME

set thisTitleBox to ¬

make new text item with properties {object text:thisImageName}

tell thisTitleBox

tell its object text

set font to "Times New Roman Italic"

set size to defaultTypeSize

set color of it to {65535, 65535, 65535}

end tell

set textItemHeight to its height

set textItemWidth to its width

copy position of it to {textHPosition, textVPosition}

set newHPosition to imageHPosition + ((imageWidth div 2) - (textItemWidth div 2))

set newVPosition to imageVPositon + 24

set position of it to {newHPosition, newVPosition}

end tell

-- CREATE AN OVERLAY TABLE

set thisTable to make new table

tell thisTable

set the background color of cell range to {65535, 65535, 65535}

set tableWidth to its width

set tableHeight to its height

set newHPosition to imageHPosition + ((imageWidth div 2) - (tableWidth div 2))

set newVPosition to imageVPositon + (imageHeight - tableHeight - 36)

set position of it to {newHPosition, newVPosition}

end tell

on getRandomDesktopPicture()

-- GET A RANDOM IMAGE FROM THE DESKTOP pictures folder

set desktopPicturesFolder to (path to desktop pictures folder)

set the imageFileNames to every paragraph of ¬

(do shell script "ls " & quoted form of POSIX path of desktopPicturesFolder)

--> RETURNS: {"Abstract.jpg", "Antelope Canyon.jpg", "Bahamas Aerial.jpg", etc.}

set thisImageFileName to some item of the imageFileNames

--> RETURNS: "Mountain Range.jpg"

set thisImageFile to ((desktopPicturesFolder as string) & thisImageFileName) as alias

--> RETURNS: alias "Macintosh HD:Library:Desktop Pictures:Mountain Range.jpg"

return {thisImageFileName, thisImageFile}

end getRandomDesktopPicture

TOP | CONTINUE

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.