Documents created by any of the iWork applications, Pages, Numbers, or Numbers, can incorporate a common set of elements, including images, shapes, lines, tables, charts, movies, audio clips, and text items. To AppleScript and the built-in scripting support of the iWork applications, these elements are considered iWork Items, and share a common set of properties, detailed in the iWork Item class from the iWork Suite:

The iWork Suite iWork item Class

The properties in the iWork item class can be accessed and changed for any of the common iWork elements. For example, a script can get or set the position of a text item, or image, or shape, or any of the common elements.

In addition to sharing a common set of properties with the other iWork elements, each iWork element has its own set of properties, particular to that element. For example, the element-specific properties of a text item are detailed in its dictionary listing, found in the iWork Suite:  (⬇ see below ) 

The iWork Suite text item Class

The object text property is used to control the contents of a text item, and will be covered in detail in this section.

NOTE: A text alignment property is not yet implemented in the current scripting dictionary.

In the iWork applications, there are two container types for text items:

 1  Labels • Are the default text item created using scripts, the text toolbar button, or the Insert menu. Label containers have two horizontal adjustment handles and automatically wrap vertically to fit their object text.

 2  Boxes • Are text items with eight adjustment handles, allowing them to be sized both vertically and horizontally, regardless of their object text. NOTE: a text item label can be converted to a text item box by adjusting its column count to 2 and then back to 1.

An example script that creates a title and subtitle text items centered on the document page:

New Document with Title & Subtitle
Open in AppleScript Editor
01		-- U.S. Letter page dimensions in points
02		-- (reverse for horizontal layout)
03		property pageWidth : 612
04		property pageHeight : 792
05
06		property titleTypeSize : 48
07		property titleTypeface : "Times New Roman"
08		property titleText : "Wind Power in America"
09		property titleVerticalOffset : 72
10
11		property subtitleTypeSize : 24
12		property subtitleTypeface : "Times New Roman Italic"
13		property subtitleText : "A 20-year overview of the use of domestic wind power"
14
15		tell application "Numbers"
16		activate
17
18		-- CREATE NEW DOCUMENT USING ONE OF THE VERTICAL TEMPLATES
19		set thisDocument to ¬
20		make new new document with properties ¬
21		{document template:template "Checklist"}
22
23		tell thisDocument
24		tell active sheet
25		-- RESET SHEET TITLE
26		set its name to "Untitled"
27
28		-- CLEAR THE CANVAS
29		delete every iWork item
30
31		-- ADD TITLE TEXT ITEM
32		set titleTextItem to ¬
33		make new text item with properties {object text:titleText}
34		-- FORMAT THE TITLE TEXT ITEM
35		tell titleTextItem
36		tell its object text
37		set font to titleTypeface
38		set size to titleTypeSize
39		end tell
40		set titleWidth to its width
41		set titleHeight to its height
42		set position to ¬
43		{(pageWidth - titleWidth) div 2, titleVerticalOffset}
44		end tell
45
46		-- ADD SUBTITLE TEXT ITEM
47		set subtitleTextItem to ¬
48		make new text item with properties {object text:subtitleText}
49		-- FORMAT THE SUBTITLE TEXT ITEM
50		tell subtitleTextItem
51		tell its object text
52		set font to subtitleTypeface
53		set size to subtitleTypeSize
54		end tell
55		set subtitleWidth to its width
56		set position to ¬
57		{(pageWidth - subtitleWidth) div 2 ¬
58		, (titleVerticalOffset + titleHeight)}
59		end tell
60		end tell
61		end tell
62		end tell

(⬇ see below ) The Print Setup window for A Numbers document with centered title and subtitle. The page size is set for U.S. Letter, and the left and right margins are set to 0.