The cell is a fundamental element, providing the building-blocks that are combined to create rows, columns, and tables. As with rows and columns, the cell inherits the properties of the range class, including those that provide styling and formatting.

The properties unique to the cell class are: column, row, and value. The value of the row and column properties are references to the row or column that contains the cell. The value of the value property is the contents of the cell, expressed in a number, text, date, or true/false format.

The combination of the cell’s inherited and unique properties provides the mechanism for accomplishing interesting applications, such as highlighting the intersection of a selected cell.

This script, based upon the script template provided on the table editing page, uses both the unique and inherited properties of a cell, to style an existing table, so that a specific cell or cells are highlighted as an intersection.

Highlight Intersection
Open in AppleScript Editor
01		tell application "Numbers"
02		activate
03		try
04		if not (exists document 1) then error number 1000
05		tell document 1
06		try
07		tell active sheet
08		set the selectedTable to ¬
09		(the first table whose class of selection range is range)
10		end tell
11		on error
12		error number 1001
13		end try
14
15		-- set the default colors for intersection
16		set the intersectionbackgroundColor to {65535, 65535, 65535} -- white
17		set the intersectiontextColor to {0, 0, 0} -- black
18
19		-- set the default colors for parent columns/rows
20		set the backgroundColor to {52428, 26214, 65535}
21		set the textColor to {65535, 65535, 65535}
22
23		tell selectedTable
24		set the selectionRange to the selection range
25
26		-- get the parent columns and rows of the selection
27		set theseColumns to the columns of selection range
28		set theseRows to the rows of selection range
29
30		-- format the parent columns
31		repeat with i from 1 to the count of theseColumns
32		set thisColumn to item i of theseColumns
33		set the background color of thisColumn to backgroundColor
34		set the text color of thisColumn to textColor
35		set the font name of thisColumn to "Helvetica"
36		set the font size of thisColumn to 15
37		end repeat
38
39		-- format the parent rows
40		repeat with i from 1 to the count of theseRows
41		set thisRow to item i of theseRows
42		set the background color of thisRow to backgroundColor
43		set the text color of thisRow to textColor
44		set the font name of thisRow to "Helvetica"
45		set the font size of thisRow to 15
46		end repeat
47
48		-- format the intersection
49		set the background color of selectionRange to intersectionbackgroundColor
50		set the text color of selectionRange to intersectiontextColor
51		end tell
52		end tell
53		on error errorMessage number errorNumber
54		if errorNumber is 1000 then
55		set alertString to "MISSING RESOURCE"
56		set errorMessage to ¬
57		"Please create or open a document before running this script."
58		else if errorNumber is 1001 then
59		set alertString to "SELECTION ERROR"
60		set errorMessage to ¬
61		"Please select a table before running this script."
62		else
63		set alertString to "EXECUTION ERROR"
64		end if
65		display alert alertString message errorMessage buttons {"Cancel"}
66		error number -128
67		end try
68		end tell

To use the script, simply select one or more contiguous cells, and run the script. The parent rows and columns of the selected cells will be colorized.

TIP: use the Table to Image script to save the table as an image file to share the highlighted table with others.