The template class is a top-level element of the Numbers application. It contains no other elements, and has two properties. The choice of template determines the overall look of a document.

The Numbers Suite Template Class

The pages of this topic section detail how to access the properties of all installed templates, all application templates, and all user-created templates. Example scripts detail how to create documents using a specified template.

The id property of a template is a text string that uniquely identifies the template to the Numbers application.

The following script retrieves the id of every template:

IMPORTANT TIP: Learn how to save and run your favorite scripts using the system-wide Script Menu.

Get the ID of Every Template
Open in AppleScript Editor
01		tell application "Numbers"
02		get the id of every template
03		--> RETURNS: {"Application/Blank/Traditional", "Application/08_Checklist/Traditional", "Application/08_SumChecklist/Traditional", "Application/01_Simple_Charts/Traditional", "Application/05_Personal_Budget/Traditional", "Application/05_Personal_Savings/Traditional", "Application/05_Net_Worth/Traditional", "Application/05_Retirement_Savings/Traditional", "Application/04_LoanComparison/Traditional", "Application/04_MortgageCalculator/Traditional", "Application/07_Calendar/Traditional", "Application/07_Schedule/Traditional", "Application/01_Running_Log/Traditional", "Application/08_Home_Improvement/Traditional", "Application/TeamOrganization/Traditional", "Application/09_Baby_Record/Traditional", "Application/08_Travel_Planner/Traditional", "Application/08_Party_Planner/Traditional", "Application/04_Meal_Planner/Traditional", "Application/04_Recipe/Traditional", "Application/02_EmployeeSchedule/Traditional", "Application/02_Invoice/Traditional", "Application/02_ROI/Traditional", "Application/02_Financial_Statement/Traditional", "Application/02_BreakEvenAnalysis/Traditional", "Application/06_AttendanceSheet/Traditional", "Application/06_GradeBook/Traditional", "Application/04_GPA/Traditional", "Application/06_Dice_Lab/Traditional", "Application/06_Correlation_Lab/Traditional", "Application/05_School_Savings/Traditional", "User/F7CFF09C-4D49-4F40-9DBF-8AA822EB9322"}
04		end tell

In Numbers, there are two kinds of templates: those that come with the application, and those created and saved by the user.

The id for an application template begins with the term: “Application”

"Application/Blank/Traditional"

The id for a user-created template begins with the term: “User”

"User/C34CF6EC-2BC4-4DE0-9A3B-35BA88F15B2C"

The design of template ids allows for specialized searches, as shown later on this page.

The name property of a template is a text string that is the name of the template as it is displayed in the Numbers application interface.

The following script retrieves the name of every template, including user-created templates:

Get the Name of Every Template
Open in AppleScript Editor
01		tell application "Numbers"
02		get the name of every template
03		--> RETURNS: {"Blank", "Checklist", "Checklist Total", "Charting Basics", "Personal Budget", "Personal Savings", "Net Worth", "Retirement Savings", "Loan Comparison", "Mortgage Calculator", "Calendar", "Schedule", "Running Log", "Home Improvement", "Team Organization", "Baby Record", "Travel Planner", "Party Planner", "Meal Planner", "Recipe", "Employee Schedule", "Invoice", "Return on Investment", "Financials", "Break-Even Analysis", "Attendance", "Grade Book", "GPA", "Probability Lab", "Correlation Project", "School Savings", "ACME Widget Template"}
04		end tell

A script can use the unique design of the id property to retrieve only templates of a specific type.

The following script retrieves the name of every application template:

Get the Name of All Application Templates
Open in AppleScript Editor
01		tell application "Numbers"
02		set applicationTemplateNames to the name of every template whose id of it begins with "Application/"
03		--> RETURNS: {"Blank", "Checklist", "Checklist Total", "Charting Basics", "Personal Budget", "Personal Savings", "Net Worth", "Retirement Savings", "Loan Comparison", "Mortgage Calculator", "Calendar", "Schedule", "Running Log", "Home Improvement", "Team Organization", "Baby Record", "Travel Planner", "Party Planner", "Meal Planner", "Recipe", "Employee Schedule", "Invoice", "Return on Investment", "Financials", "Break-Even Analysis", "Attendance", "Grade Book", "GPA", "Probability Lab", "Correlation Project", "School Savings"}
04		end tell

The following script retrieves the name of every user template:

Get the Name of All User Templates
Open in AppleScript Editor
01		tell application "Numbers"
02		set userTemplateNames to the name of every template whose id of it begins with "User/"
03		--> RETURNS: {"ACME Widget Template"}
04		end tell

A principle of good “defensive” script writing is to never assume anything, always check for resources. Here’s a script that checks to make sure a specific template is intalled:

Check for Template
Open in AppleScript Editor
01		property thisTemplateName : "Travel Expense Report"
02
03		tell application "Numbers"
04		activate
05		try
06		-- GET THE TEMPLATE NAMES
07		set the templateNames to the name of every template
08
09		-- CHECK FOR TEMPLATE
10		if thisTemplateName is not in the templateNames then
11		error "The template “" & thisTemplateName & "” is not installed on this computer."
12		end if
13
14		on error errorMessage number errorNumber
15		if errorNumber is not -128 then
16		display alert ("ERROR " & errorNumber) message errorMessage
17		end if
18		end try
19		end tell