AppleScript and Keynote: Table & Charts from Shared Data

Table & Charts from Shared Data

A compelling reason for using automation is its ability to quickly display data in a variety of formats. For example, a single data set can be displayed as a table, or as a chart, or as both — in seconds. With the AppleScript support in Keynote, connecting data to display becomes a hands-free process, as demonstrated by the following script that generates a presentation containing slides showing a table and multiple charts from a single data set: (⬇ see below )

Table & Charts From Shared Data

tell application "Keynote"

-- STOP ANY PLAYING PRESENTATION

if playing is true then stop the front document

activate

-- MAKE NEW DOCUMENT

set thisDocument to make new document with properties ¬

{height:764, width:1024, document theme:theme "Black"}

tell thisDocument

-- THE SOURCE DATA

set rowNames to {"ROW A", "ROW B", "ROW C"}

set columnNames to {"COL 1", "COL 2", "COL 3", "COL 4"}

set rowCount to count of rowNames

set columnCount to count of columnNames

set thisData to my generateRandomData(rowCount, columnCount)

-- THE EXISTING SLIDE

tell slide 1

set the base slide to master slide "Title - Top" of thisDocument

set the object text of the default title item to "Table"

-- MAKE A TABLE FROM DATA

-- include headers in counts

set the rowCount to (the count of thisData) + 1

set the columnCount to (the count of (item 1 of thisData)) + 1

-- make the table

set thisTable to ¬

make new table with properties ¬

{row count:rowCount, column count:columnCount}

-- populate the table

tell thisTable

-- column headers

repeat with i from 1 to the the count of the columnNames

set the value of cell (i + 1) of row 1 to item i of columnNames

end repeat

-- row headers

repeat with i from 1 to the the count of the rowNames

set the value of cell (i + 1) of column 1 to item i of rowNames

end repeat

-- insert data, which is assumed to be grouped by rows

repeat with q from 1 to the count of thisData

set thisDataItem to item q of thisData

repeat with i from 1 to the the count of thisDataItem

set the value of cell (i + 1) of row (q + 1) to item i of thisDataItem

end repeat

end tell

-- MAKE NEW SLIDE

set thisSlide to make new slide with properties {base slide:master slide "Title - Top"}

tell thisSlide

set the object text of the default title item to "Grouped by Column"

-- MAKE A CHART FROM DATA (GROUPED BY COLUMN)

add chart row names rowNames column names columnNames ¬

data thisData type line_2d group by chart column

end tell

-- MAKE NEW SLIDE

set thisSlide to make new slide with properties {base slide:master slide "Title - Top"}

tell thisSlide

set the object text of the default title item to "Grouped by Row"

-- MAKE A CHART FROM DATA (GROUPED BY ROW)

add chart row names rowNames column names columnNames ¬

data thisData type line_2d group by chart row

end tell

-- PLAY THE PRESENTATION

start thisDocument from first slide of thisDocument

end tell

-- SUB-ROUTINE FOR GENERATING RANDOM ROW/COLUMN DATA

on generateRandomData(rowCount, columnCount)

set thisData to {}

repeat rowCount times

set thisDataItem to {}

repeat columnCount times

set thisValue to random number from 0 to 100

set the end of thisDataItem to thisValue

end repeat

set the end of thisData to thisDataItem

end repeat

return thisData

end generateRandomData

(⬇ see below ) The slides created by the script:

TOP | CONTINUE

KEYNOTE SCRIPTING

Overview
Automation Utilities

Examples

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.