AppleScript and Keynote: Exporting Documents

Exporting Documents

Exporting Keynote documents is done using the export command from the Keynote Suite.

export v : Export a presentation to another file(s).

export document : The presentation to export.

to (file ) : A reference to the file (folder) to be created. When exporting images or HTML, a new folder, containing the exported items, is created instead of a file.

as ( HTML / ‌QuickTime movie /‌ PDF /‌ slide images / ‌Microsoft PowerPoint /‌ Keynote 09 ) : The format in which the document is to be exported.

[ with properties (export options ) ] : An AppleScript record containing property:value pairings for the initial values for properties of the exported object.

export options n : The export options for the Keynote export command.

properties

all stages ( boolean ) : Include each stage of the builds.

borders ( boolean ) : Add borders around the slides.

compression factor ( real ) : Compressed image quality, ranging from 0.0 (maximum compression, lowest quality) to 1.0 (lossless compression, highest quality). This option only pertains to JPEG format images.

date ( boolean ) : Include the current date.

export style ( IndividualSlides /‌ SlideWithNotes /‌ Outline /‌ Handouts ) : Indicate whether to include notes, etc. (applies only to printing)

image format ( JPEG /‌ PNG /‌ TIFF ) : The format to use for the resulting images.

movie format ( small /‌ medium /‌ large ) : The desired size for exported movie: 360P, 540P, 720P

password ( text ) : The password to use when the exported PDF is encrypted.

password hint ( text ) : The password hint.

PDF image quality ( good/better/best ) : (Keynote 6.6) The quality of the images in the exported PDF file.

rawKPF ( boolean ) : Should the document be exported in raw KPF?

skipped slides ( boolean ) : Should the exported document include skipped slides?

slide numbers ( boolean ) : Should the exported document include slide numbers?

NOTE: The Keynote version 6.6 scripting dictionary includes options for indicating the quality of images used when the presentation is exported as a PDF file.

Shortcuts to the script examples:

Export to Images, Export to Movie, Export to HTML, Export to Microsoft PowerPoint, Export to PDF

Export to Images

Here’s an example script that exports the front document to image files.

Export Slides to Images

property exportFormat : "PNG" -- "TIFF" "JPEG" "PNG"

property includeSkippedSlides : false

property compressionFactor : 1.0

-- THE DESTINATION FOLDER

-- (see the "path" to command in the Standard Additions dictionary for other locations, such as documents folder, movies folder, desktop folder)

set the defaultDestinationFolder to (path to pictures folder)

tell application "Keynote"

activate

try

if playing is true then tell the front document to stop

if not (exists document 1) then error number -128

-- DERIVE NAME FOR NEW FOLDER FROM NAME OF THE FRONT DOCUMENT

set documentName to the name of the front document

if documentName ends with ".key" then ¬

set documentName to text 1 thru -5 of documentName

-- CREATE AN EXPORT DESTINATION FOLDER

-- IMPORTANT: IT’S ADVISED TO ALWAYS CREATE a NEW DESTINATION FOLDER, AS THE CONTENTS OF ANY TARGETED FOLDER WILL BE OVERWRITTEN

tell application "Finder"

set newFolderName to documentName

set incrementIndex to 1

repeat until not (exists folder newFolderName of defaultDestinationFolder)

set newFolderName to documentName & "-" & (incrementIndex as string)

set incrementIndex to incrementIndex + 1

end repeat

set the targetFolder to ¬

make new folder at defaultDestinationFolder with properties ¬

{name:newFolderName}

set the targetFolderHFSPath to targetFolder as string

end tell

-- EXPORT THE DOCUMENT

if exportFormat is "PNG" then

-- EXPORT THE FRONT DOCUMENT TO PNG IMAGES

export front document as slide images to file targetFolderHFSPath with properties ¬

{image format:PNG, skipped slides:includeSkippedSlides}

else if exportFormat is "JPEG" then

-- EXPORT THE FRONT DOCUMENT TO JPEG IMAGES

export front document as slide images to file targetFolderHFSPath with properties ¬

{image format:JPEG, skipped slides:includeSkippedSlides ¬

, compression factor:compressionFactor}

else if exportFormat is "TIFF" then

-- EXPORT THE FRONT DOCUMENT TO TIFF IMAGES

export front document as slide images to file targetFolderHFSPath with properties ¬

{image format:TIFF, skipped slides:includeSkippedSlides ¬

, compression factor:compressionFactor}

end if

on error errorMessage number errorNumber

display alert "EXPORT PROBLEM" message errorMessage

error number -128

end try

end tell

-- OPEN THE DESTINATION FOLDER

tell application "Finder"

activate

open the targetFolder

end tell

TIP: To see how to convert the previous script to a droplet, check out the Movie Export Droplet example on this website.

Export to Movie

Here’s a script for exporting the Keynote presentation to a movie file:

Export Front Document to Movie

property movieFileExtension : "m4v"

-- THE DESTINATION FOLDER

-- (see the "path" to command in the Standard Additions dictionary for other locations, such as documents folder, pictures folder, desktop folder)

set the defaultDestinationFolder to (path to movies folder)

tell application "Keynote"

activate

try

if playing is true then tell the front document to stop

if not (exists document 1) then error number -128

-- DERIVE NAME AND FILE PATH FOR NEW MOVIE FILE

set documentName to the name of the front document

if documentName ends with ".key" then ¬

set documentName to text 1 thru -5 of documentName

tell application "Finder"

set newMovieFileName to documentName & "." & movieFileExtension

set incrementIndex to 1

repeat until not (exists document file newMovieFileName of defaultDestinationFolder)

set newMovieFileName to ¬

documentName & "-" & (incrementIndex as string) & "." & movieFileExtension

set incrementIndex to incrementIndex + 1

end repeat

end tell

set the targetFileHFSpath to (defaultDestinationFolder as string) & newMovieFileName

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

export front document to file targetFileHFSPath ¬

as QuickTime movie with properties {movie format:large}

end timeout

on error errorMessage number errorNumber

display alert "EXPORT PROBLEM" message errorMessage

error number -128

end try

end tell

-- SHOW THE NEW MOVIE FILE

tell application "Finder"

activate

reveal document file targetFileHFSPath

end tell

Export to HTML

This script exports the frontmost Keynote presentation to a folder containing all the HTML materials for a self-contained website.

TIP: Using the following Export to HTML script, a presentation containing audio clips, like the one created by the Render Presenter Notes script on this website, can be exported to HTML content, and placed on a server to become an online presentation! See it for yourself!

Export to HTML Content

-- THE DESTINATION FOLDER

-- (see the "path" to command in the Standard Additions dictionary for other locations, such as pictures folder, movies folder, sites folder, desktop folder)

set the defaultDestinationFolder to (path to documents folder)

tell application "Keynote"

activate

try

if playing is true then tell the front document to stop

if not (exists document 1) then error number -128

-- DERIVE NAME FOR NEW FOLDER FROM NAME OF THE FRONT DOCUMENT

set documentName to the name of the front document

if documentName ends with ".key" then ¬

set documentName to text 1 thru -5 of documentName

-- CREATE AN EXPORT DESTINATION FOLDER

-- IMPORTANT: IT’S ADVISED TO ALWAYS CREATE a NEW DESTINATION FOLDER, AS THE CONTENTS OF ANY TARGETED FOLDER WILL BE OVERWRITTEN

tell application "Finder"

set newFolderName to documentName

set incrementIndex to 1

repeat until not (exists folder newFolderName of defaultDestinationFolder)

set newFolderName to documentName & "-" & (incrementIndex as string)

set incrementIndex to incrementIndex + 1

end repeat

set the targetFolder to ¬

make new folder at defaultDestinationFolder with properties ¬

{name:newFolderName}

set the targetFolderHFSPath to targetFolder as string

end tell

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

export front document as HTML to file targetFolderHFSPath

end timeout

on error errorMessage number errorNumber

display alert "EXPORT PROBLEM" message errorMessage

error number -128

end try

end tell

-- OPEN THE DESTINATION FOLDER

tell application "Finder"

open the targetFolder

end tell

-- VIEW THE PRESENTATION

tell application "Safari"

activate

open file (targetFolderHFSPath & "index.html")

end tell

Export to Microsoft PowerPoint

This version of the export script will export the front Keynote presentation to a Microsoft PowerPoint file. Presentations containing media, such as movies and/or audio files, must be exported to the newer file format (PPTX), while presentations without media can be exported to the Microsoft PowerPoint 1997-2003 compatible format (PPT).

Export to Microsoft PowerPoint

-- Export the presentation as a MSPowerPoint 1997-2003 compatible file?

property attemptCompatibleExport : true

-- THE DESTINATION FOLDER

-- (see the "path to" command in the Standard Additions dictionary for other locations, such as movies folder, pictures folder, desktop folder)

set the defaultDestinationFolder to (path to documents folder)

tell application "Keynote"

activate

try

if playing is true then tell the front document to stop

if not (exists document 1) then error number -128

tell the front document

set documentName to its name

if documentName ends with ".key" then ¬

set documentName to text 1 thru -5 of documentName

set movieCount to the count of every movie of every slide

set audioClipCount to the count of every audio clip of every slide

end tell

-- Check for media. Presentations containing media must be saved as PPTX

if movieCount is 0 and audioClipCount is 0 and attemptCompatibleExport is true then

set MicrosoftPowerPointFileExtension to "ppt"

else

set MicrosoftPowerPointFileExtension to "pptx"

end if

tell application "Finder"

set newExportItemName to documentName & "." & MicrosoftPowerPointFileExtension

set incrementIndex to 1

repeat until not (exists document file newExportItemName of defaultDestinationFolder)

set newExportItemName to ¬

documentName & "-" & (incrementIndex as string) & "." & MicrosoftPowerPointFileExtension

set incrementIndex to incrementIndex + 1

end repeat

end tell

set the targetFileHFSpath to (defaultDestinationFolder as string) & newExportItemName

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

export front document to file targetFileHFSPath as Microsoft PowerPoint

end timeout

set exportedItempath to targetFileHFSPath

on error errorMessage number errorNumber

display alert "EXPORT PROBLEM" message errorMessage

error number -128

end try

end tell

-- SHOW THE NEW EXPORTED FILE

tell application "Finder"

activate

set exportedFile to (document file exportedItemPath)

set extension hidden of exportedFile to false

reveal exportedFile

end tell

Export to PDF

This script exports the frontmost Keynote presentation to a PDF file. Set the boolean value of the useEncryptionDefaultValue property to either true or false to determine whether you will be prompted for the password to use in encrypting the PDF file.

Export to PDF

property exportFileExtension : "pdf"

property useEncryptionDefaultValue : true

-- THE DESTINATION FOLDER

-- (see the "path" to command in the Standard Additions dictionary for other locations, such as movies folder, pictures folder, desktop folder)

set the defaultDestinationFolder to (path to documents folder)

set usePDFEncryption to useEncryptionDefaultValue

tell application "Keynote"

activate

try

if playing is true then tell the front document to stop

if not (exists document 1) then error number -128

if usePDFEncryption is true then

-- PROMPT FOR PASSWORD (OPTIONAL)

repeat

display dialog "Enter a password for the PDF file:" default answer ¬

"" buttons {"Cancel", "No Password", "OK"} ¬

default button 3 with hidden answer

copy the result to ¬

{button returned:buttonPressed, text returned:firstPassword}

if buttonPressed is "No Password" then

set usePDFEncryption to false

exit repeat

else

display dialog "Enter the password again:" default answer ¬

"" buttons {"Cancel", "No Password", "OK"} ¬

default button 3 with hidden answer

copy the result to ¬

{button returned:buttonPressed, text returned:secondPassword}

if buttonPressed is "No Password" then

set usePDFEncryption to false

exit repeat

else

if firstPassword is not secondPassword then

display dialog "Passwords do no match." buttons ¬

{"Cancel", "Try Again"} default button 2

else

set providedPassword to the firstPassword

set usePDFEncryption to true

exit repeat

end if

end repeat

end if

-- DERIVE NAME AND FILE PATH FOR NEW EXPORT FILE

set documentName to the name of the front document

if documentName ends with ".key" then ¬

set documentName to text 1 thru -5 of documentName

tell application "Finder"

set exportItemFileName to documentName & "." & exportFileExtension

set incrementIndex to 1

repeat until not (exists document file exportItemFileName of defaultDestinationFolder)

set exportItemFileName to ¬

documentName & "-" & (incrementIndex as string) & "." & exportFileExtension

set incrementIndex to incrementIndex + 1

end repeat

end tell

set the targetFileHFSpath to (defaultDestinationFolder as string) & exportItemFileName

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

if usePDFEncryption is true then

export front document to file targetFileHFSpath ¬

as PDF with properties {password:providedPassword}

else

export front document to file targetFileHFSpath as PDF

end if

end timeout

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert "EXPORT PROBLEM" message errorMessage

end if

error number -128

end try

end tell

-- SHOW THE NEW PDF FILE

tell application "Finder"

activate

reveal document file targetFileHFSpath

end tell

IMPORTANT TIP: Learn how to save and run your favorite scripts using the system-wide Script Menu.

TOP | CONTINUE

KEYNOTE SCRIPTING

Overview
Automation Utilities

Examples

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.