Keynote in an excellent tool for creating interactive presentations designed to be displayed by Mac-based kiosks or Apple computers functioning as kiosks. The document class contains properties for setting up a presentation to become kiosk-ready.

A script example demonstrating this process is included on this page.

The Keynote Suite Document Class (excerpt)

The script properties shown above correspond to those displayed in the application interface:

(⬇ see below ) Select the Document tab  1  to access the slideshow settings options.  2 

(⬇ see below ) The kiosk display controls in the application’s Slideshow preference tab.  1  To set your computer to kiosk mode, select the “Require password…” checkbox  2  and then enter the password  3  to prevent the running presentation from being stopped.

DO THIS ►DOWNLOAD (30MB) an example image kiosk created using the script below. The auto-restart time is set to one minute.

The following script will create a simple image slideshow, set the document to be kiosk-ready, and then save, quit, and re-open the document:

Make, Save, and Play Image Kiosk
Open in Script Editor
01		-- Create a new document and save it into the Documents folder
02		set the nameToUse to "Image Kiosk"
03		-- make sure the file name is not in use
04		set the destinationFolderHFSpath to ¬
05		(path to the documents folder) as string
06		repeat with i from 0 to 100000
07		if i is 0 then
08		set incrementText to ""
09		else
10		set incrementText to "-" & (i as string)
11		end if
12		set thisFileName to nameToUse & incrementText & ".key"
13		set thisFilepath to destinationFolderHFSpath & thisFileName
14		tell application "Finder"
15		if not (exists document file thisFilepath) then exit repeat
16		end tell
17		end repeat
18
19		-- GET THE CURRENT SCREEN DIMENSIONS
20		tell application "Finder"
21		copy the bounds of the window of the desktop to ¬
22		{x, y, screenWidth, screenHeight}
23		end tell
24
25		-- CREATE A NEW PRESENTATION
26		tell application "Keynote"
27		activate
28		if playing is true then tell the front document to stop
29
30		-- CREATE THE DOCUMENT
31		set thisDocument to make new document with properties ¬
32		{document theme:theme "Black", width:screenWidth, height:screenHeight}
33
34		tell thisDocument
35		set theseImages to {}
36		repeat with i from 1 to 5
37		if i is 1 then
38		-- SET THE TITLE SLIDE
39		set the base slide of the first slide to master slide "Title & Subtitle"
40		tell slide i
41		set the object text of the default title item to "Desktop Images"
42		set the object text of the default body item to "Tap to View"
43		end tell
44		else
45		-- make new image SLIDE
46		make new slide with properties {base slide:master slide "Blank"}
47		end if
48
49		-- GET THE RANDOM IMAGE
50		repeat
51		copy my getRandomDesktopPicture() to ¬
52		{thisImageFileName, thisImageFile}
53		if theseImages does not contain thisImageFileName then
54		set the end of theseImages to thisImageFileName
55		exit repeat
56		end if
57		end repeat
58		-- trim the file extension (.jpg) from the file name
59		set thisImageName to text 1 thru -5 of thisImageFileName
60
61		-- ADD THE IMAGE FILE TO THE FIRST SLIDE
62		tell slide i
63		-- IMPORT THE DESKTOP IMAGE
64		set thisImage to ¬
65		make new image with properties {file:thisImageFile}
66		tell thisImage
67		set thisItemHeight to its height
68		if thisItemHeight is not screenHeight then
69		-- FILL IMAGE TO SLIDE HEIGHT AND CENTER
70		set height of it to screenHeight
71		set thisItemWidth to its width
72		set the position of it to {((screenWidth - thisItemWidth) div 2), 0}
73		end if
74		if i is 1 then set opacity to 20
75		end tell
76
77		-- CREATE A TEXT OVERLAY DISPLAYING IMAGE NAME
78		set thisTitleBox to ¬
79		make new text item with properties {object text:thisImageName}
80		tell thisTitleBox
81		set font of object text of it to "Times New Roman Italic"
82		set thisItemHeight to its height
83		copy position of it to {horizontalPosition, verticalPositon}
84		set position of it to {horizontalPosition, screenHeight - (thisItemHeight * 2)}
85		if i is 1 then set opacity to 20
86		end tell
87
88		-- APPLY TRANSITION
89		set the transition properties to ¬
90		{transition effect:dissolve, transition duration:2.0, transition delay:0, automatic transition:false}
91		end tell
92		end repeat
93
94		-- SET THE KIOSK PROPERTIES
95		set auto play to true
96		set auto loop to true
97		set auto restart to true
98		set maximum idle duration to 1 -- minute
99
100		-- MOVE TO THE STARTING SLIDE BEFORE SAVING
101		my moveToSlide(first slide of it)
102		end tell
103
104		-- SAVE AND CLOSE THE DOCUMENT
105		save thisDocument in file thisFilepath
106		close the front document saving no
107
108		end tell
109
110		-- LAUNCH THE KIOSK
111		tell application "Finder"
112		open document file thisFilepath
113		end tell
114
115		on getRandomDesktopPicture()
116		-- GET A RANDOM IMAGE FROM THE DESKTOP PICTURES FOLDER
117		set desktopPicturesFolder to (path to desktop pictures folder)
118		set the imageFileNames to every paragraph of ¬
119		(do shell script "ls " & quoted form to of POSIX path of desktopPicturesFolder)
120		--> RETURNS: {"Abstract.jpg", "Antelope Canyon.jpg", "Bahamas Aerial.jpg", etc.}
121		set thisImageFileName to some item of the imageFileNames
122		--> RETURNS: "Mountain Range.jpg"
123		set thisImageFile to ¬
124		((desktopPicturesFolder as string) & thisImageFileName) as alias
125		--> RETURNS: alias "Macintosh HD:Library:Desktop Pictures:Mountain Range.jpg"
126		return {thisImageFileName, thisImageFile}
127		end getRandomDesktopPicture
128
129		on moveToSlide(thisSlide)
130		tell application "Keynote"
131		tell the front document
132		if thisSlide is last slide then
133		start from slide before last slide
134		tell application "Keynote"
135		show slide switcher
136		move slide switcher forward
137		accept slide switcher
138		stop front document
139		end tell
140		else
141		set thisSlideNumber to slide number of thisSlide
142		start from slide (thisSlideNumber + 1)
143		tell application "Keynote"
144		show slide switcher
145		move slide switcher backward
146		accept slide switcher
147		stop front document
148		end tell
149		end if
150		end tell
151		end tell
152		end moveToSlide

IMPORTANT TIP: Learn how to save and run your favorite scripts using the system-wide Script Menu.