Tables are meant to hold data. That’s obvious. So the question you’re probably asking now is: using scripting, how do you get data into a table? The answer is: the script iterates the data one bit at a time, and places each bit in its corresponding table cell.

Huh?

It makes sense, once you understand that it’s all about the data and how it is read. You see, table data is grouped by either row or column.

For example, let’s examine this list of names (remember that in AppleScript, lists are contained within curly braces, and contain comma-delimited items) :

{"Sal", "Sue", "Bob", "Carl", "Wanda"}

The list contains five names. If this list was to be used as the data for a row, it would require a single row that would span at least five columns, one for each name.

Sal

Sue

Bob

Carl

Wanda

However, if this list was to be used as the data for a column, it would require a single column that would span at least five rows, one for each name.

Sal

Sue

Bob

Carl

Wanda

Makes sense, right? If the data is for a row, there has to be a column for each item in the data list. If the data is for a column, there has to be a row for each item in the data list.

Now, let’s add some more data. Instead of having just one list of five names, let’s have three lists of five names, fifteen names in total, all combined into a parent list (think of it as a “list of lists”), like this:

{{"Sal", "Sue", "Bob", "Carl", "Wanda"}, {"Egbert", "Fred", "Danita", "Shirley", "Scott"}, {"Quincy", "Bertha", "Jane", "Julia", "Frank"}}

If this data is to be read as rows, there would be a row for each list item (that’s three rows), and each row would span five columns (the number of items in each list item), like this:

Sal	Sue	Bob	Carl	Wanda
Egbert	Fred	Danita	Shirley	Scott
Quincy	Bertha	Jane	Julia	Frank

If this data is to be read as columns, there would be a column for each list item (that’s three columns), and each column would span five rows (the number of items in each list item), like this:

Sal	Egbert	Quincy
Sue	Fred	Bertha
Bob	Danita	Jane
Carl	Shirley	Julia
Wanda	Scott	Frank

Not to be overly repetitious, but as you can see, it’s all about how the data is read: row or column. So all a script has to do to populate a table, is to read the data and place into one row at time, or one column at a time.

The two example scripts below, demonstrate how scripts can create and populate tables based upon whether the data is read as row-based, or as column-based:

IMPORTANT TIP: Learn how to save and run your favorite scripts using the system-wide Script Menu.

Populate New Table with Row-Based Data
Open in AppleScript Editor
01		property useHeaders : true -- change to false to omit headers
02		property datasetCount : 6
03		property datasetItemCount : 3
04
05		tell application "Keynote"
06		activate
07		-- for this example script, generate some random data sets
08		set generatedData to my generaterandomNumericDataSets(datasetCount, datasetItemCount)
09		-- determine row count based on data length
10		-- determine column count based on length of first item of data
11		-- add 1 to row and column count if table is to include headers
12		if useHeaders is true then
13		set the rowCount to (the count of generatedData) + 1
14		set the columnCount to (the count of item 1 of generatedData) + 1
15		else
16		set the rowCount to the count of generatedData
17		set the columnCount to the count of item 1 of generatedData
18		end if
19		-- create and poplate a table reading the data as row based
20		tell document 1
21		tell current slide
22		if useHeaders is true then
23		set thisTable to ¬
24		make new table with properties ¬
25		{row count:rowCount, column count:columnCount, name:"Row Data Table", header row count:1, header column count:1}
26		else
27		set thisTable to ¬
28		make new table with properties ¬
29		{row count:rowCount, column count:columnCount, name:"Row Data Table", header row count:0, header column count:0}
30		end if
31		tell thisTable
32		if useHeaders is true then
33		-- set the starting indexes for using headers
34		set rowIndex to 1
35		set columnIndex to 1
36		-- since headers are used, name the column & row headers
37		-- title and style the column header cells
38		set x to 1
39		repeat with i from 2 to the columnCount
40		tell cell 1 of column i
41		set value to "COL " & (x as string)
42		set alignment to center
43		set vertical alignment to center
44		end tell
45		set x to x + 1
46		end repeat
47		-- title and style the row header cells
48		set x to 1
49		repeat with i from 2 to the rowCount
50		tell cell 1 of row i
51		-- set the value and styling of the cell
52		set value to "ROW " & (x as string)
53		set alignment to right
54		set vertical alignment to center
55		end tell
56		set x to x + 1
57		end repeat
58		else
59		-- set the starting indexes for not using headers
60		set rowIndex to 0
61		set columnIndex to 0
62		end if
63		-- populate the table with the data
64		set the rowCellCount to count of cells of row 2
65		repeat with i from 1 to count of the generatedData
66		-- get a data set from the data set list
67		set thisRowData to item i of the generatedData
68		tell row (rowIndex + i)
69		-- iterate the data set, populating row cells from left to right
70		repeat with q from 1 to the count of thisRowData
71		tell cell (columnIndex + q)
72		set value to item q of thisRowData
73		set alignment to center
74		set vertical alignment to center
75		end tell
76		end repeat
77		end tell
78		end repeat
79		end tell
80		end tell
81		end tell
82		end tell
83
84		on generaterandomNumericDataSets(setCount, setItemCount)
85		set randomNumericDataSets to {}
86		repeat setCount times
87		set thisSet to {}
88		repeat setItemCount times
89		set the end of thisSet to (random number from -100 to 100)
90		end repeat
91		set the end of randomNumericDataSets to thisSet
92		end repeat
93		return randomNumericDataSets
94		end generaterandomNumericDataSets

(⬇ see below ) A table with row-based data created with the example script:

Populate New Table with Column-Based Data
Open in AppleScript Editor
01		property useHeaders : true -- change to false to omit headers
02		property datasetCount : 6
03		property datasetItemCount : 2
04
05		tell application "Keynote"
06		activate
07		-- for this example script, generate some random data sets
08		set generatedData to my generaterandomNumericDataSets(datasetCount, datasetItemCount)
09		-- determine column count based on data length
10		-- determine row count based on length of first item of data
11		-- add 1 to row and column count if table is to include headers
12		if useHeaders is true then
13		set the columnCount to (the count of generatedData) + 1
14		set the rowCount to (the count of item 1 of generatedData) + 1
15		else
16		set the columnCount to the count of generatedData
17		set the rowCount to the count of item 1 of generatedData
18		end if
19		-- create and poplate a table reading the data as column based
20		tell document 1
21		tell current slide
22		if useHeaders is true then
23		set thisTable to ¬
24		make new table with properties ¬
25		{row count:rowCount, column count:columnCount, name:"Column Data Table", header row count:1, header column count:1}
26		else
27		make new table with properties ¬
28		{row count:rowCount, column count:columnCount, name:"Column Data Table", header row count:0, header column count:0}
29		end if
30		tell thisTable
31		if useHeaders is true then
32		-- set the starting indexes for using headers
33		set rowIndex to 1
34		set columnIndex to 1
35		-- since headers are used, name the column & row headers
36		-- title and style the column header cells
37		set x to 1
38		repeat with i from 2 to the columnCount
39		tell cell 1 of column i
40		-- set the value and styling of the cell
41		set value to "COL " & (x as string)
42		set alignment to center
43		set vertical alignment to center
44		end tell
45		set x to x + 1
46		end repeat
47		-- title and style the row header cells
48		set x to 1
49		repeat with i from 2 to the rowCount
50		tell cell 1 of row i
51		-- set the value and styling of the cell
52		set value to "ROW " & (x as string)
53		set alignment to right
54		set vertical alignment to center
55		end tell
56		set x to x + 1
57		end repeat
58		else
59		-- set the starting indexes for not using headers
60		set rowIndex to 0
61		set columnIndex to 0
62		end if
63		-- populate the table with the data
64		set the columnCellCount to count of cells of column 2
65		repeat with i from 1 to count of the generatedData
66		-- get a data set from the data set list
67		set thisColumnData to item i of the generatedData
68		tell column (columnIndex + i)
69		-- iterate the data set, populating column cells from top to bottom
70		repeat with q from 1 to the count of thisColumnData
71		-- set the value and styling of the cell
72		tell cell (rowIndex + q)
73		set value to item q of thisColumnData
74		set alignment to center
75		set vertical alignment to center
76		end tell
77		end repeat
78		end tell
79		end repeat
80		end tell
81		end tell
82		end tell
83		end tell
84
85		on generaterandomNumericDataSets(setCount, setItemCount)
86		set randomNumericDataSets to {}
87		repeat setCount times
88		set thisSet to {}
89		repeat setItemCount times
90		set the end of thisSet to (random number from -100 to 100)
91		end repeat
92		set the end of randomNumericDataSets to thisSet
93		end repeat
94		return randomNumericDataSets
95		end generaterandomNumericDataSets

(⬇ see below ) A table with column-based data created with the example script: