Although Keynote offers the ability to assign an audio track to be played during a presentation, it is currently not possible to assign individual audio tracks to specific slides, or to have an audio track play during the presentation of a series of slides.

For those creative types who are looking for new ways to maximize the effectiveness of Keynote, here’s an Applescript script to trigger and control the playing of tracks in iTunes based upon the current slide being presented in Keynote.

Using this script, you can have a specified iTunes track play through multiple slides, or have a track play only for a specific slide.

NOTE: Requires Keynote 6.5+ and OS X 10.10+

DOWNLOAD  the completed helper applet. NOTE: Before launching the applet, make sure that iTunes and Keynote are open.

The Helper Script Application

This script is designed to be saved as an application that stays open after launch. This accomplished by selecting the “Stay open after run handler” checkbox in the script’s Save dialog.

When the script application is launched, it queries the iTunes application to get a list of names of all user playlists. The script then presents the list to the user so they can choose the playlist containing the tracks whose titles are placed in the presenter notes of the presentation slides.

The interactive power of the script is accomplished through its use of an idle handler. Once the script has been launched, the idle handler is triggered after the specified idle interval (in seconds), executing the script statements within the handler. The script queries Keynote as to the contents of the presenter notes of the current slide, and based upon the reply, takes the following actions:

• If the contents of the current slide’s presenter notes is the name of a track in the chosen playlist, the track will be played, unless it is already the currently playing track in iTunes—in which case, the track continues uninterrupted.
• If the contents of the current slide’s presenter notes is nothing, then the script tells iTunes to stop playing.
• If the Keynote presentation is halted, the script will close itself and quit.
• If either Keynote or iTunes is closed, the script will close itself and quit.

Keynote Music Helper
Open in Script Editor
01		property idleTimeInSeconds : 1
02
03		global playlistTitle, hasPlayed, startFlag
04
05		on run
06		if running of application "iTunes" is false then
07		tell application "iTunes" to launch
08		end if
09		tell application "iTunes"
10		set thesePlaylistTitles to the name of every user playlist
11		end tell
12		activate
13		set the beginning of thesePlaylistTitles to "USE MUSIC LIBRARY"
14		set chosenPlaylistTitle to ¬
15		(choose from list thesePlaylistTitles with prompt "Choose the playlist to use:")
16		if chosenPlaylistTitle is false then tell me to quit
17		set chosenPlaylistTitle to chosenPlaylistTitle as string
18		if chosenPlaylistTitle is "USE MUSIC LIBRARY" then
19		set playlistTitle to missing value
20		else
21		set playlistTitle to chosenPlaylistTitle
22		end if
23		set hasPlayed to false
24		display dialog "Applet is active and ready for presentation to begin!" buttons {"Switch to Keynote", "OK"} default button 2
25		if button returned of the result is "Switch to Keynote" then
26		tell application "Keynote"
27		activate
28		end tell
29		set startFlag to true
30		else
31		set startFlag to false
32		end if
33		end run
34
35		on idle
36		if startFlag is true then
37		set startFlag to false
38		return 1
39		end if
40		if running of application "Keynote" is true then
41		tell application "Keynote"
42		if playing is true then
43		activate
44		set hasPlayed to true
45		set trackTitle to the presenter notes of current slide of front document
46		if trackTitle is "" then
47		my stopPlaying()
48		else
49		my playThisTrack(trackTitle, missing value)
50		end if
51		else
52		-- stop iTunes if it playing
53		my stopPlaying()
54		-- quit the applet if the presentation has been played
55		if hasPlayed is true then
56		tell me to quit
57		end if
58		end if
59		end tell
60		else
61		say "Keynote is not open. Quiting applet."
62		tell me to quit
63		end if
64		if running of application "iTunes" is false then
65		say "iTunes is not open. Quiting applet."
66		tell me to quit
67		end if
68		return idleTimeInSeconds
69		end idle
70
71		on playThisTrack(trackTitle, playlistTitle)
72		-- check to see if iTunes is open
73		if running of application "iTunes" is true then
74		try
75		tell application "iTunes"
76		-- check to see if iTunes is playing
77		if player state is playing then
78		-- if the current track is not the current track then play new track
79		if the name of current track is not trackTitle then
80		if playlistTitle is missing value then
81		tell user playlist "Music"
82		play (first track whose name is trackTitle)
83		end tell
84		else
85		if exists user playlist playlistTitle then
86		tell user playlist playlistTitle
87		play (first track whose name is trackTitle)
88		end tell
89		else
90		say "No matching playlist in iTunes. Quitting applet."
91		tell me to quit
92		end if
93		end if
94		end if
95		else
96		-- play new track
97		tell user playlist "Music"
98		play (first track whose name is trackTitle)
99		end tell
100		end if
101		end tell
102		return true
103		on error errorMessage number errorNumber
104		if errorNumber is -1728 then
105		-- no matching track
106		say "No matching track in the iTunes music library."
107		else
108		-- do nothing
109		end if
110		return false
111		end try
112		else
113		say "iTunes is not running"
114		return false
115		end if
116		end playThisTrack
117
118		on stopPlaying()
119		if running of application "iTunes" is true then
120		tell application "iTunes"
121		if player state is playing then stop
122		end tell
123		end if
124		end stopPlaying
125
126		on quit
127		continue quit
128		end quit