Some things are just “too big” to capture in a single image: Alaska, the Grand Canyon, the Aurora Borealis, Space, those kind of things. But that doesn’t stop us from trying to convey what it was like to “be there.” That’s why we came up with the pano (short for panoramic image), whose width mimics more of what we can see with our own eyes.

But unless you’ve got a special circular projection system, and a really large curved screen, replicating the panoramic view is very difficult. Especially in a slide presentation. But again, that doesn’t stop us from trying.

Here’s an interesting use of Keynote automation that incorporates a very wide image, like the one shown below:

NASA Jet Propulsion Laboratory, Space Images: Curiosity Mars Rover Approaches “Dingo Gap,” Mastcam View. (webpage here) (image here)

into a widescreen presentation, like this: (Click Movie to Play)

The addition of a pano image to a presentation is labor-intensive, as you need to:

• Import the pano image to a new slide.
• Duplicate the slide three times.
• Scale the image in the second slide to fit the height of the slide and then position the image so that its left side is flush with the left side of the slide.
• Scale the image in the third slide to fit the height of the slide and then position the image so that its right side is flush with the right side of the slide.
• Apply the Magic Move transition to the first three slides, and adjust their transition delay value.

A very detailed process indeed, and one that’s ideal for automating.

 (⬆ see above )  A widescreen presentation designed to display, zoom, and scan, a panoramic image.

DO THIS ►DOWNLOAD example image. DOWNLOAD finished presentation.

This script is designed to quickly create a presentation for a panoramic image:

Pano to Preso
Open in Script Editor
01		property transitionInOutDuration : 3
02		property transitionPanDuration : 10
03		property transitionInOutDelay : 2
04
05		tell application "Keynote"
06		if playing is true then tell the front document to stop
07		activate
08
09		set the sourcePanoImage to ¬
10		(choose file of type "public.image" with prompt ¬
11		"Pick the panoramic image to place across two slides:")
12
13		set thisDocument to make new document with properties ¬
14		{document theme:theme "Black", width:1920, height:1080}
15
16		tell thisDocument
17		-- get dimensions of the current document
18		set documentHeight to its height
19		set documentWidth to its width
20
21		-- set the master slide of the first slide
22		set the base slide of slide 1 to master slide "Blank"
23
24		tell slide 1
25		-- set transition to Magic Move
26		set the transition properties to ¬
27		{transition effect:magic move ¬
28		, transition duration:transitionInOutDuration ¬
29		, transition delay:transitionInOutDelay ¬
30		, automatic transition:true}
31		-- import the pano image
32		set thisImage to ¬
33		make new image with properties {file:sourcePanoImage}
34		end tell
35
36		-- create a second slide
37		set secondSlide to ¬
38		make new slide with properties {base slide:master slide "Blank"}
39		tell secondSlide
40		-- set transition to Magic Move
41		set the transition properties to ¬
42		{transition effect:magic move ¬
43		, transition duration:transitionPanDuration ¬
44		, transition delay:0 ¬
45		, automatic transition:true}
46		-- import the pano image
47		set thisImage to ¬
48		make new image with properties {file:sourcePanoImage}
49		-- scale the image to match slide height and position so the left side of the image aligns with the left side of the slide
50		tell thisImage
51		set height to documentHeight
52		set position to {0, 0}
53		end tell
54		end tell
55
56		-- create a third slide
57		set thirdSlide to ¬
58		make new slide with properties {base slide:master slide "Blank"}
59		tell thirdSlide
60		-- set transition to Magic Move
61		set the transition properties to ¬
62		{transition effect:magic move ¬
63		, transition duration:transitionInOutDuration ¬
64		, transition delay:transitionInOutDelay ¬
65		, automatic transition:true}
66		-- import the pano image
67		set thisImage to ¬
68		make new image with properties {file:sourcePanoImage}
69		-- scale the image to match slide height and position so the right side of the image aligns with the right side of the slide
70		tell thisImage
71		set height to documentHeight
72		set imageWidth to its width
73		set position to {documentWidth - imageWidth, 0}
74		end tell
75		end tell
76
77		-- create a fourth slide
78		set fourthSlide to ¬
79		make new slide with properties {base slide:master slide "Blank"}
80		tell fourthSlide
81		-- import the pano image
82		set thisImage to ¬
83		make new image with properties {file:sourcePanoImage}
84		end tell
85
86		end tell
87
88		start thisDocument from first slide of thisDocument
89
90		end tell

Here’s another example: a beautiful panoramic image of Tromsø Norway.
(Click Movie to Play) (webpage here)

One last example: a panoramic presentation of the history of United States debt.
(Click Movie to Play) (webpage here)