AppleScript and Numbers: Save Table|Selection as Image File

Save Table|Selection as Image File

Sharing table data with others is a common practice. And while you can copy and paste formatted table data between some applications (such as from Numbers to Mail, TextEdit, Keynote, etc.), it is often preferable to share the table data as an un-editable image file. This script will convert either the entire table, or just the selected range of cells, into an image file in PNG format.

The script provides examples of these techniques:

Interacting with the script user (7, 39, 48)
Using the Accessibility Frameworks to mimic user keystrokes (18, 33)
Retrieving image data from the clipboard (44)
Saving image data to file (75-92)
Displaying table data in other applications (54, 59)

Here’s the script:

Save Table|Selection as Image File

tell application "Numbers"

activate

try

tell the front document

tell active sheet

set thisTable to the first table whose class of selection range is range

display dialog ¬

"Save the entire table, or just the selection range, as an image?" buttons ¬

{"Cancel", "Range", "Table"} default button 3 with icon 1

set the userChoice to the button returned of the result

if the userChoice is "Table" then

tell thisTable

-- store the selection range address

set thisRange to the selection range

-- select the entire table

set the selection range to the cell range

-- copy to selection to the clipboard

tell application "System Events" to ¬

keystroke "c" using command down

-- restore the selection range to original state

set the selection range to thisRange

-- derive default image name

set tableName to the name

set the defaultName to (tableName & ".png")

end tell

else

tell thisTable

-- derive default image name

set tableName to the name

set the defaultName to (tableName & space & "Selection" & ".png")

end tell

-- copy to selection to the clipboard

tell application "System Events" to ¬

keystroke "c" using command down

end if

end tell

set the targetImageFile to (choose file name default name defaultName)

set targetImageFileHFSpath to targetImageFile as string

if targetImageFileHFSpath does not end with ".png" then

set targetImageFileHFSpath to targetImageFileHFSpath & ".png"

end if

set the imageData to get the clipboard as «class PNGf»

set the writeResult to my writeToFile(imageData, targetImageFileHFSpath, false)

if writeResult is true then

display dialog "The table image has been created." buttons ¬

{"Send Image", "Show Image File", "OK"} default button 3 with icon 1

set userChoice to the button returned of the result

if userChoice is "Send Image" then

tell application "Finder"

open document file targetImageFileHFSpath ¬

using application file id "com.apple.mail"

end tell

else if userChoice is "Show Image File" then

tell application "Finder"

activate

reveal document file targetImageFileHFSpath

end tell

end if

else

error "There was a problem writing the image file."

end if

on error errorMessage number errorNumber

if errorNumber is -1719 then

set errorMessage to "Please select a table before running this script."

end if

if errorNumber is not -128 then

display alert errorNumber message errorMessage

end if

end try

end tell

on writeToFile(thisData, targetFile, appendData)

tell current application

try

set the targetFile to the targetFile as string

set the openTargetFile to open for access file targetFile with write permission

if appendData is false then set eof of the openTargetFile to 0

write thisData to openTargetFile starting at eof --as «class PNGf»

close access the openTargetFile

return true

on error errorMessage

try

close access file targetFile

end try

log ("SCRIPT ERROR: " & errorMessage)

return false

end try

end tell

end writeToFile

TOP | CONTINUE

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.