AppleScript and Numbers: Adding Columns

Adding Columns

Adding columns to a table is accomplished using the add column after and add column before commands, which take as a direct parameter, a range of the table.

add column after v : Add a column to the table after a specified range of cells.

add column after range

add column before v : Add a column to the table before a specified range of cells.

add column before range

The script example below, adds a summation column to the end of the currently selected table:

(⬆ see above ) Table before adding SUM column.
(⬇ see below ) Table after adding SUM column to end.

Here’s the script:

Add Summation Column to Selected Table

tell application "Numbers"

activate

try

if not (exists document 1) then error number 1000

tell document 1

try

tell active sheet

set the selectedTable to ¬

(the first table whose class of selection range is range)

end tell

on error

error number 1001

end try

tell selectedTable

-- currently, use of headers and footers cannot be determined by a script.

-- make the following assumptions:

set usesHeaders to true -- assume 1 row and 1 column

set usesFooters to false -- assume 1 row

-- add a new column

add column after last column

set the summationColumn to the last column

-- set the formula of each cell of the summation column

tell summationColumn

if usesHeaders is true then

set startIndex to 2

else

set startIndex to 1

end if

repeat with i from startIndex to the count of cells

-- get the row of the cell

set thisRow to the row of cell i

-- determine range coordinates

set the rangeStart to the name of cell startIndex of thisRow

set the rangeEnd to the name of cell -2 of thisRow

-- create formula using SUM function

set the summationFormula to ¬

("=SUM(" & rangeStart & ":" & rangeEnd & ")") as string

-- set the formula to the cell

set the value of cell i to summationFormula

end repeat

end tell

on error errorMessage number errorNumber

if errorNumber is 1000 then

set alertString to "MISSING RESOURCE"

set errorMessage to ¬

"Please create or open a document before running this script."

else if errorNumber is 1001 then

set alertString to "SELECTION ERROR"

set errorMessage to ¬

"Please select a table before running this script."

else

set alertString to "EXECUTION ERROR"

end if

if errorNumber is not -128 then

display alert alertString message errorMessage buttons {"Cancel"}

end if

error number -128

end try

end tell

TOP | CONTINUE

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.