AppleScript and Numbers: Exporting Documents

Exporting Documents

Exporting Numbers documents is done using the export command from the Numbers Suite.

export v : Export a presentation to another file(s).

export document : The presentation to export.

to (file ) : A reference to the file (folder) to be created. When exporting images or HTML, a new folder, containing the exported items, is created instead of a file.

as ( PDF / ‌Microsoft Excel /‌ CSV /‌ Numbers 09 ) : The format in which the document is to be exported.

[ with properties (export options ) ] : An AppleScript record containing property:value pairings for the initial values for properties of the exported object.

export options n : The export options for the Numbers export command.

properties

exclude summary worksheet ( boolean ) : (Numbers 3.6) Whether to exclude a summary worksheet in Excel workbook.

image quality ( good/better/best ) : (Numbers 3.6) The quality of the images in the exported PDF file.

password ( text ) : The password to use when the exported PDF is encrypted.

password hint ( text ) : The password hint.

NOTE: The Numbers version 3.6 scripting dictionary includes enhanced export options for exporting to Excel format, as well as image compression options for images placed within the exported document.

Export Scripts

The following are script examples for each of the export types:

Export to CSV, Export to PDF, Export to Microsoft Excel, Export to Numbers 2009

Export to PDF

This script exports the frontmost Numbers presentation to a PDF file. Set the boolean value of the useEncryptionDefaultValue property to either true or false to determine whether you will be prompted for the password to use in encrypting the PDF file.

Export to PDF

property exportFileExtension : "pdf"

property useEncryptionDefaultValue : true

-- THE DESTINATION FOLDER

-- (see the "path" to command in the Standard Additions dictionary for other locations, such as movies folder, pictures folder, desktop folder)

set the defaultDestinationFolder to (path to documents folder)

set usePDFEncryption to useEncryptionDefaultValue

tell application "Numbers"

activate

try

if not (exists document 1) then error number -128

if usePDFEncryption is true then

-- PROMPT FOR PASSWORD (OPTIONAL)

repeat

display dialog "Enter a password for the PDF file:" default answer ¬

"" buttons {"Cancel", "No Password", "OK"} ¬

default button 3 with hidden answer

copy the result to ¬

{button returned:buttonPressed, text returned:firstPassword}

if buttonPressed is "No Password" then

set usePDFEncryption to false

exit repeat

else

display dialog "Enter the password again:" default answer ¬

"" buttons {"Cancel", "No Password", "OK"} ¬

default button 3 with hidden answer

copy the result to ¬

{button returned:buttonPressed, text returned:secondPassword}

if buttonPressed is "No Password" then

set usePDFEncryption to false

exit repeat

else

if firstPassword is not secondPassword then

display dialog "Passwords do no match." buttons ¬

{"Cancel", "Try Again"} default button 2

else

set providedPassword to the firstPassword

set usePDFEncryption to true

exit repeat

end if

end repeat

end if

-- DERIVE NAME AND FILE PATH FOR NEW EXPORT FILE

set documentName to the name of the front document

if documentName ends with ".numbers" then ¬

set documentName to text 1 thru -9 of documentName

tell application "Finder"

set exportItemFileName to documentName & "." & exportFileExtension

set incrementIndex to 1

repeat until not (exists document file exportItemFileName of defaultDestinationFolder)

set exportItemFileName to ¬

documentName & "-" & (incrementIndex as string) & "." & exportFileExtension

set incrementIndex to incrementIndex + 1

end repeat

end tell

set the targetFileHFSpath to (defaultDestinationFolder as string) & exportItemFileName

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

if usePDFEncryption is true then

export front document to file targetFileHFSpath ¬

as PDF with properties {password:providedPassword}

else

export front document to file targetFileHFSpath as PDF

end if

end timeout

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert "EXPORT PROBLEM" message errorMessage

end if

error number -128

end try

end tell

-- SHOW THE NEW PDF FILE

tell application "Finder"

activate

reveal document file targetFileHFSpath

end tell

Export to CSV

This script exports the frontmost Numbers presentation to one or more CSV files.

Export to CSV

property exportFileExtension : "csv"

-- THE DESTINATION FOLDER

-- (see the "path to" command in the Standard Additions dictionary for other locations, such as movies folder, pictures folder, desktop folder)

set the defaultDestinationFolder to (path to documents folder)

tell application "Numbers"

activate

try

if not (exists document 1) then error number -128

tell the front document

set documentName to its name

if documentName ends with ".numbers" then ¬

set documentName to text 1 thru -9 of documentName

set tableCount to the count of every table of every sheet

end tell

-- a DOCUMENT WITH ONE TABLE WILL EXPORT TO A FILE

if tableCount is 0 then

tell application "Finder"

set newExportItemName to documentName & "." & exportFileExtension

set incrementIndex to 1

repeat until not (exists document file newExportItemName of defaultDestinationFolder)

set newExportItemName to ¬

documentName & "-" & (incrementIndex as string) & "." & exportFileExtension

set incrementIndex to incrementIndex + 1

end repeat

end tell

set the targetFileHFSpath to ¬

(defaultDestinationFolder as string) & newExportItemName

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

export front document to file targetFileHFSpath as CSV

end timeout

set exportedItempath to targetFileHFSpath

else

-- a DOCUMENT CONTAINING MULTIPLE TABLES WILL EXPORT TO A FOLDER

tell application "Finder"

set newFolderName to documentName

set incrementIndex to 1

repeat until not (exists folder newFolderName of defaultDestinationFolder)

set newFolderName to documentName & "-" & (incrementIndex as string)

set incrementIndex to incrementIndex + 1

end repeat

set targetHFSpath to (defaultDestinationFolder as string) & ¬

newFolderName & "." & exportFileExtension

end tell

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

export front document as CSV to file targetHFSpath

end timeout

set exportedItempath to ¬

(defaultDestinationFolder as string) & newFolderName & ":"

end if

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert "EXPORT PROBLEM" message errorMessage

end if

error number -128

end try

end tell

-- SHOW THE NEW EXPORTED ITEM

tell application "Finder"

activate

reveal item exportedItempath

end tell

Export to Microsoft Excel

This script exports the frontmost Numbers presentation to a Microsoft Excel file.

Export to Microsoft Excel

property exportFileExtension : "xls"

-- THE DESTINATION FOLDER

-- (see the "path" to command in the Standard Additions dictionary for other locations, such as EXPORTs folder, pictures folder, desktop folder)

set the defaultDestinationFolder to (path to documents folder)

tell application "Numbers"

activate

try

if not (exists document 1) then error number -128

-- DERIVE NAME AND FILE PATH FOR NEW EXPORT FILE

set documentName to the name of the front document

if documentName ends with ".numbers" then ¬

set documentName to text 1 thru -9 of documentName

tell application "Finder"

set newExportFileName to documentName & "." & exportFileExtension

set incrementIndex to 1

repeat until not (exists document file newExportFileName of defaultDestinationFolder)

set newExportFileName to ¬

documentName & "-" & (incrementIndex as string) & "." & exportFileExtension

set incrementIndex to incrementIndex + 1

end repeat

end tell

set the targetFileHFSpath to (defaultDestinationFolder as string) & newExportFileName

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

export front document to file targetFileHFSpath as Microsoft Excel

end timeout

on error errorMessage number errorNumber

display alert "EXPORT PROBLEM" message errorMessage

error number -128

end try

end tell

-- SHOW THE NEW EXPORT FILE

tell application "Finder"

activate

reveal document file targetFileHFSpath

end tell

Export to Numbers 2009

This script exports the frontmost Numbers presentation to a Numbers 2009 file.

Export to Numbers 2009

property exportFileExtension : "numbers"

-- THE DESTINATION FOLDER

-- (see the "path" to command in the Standard Additions dictionary for other locations, such as EXPORTs folder, pictures folder, desktop folder)

set the defaultDestinationFolder to (path to documents folder)

tell application "Numbers"

activate

try

if not (exists document 1) then error number -128

-- DERIVE NAME AND FILE PATH FOR NEW EXPORT FILE

set documentName to the name of the front document

if documentName ends with ".numbers" then ¬

set documentName to text 1 thru -9 of documentName

tell application "Finder"

set newExportFileName to documentName & "." & exportFileExtension

set incrementIndex to 1

repeat until not (exists document file newExportFileName of defaultDestinationFolder)

set newExportFileName to ¬

documentName & "-" & (incrementIndex as string) & "." & exportFileExtension

set incrementIndex to incrementIndex + 1

end repeat

end tell

set the targetFileHFSpath to (defaultDestinationFolder as string) & newExportFileName

-- EXPORT THE DOCUMENT

with timeout of 1200 seconds

export front document to file targetFileHFSpath as Numbers 09

end timeout

on error errorMessage number errorNumber

display alert "EXPORT PROBLEM" message errorMessage

error number -128

end try

end tell

-- SHOW THE NEW EXPORT FILE

tell application "Finder"

activate

reveal document file targetFileHFSpath

end tell

IMPORTANT TIP: Learn how to save and run your favorite scripts using the system-wide Script Menu.

TOP | CONTINUE

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.