AppleScript and Numbers: Adding Sheets

Adding Sheets

Sheets are added to a document by using the make command of the Standard Suite.

make v : Create a new object.

make

new class : The class of the new object.

[ at location specifier ] : The location at which to insert the object.

[ with data any ] : The initial contents of the object.

[ with properties record ] : The initial values for properties of the object.

⇒ specifier : The new object.

When creating a sheet, the optional with properties parameter of the make command is supported, so that sheets can be created and named with a single statement.

New Document with Sheet for Every Month

set the monthNames to {"January", "February", "March", "April", "May", "June", "July", "August", "September", "October", "November", "December"}

set thisYearName to (year of (current date)) as string

tell application "Numbers"

activate

-- confirmation dialog

display dialog "This script will create a new document containing a sheet, " & ¬

"with a named table, for every month of the year." buttons ¬

{"Cancel", "Continue"} default button 2 with icon 1

-- make a new document

set thisDocument to make new document

-- create a sheet with a named table for every month

tell thisDocument

repeat with i from 1 to the count of the monthNames

set thisMonthName to item i of the monthNames

set thisTableName to thisMonthName & "-" & thisYearName

if i is 1 then

-- name the sheet

set the name of sheet 1 to thisMonthName

tell sheet 1

-- delete default table and create new one

delete every table

make new table with properties {name:thisTableName}

end tell

else

-- make a new sheet

set thisSheet to ¬

make new sheet with properties {name:thisMonthName}

tell thisSheet

-- delete default table and create new one

delete every table

make new table with properties {name:thisTableName}

end tell

end if

end repeat

delay 0.5

-- display the first sheet by selecting table on current sheet, then table on first sheet

set selection range of table 1 of sheet 12 to cell range of table 1 of sheet 12

delay 1

set selection range of table 1 of sheet 1 to cell range of table 1 of sheet 1

end tell

display dialog "Document created." buttons {"OK"} default button 1 with icon 1

end tell

The script below, adds a sheet, titled for every day of the current month, to the front document.

New Document with Sheet for Every Day of This Month

copy my deriveNameIndexLengthYearOfCurrentMonth() to ¬

{thisMonthName, thisMonthIndex, monthLengthInDays, thisYearName}

tell application "Numbers"

activate

-- confirmation dialog

display dialog "This script will create a new document " & ¬

"containing a sheet for every day of the month." buttons ¬

{"Cancel", "Continue"} default button 2 with icon 1

-- make a new document

set thisDocument to make new document

-- create a sheet with a named table for every month

tell thisDocument

repeat with i from 1 to monthLengthInDays

set the sheetName to ¬

(thisMonthName & space & i & space & thisYearName) as string

set the tableName to ¬

(thisMonthIndex & "-" & i & "-" & thisYearName) as string

if i is 1 then

-- name the sheet

set the name of sheet 1 to the sheetName

-- delete default table and create new one

tell sheet 1

delete every table

make new table with properties {name:tableName}

end tell

else

-- make a new sheet

set thisSheet to ¬

make new sheet with properties {name:sheetName}

tell thisSheet

-- delete default table and create new one

delete every table

make new table with properties {name:tableName}

end tell

end if

end repeat

delay 0.5

-- display the first sheet by selecting table on current sheet, then table on first sheet

set selection range of table 1 of sheet 12 to cell range of table 1 of sheet 12

delay 1

set selection range of table 1 of sheet 1 to cell range of table 1 of sheet 1

end tell

display dialog "Document created." buttons {"OK"} default button 1 with icon 1

end tell

on deriveNameIndexLengthYearOfCurrentMonth()

set thisDate to (current date)

set day of thisDate to 1

set thisMonth to month of thisDate

set thisMonthName to thisMonth as string

set thisMonthIndex to thisMonth as integer

set thisYearName to (year of thisDate) as string

repeat with i from 1 to 32

set thisDate to thisDate + (1 * days)

if month of thisDate is not thisMonth then

set monthLengthInDays to i

exit repeat

end if

end repeat

return {thisMonthName, thisMonthIndex, monthLengthInDays, thisYearName}

end deriveNameIndexLengthYearOfCurrentMonth

TOP | CONTINUE

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.