Tables are meant to hold data. That’s obvious. So the question you’re probably asking now is: using scripting, how do you get data into a table? The answer is: the script iterates the data one bit at a time, and places each bit in its corresponding table cell.

Huh?

It makes sense, once you understand that it’s all about the data and how it is read. You see, table data is grouped by either row or column.

For example, let’s examine this list of names (remember that in AppleScript, lists are contained within curly braces, and contain comma-delimited items) :

{"Sal", "Sue", "Bob", "Carl", "Wanda"}

The list contains five names. If this list was to be used as the data for a row, it would require a single row that would span at least five columns, one for each name.

Sal

Sue

Bob

Carl

Wanda

However, if this list was to be used as the data for a column, it would require a single column that would span at least five rows, one for each name.

Sal

Sue

Bob

Carl

Wanda

Makes sense, right? If the data is for a row, there has to be a column for each item in the data list. If the data is for a column, there has to be a row for each item in the data list.

Now, let’s add some more data. Instead of having just one list of five names, let’s have three lists of five names, fifteen names in total, all combined into a parent list (think of it as a “list of lists”), like this:

{{"Sal", "Sue", "Bob", "Carl", "Wanda"}, {"Egbert", "Fred", "Danita", "Shirley", "Scott"}, {"Quincy", "Bertha", "Jane", "Julia", "Frank"}}

If this data is to be read as rows, there would be a row for each list item (that’s three rows), and each row would span five columns (the number of items in each list item), like this:

Sal	Sue	Bob	Carl	Wanda
Egbert	Fred	Danita	Shirley	Scott
Quincy	Bertha	Jane	Julia	Frank

If this data is to be read as columns, there would be a column for each list item (that’s three columns), and each column would span five rows (the number of items in each list item), like this:

Sal	Egbert	Quincy
Sue	Fred	Bertha
Bob	Danita	Jane
Carl	Shirley	Julia
Wanda	Scott	Frank

Not to be overly repetitious, but as you can see, it’s all about how the data is read: row or column. So all a script has to do to populate a table, is to read the data and place into one row at time, or one column at a time.

The two example scripts below, demonstrate how scripts can create and populate tables based upon whether the data is read as row-based, or as column-based:

Populate New Table with Row-Based Data
Open in AppleScript Editor
01		tell application "Numbers"
02		activate
03		-- for this example script, generate some random data sets
04		set generatedData to my generaterandomNumericDataSets(8, 3)
05		-- determine row count based on data length
06		-- determine column count based on length of first item of data
07		-- add 1 to row and column count if table is to include headers
08		set useHeaders to true -- change to false to omit headers
09		if useHeaders is true then
10		set the rowCount to (the count of generatedData) + 1
11		set the columnCount to (the count of item 1 of generatedData) + 1
12		else
13		set the rowCount to the count of generatedData
14		set the columnCount to the count of item 1 of generatedData
15		end if
16		-- create and poplate a table reading the data as row based
17		tell document 1
18		tell active sheet
19		set thisTable to ¬
20		make new table with properties ¬
21		{row count:rowCount, column count:columnCount, name:"Row Data Table"}
22		tell thisTable
23		if useHeaders is true then
24		-- set the starting indexes for using headers
25		set rowIndex to 1
26		set columnIndex to 1
27		-- since headers are used, name the column & row headers
28		-- title and style the column header cells
29		set x to 1
30		repeat with i from 2 to the columnCount
31		tell cell 1 of column i
32		set value to "COL " & (x as string)
33		set alignment to center
34		set vertical alignment to center
35		end tell
36		set x to x + 1
37		end repeat
38		-- title and style the row header cells
39		set x to 1
40		repeat with i from 2 to the rowCount
41		tell cell 1 of row i
42		-- set the value and styling of the cell
43		set value to "ROW " & (x as string)
44		set alignment to right
45		set vertical alignment to center
46		end tell
47		set x to x + 1
48		end repeat
49		else
50		-- set the starting indexes for not using headers
51		set rowIndex to 0
52		set columnIndex to 0
53		end if
54		-- populate the table with the data
55		set the rowCellCount to count of cells of row 2
56		repeat with i from 1 to count of the generatedData
57		-- get a data set from the data set list
58		set thisRowData to item i of the generatedData
59		tell row (rowIndex + i)
60		-- iterate the data set, populating row cells from left to right
61		repeat with q from 1 to the count of thisRowData
62		tell cell (columnIndex + q)
63		set value to item q of thisRowData
64		set alignment to center
65		set vertical alignment to center
66		end tell
67		end repeat
68		end tell
69		end repeat
70		end tell
71		end tell
72		end tell
73		end tell
74
75
76		on generaterandomNumericDataSets(setCount, setItemCount)
77		set randomNumericDataSets to {}
78		repeat setCount times
79		set thisSet to {}
80		repeat setItemCount times
81		set the end of thisSet to (random number from -100 to 100)
82		end repeat
83		set the end of randomNumericDataSets to thisSet
84		end repeat
85		return randomNumericDataSets
86		end generaterandomNumericDataSets

Populate New Table with Column-Based Data
Open in AppleScript Editor
01		tell application "Numbers"
02		activate
03		-- for this example script, generate some random data sets
04		set generatedData to my generaterandomNumericDataSets(8, 3)
05		-- determine column count based on data length
06		-- determine row count based on length of first item of data
07		-- add 1 to row and column count if table is to include headers
08		set useHeaders to true -- change to false to omit headers
09		if useHeaders is true then
10		set the columnCount to (the count of generatedData) + 1
11		set the rowCount to (the count of item 1 of generatedData) + 1
12		else
13		set the columnCount to the count of generatedData
14		set the rowCount to the count of item 1 of generatedData
15		end if
16		tell document 1
17		tell active sheet
18		set thisTable to ¬
19		make new table with properties ¬
20		{row count:rowCount, column count:columnCount, name:"Column Data Table"}
21		tell thisTable
22		if useHeaders is true then
23		-- set the starting indexes for using headers
24		set rowIndex to 1
25		set columnIndex to 1
26		-- since headers are used, name the column & row headers
27		-- title and style the column header cells
28		set x to 1
29		repeat with i from 2 to the columnCount
30		tell cell 1 of column i
31		-- set the value and styling of the cell
32		set value to "COL " & (x as string)
33		set alignment to center
34		set vertical alignment to center
35		end tell
36		set x to x + 1
37		end repeat
38		-- title and style the row header cells
39		set x to 1
40		repeat with i from 2 to the rowCount
41		tell cell 1 of row i
42		-- set the value and styling of the cell
43		set value to "ROW " & (x as string)
44		set alignment to right
45		set vertical alignment to center
46		end tell
47		set x to x + 1
48		end repeat
49		else
50		-- set the starting indexes for not using headers
51		set rowIndex to 0
52		set columnIndex to 0
53		end if
54		-- populate the table with the data
55		set the columnCellCount to count of cells of column 2
56		repeat with i from 1 to count of the generatedData
57		-- get a data set from the data set list
58		set thisColumnData to item i of the generatedData
59		tell column (columnIndex + i)
60		-- iterate the data set, populating column cells from top to bottom
61		repeat with q from 1 to the count of thisColumnData
62		-- set the value and styling of the cell
63		tell cell (rowIndex + q)
64		set value to item q of thisColumnData
65		set alignment to center
66		set vertical alignment to center
67		end tell
68		end repeat
69		end tell
70		end repeat
71		end tell
72		end tell
73		end tell
74		end tell
75
76		on generaterandomNumericDataSets(setCount, setItemCount)
77		set randomNumericDataSets to {}
78		repeat setCount times
79		set thisSet to {}
80		repeat setItemCount times
81		set the end of thisSet to (random number from -100 to 100)
82		end repeat
83		set the end of randomNumericDataSets to thisSet
84		end repeat
85		return randomNumericDataSets
86		end generaterandomNumericDataSets