AppleScript and Numbers: Templates

Using Templates in Document Creation

The ability to create a Numbers document using a specific template is enabled by the inclusion of the document template property of the document class. (⬇ see below )

The Numbers Suite Document Class

document n : The Numbers document. syn spreadsheet

elements

contains sheets; contained by application.

properties

active sheet (sheet ) : The active sheet in the document.

document template (template, r/o) : The template assigned to the document. This property’s value can be set during document creation.

The value of the document template property (⬆ see above ) is the template currently used (or to be used) by the document in the display of its contents.

NOTE: The document template property is currently read only (except when used with the make command) and cannot be used to change the current template of a Numbers document.

The script below demonstrates the use of the make command to create a new document with a template chosen by the script user:

New Document with Chosen Template

tell application "Numbers"

activate

try

-- get template names

set the templateNames to the name of every template

-- prompt user to pick a template

set thisTemplateName to ¬

(choose from list templateNames with prompt "Choose template:")

if thisTemplateName is false then error number -128

-- convert resulting list into string: {"Black"} to "Black"

set thisTemplateName to thisTemplateName as string

-- create default document, styled with the chosen template

make new document with properties ¬

{document template:template thisTemplateName}

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert "TEMPLATE ISSUE" message errorMessage

end if

end try

end tell

The following script, a variation of the previous script, creates a new Numbers document using the application template chosen by the script user:

New Document with Chosen Application Template

tell application "Numbers"

activate

try

-- get application template names

set theseApplicationTemplateNames to ¬

the name of every template whose id of it begins with "Application/"

-- prompt user to pick a template

set thisTemplateName to ¬

(choose from list theseApplicationTemplateNames with prompt "Choose a template:")

if thisTemplateName is false then error number -128

-- convert resulting list into a string: {"Black"} to "Black"

set thisTemplateName to thisTemplateName as string

-- create a default document, styled with the chosen template

make new document with properties ¬

{document template:template thisTemplateName}

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert "TEMPLATE ISSUE" message errorMessage

end if

end try

end tell

The following script is designed to create a new Numbers document using a specific user template. If the user template is not installed on the computer running the script, the script will prompt the script user to download the specified user template from the company website, and will display the company-hosted website page containing the template if the user desires.

Create Document with Specific User Template

tell application "Numbers"

activate

try

-- get application template names

set theseUserTemplateNames to ¬

the name of every template whose id of it begins with "User/"

-- check for installation of user template

set thisUserTemplateName to "Official Corporate Template"

if thisUserTemplateName is not in theseUserTemplateNames then

-- notify user of missing resource

set thisMessage to "The Numbers template “" & thisUserTemplateName & "” " & ¬

"is not installed on this computer." & return & return & ¬

"Download the template from the company webiste."

display alert "MISSING TEMPLATE" message thisMessage ¬

buttons {"Download", "Cancel"} default button 2

if button returned of the result is "Download" then

open location "https://mycompanyname.com/communications/templates"

end if

else

-- create a default document, styled with the template

make new document with properties ¬

{document template:template thisUserTemplateName}

end if

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert ("ERROR " & errorNumber) as string message errorMessage

end if

end try

end tell

TOP | CONTINUE

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.