This script is designed to make it easier to share a presentation that may:

• be a draft version
• incorporate typefaces not part of the default installation of the OS
• have a large file size
• may contain high-resolution images you don’t wish to make accessible to others when the presentation is distributed

This is accomplished by exporting the slides to a set of images, and then creating a new presentation incorporating the exported images. In addition, during the construction of the new presentation, slide transitions and presenter notes are transferred to the new presentation.

Note that object builds, such as bullet build-ins, are not transferred during this process.

 (⬇ see below ) Exported slide images. The DRAFT watermark was created by adding a text overlay, set to a low opacity, on each of the presentation slides, using the script provided at the bottom of this page.

Duplicate Presentation as Image Presentation
Open in Script Editor
01		tell application "Keynote"
02		activate
03		if playing is true then tell the front document to stop
04
05		if not (exists document 1) then error number -128
06
07		display dialog "This script will export the front presentation as images and then create A new presentation containing the exported images." & return & return & "Slide transitions and presenter notes will be transfered from the source presentation." with icon 1
08
09		-- STORE INFORMATION ABOUT FRONT DOCUMENT
10		tell front document
11		set documentName to its name
12		set documentWidth to its width
13		set documentHeight to its height
14		set the slideCount to the count of (every slide whose skipped is false)
15		end tell
16
17		-- CREATE AN EXPORT DESTINATION FOLDER
18		-- IMPORTANT: IT’S ADVISED TO ALWAYS CREATE A NEW DESTINATION FOLDER, AS THE CONTENTS OF ANY TARGETED FOLDER WILL BE OVERWRITTEN
19		tell application "Finder"
20		set the targetFolder to (make new folder at desktop)
21		set the targetFolderHFSPath to targetFolder as string
22		end tell
23
24		-- EXPORT THE FRONT DOCUMENT TO IMAGES
25		export the front document as slide images to file targetFolderHFSPath with properties {image format:PNG, skipped slides:false, export style:IndividualSlides}
26
27		-- SORT THE IMAGE FILES BY NAME AND CONVERT TO FILE REFERENCES
28		tell application "Finder"
29		set theseItems to every document file of the targetFolder
30		set theseItems to sort theseItems by name
31		set theseImageFiles to {}
32		repeat with i from 1 to the count of theseItems
33		set the end of theseImageFiles to (item i of theseItems) as alias
34		end repeat
35		end tell
36
37		-- MAKE A NEW PRESENTATION
38		set newPresentation to make new document with properties {document theme:theme "Black", width:documentWidth, height:documentHeight}
39		tell newPresentation
40		set blankMasterSlide to master slide "Blank"
41		set the base slide of slide 1 to blankMasterSlide
42		-- IMPORT THE IMAGE FILES
43		repeat with i from 1 to the count of theseImageFiles
44		set thisImageFile to item i of theseImageFiles
45		if i is 1 then
46		tell slide 1
47		set thisImage to make new image with properties {file:thisImageFile}
48		set locked of thisImage to true
49		end tell
50		else
51		set thisSlide to make new slide with properties {base slide:blankMasterSlide}
52		tell thisSlide
53		set thisImage to make new image with properties {file:thisImageFile}
54		set locked of thisImage to true
55		end tell
56		end if
57		end repeat
58		end tell
59
60		-- DELETE THE TEMPORARY FOLDER
61		tell application "Finder"
62		delete targetFolder
63		end tell
64
65		-- TRANSFER TRANSITION SETTINGS AND PRESENTER NOTES
66		repeat with i from 1 to slideCount
67		tell document 2
68		set sourceSlide to (the first slide whose slide number is i)
69		set theseTransitionProperties to transition properties of sourceSlide
70		set thesePresenterNotes to the presenter notes of sourceSlide
71		end tell
72		tell front document
73		set transition properties of slide i to theseTransitionProperties
74		set presenter notes of slide i to thesePresenterNotes
75		end tell
76		end repeat
77
78		-- PLAY THE NEW PRESENTATION
79		start the front document from the first slide of the front document
80		end tell

 (⬇ see below )  • A script for adding and removing transparent text overlays on slides:

TIP: To have multiple scripts for adding text overlays to slides, that contain phrases such as “DRAFT” or “CONFIDENTIAL” or “INTERNAL USE ONLY”, create multiple versions of this example script, each with different default settings.

Add|Remove Text Overlay
Open in AppleScript Editor
01		-- OBJECT TEXT PROPERTIES
02		property textOverlayString : "DRAFT"
03		property textOverlayTypeface : "Impact"
04		property textOverlayFontSize : 144
05		property textOverlayColorName : "white"
06		property textOverlayRGBColorValues : {65535, 65535, 65535}
07		-- red={65535, 0, 0}, white={65535, 65535, 65535}, black={0, 0, 0}
08		-- to derive custom color value, run following script statement and copy result:
09		-- return (choose color default color {65535, 0, 0})
10
11		-- TEXT ITEM PROPERTIES
12		property textOverlayOpacityValue : 20
13		property textOverlayDefaultPosition : 4
14		-- 0=center, 1=top left, 2=top right, 3=bottom left, 4=bottom right
15		property textItemOverlayOffset : 36
16
17		tell application "Keynote"
18		activate
19		if playing is true then tell the front document to stop
20
21		if not (exists document 1) then error number -128
22
23		set textOverlayDefaultPositionName to item (textOverlayDefaultPosition + 1) of ¬
24		{"center", "top left", "top right", "bottom left", "bottom right"}
25
26		set dialogText to "Overlay Text: " & textOverlayString & return & ¬
27		"Text Color: " & textOverlayColorName & return> & ¬
28		"Text Size: " & textOverlayFontSize & return & ¬
29		"Typeface: " & textOverlayTypeface & return & ¬
30		"Text Opacity: " & textOverlayOpacityValue & return & ¬
31		"Text Position: " & textOverlayDefaultPositionName
32
33		display dialog dialogText & return & return & "Add or Remove text overlays?" buttons ¬
34		{"Cancel", "Add", "Remove"} default button 1
35		set addDeleteOverlay to the button returned of the result
36
37		tell the front document
38		set documentWidth to its width
39		set documentHeight to its height
40
41		if addDeleteOverlay is "Add" then
42		repeat with i from 1 to the count of slides
43		tell slide i
44		set thisTextItem to ¬
45		make new text item with properties {object text:textOverlayString}
46		tell thisTextItem
47		tell object text
48		set font to textOverlayTypeface
49		set size to textOverlayFontSize
50		set color of it to textOverlayRGBColorValues
51		end tell
52		set textItemWidth to its width
53		set textItemHeight to its height
54		set opacity to textOverlayOpacityValue
55		if textOverlayDefaultPosition is 0 then
56		-- center
57		set x to (documentWidth - textItemWidth) div 2
58		set y to (documentHeight - textItemHeight) div 2
59		else if textOverlayDefaultPosition is 1 then
60		-- top left
61		set x to textItemOverlayOffset
62		set y to textItemOverlayOffset
63		else if textOverlayDefaultPosition is 2 then
64		-- top right
65		set x to documentWidth - textItemWidth - textItemOverlayOffset
66		set y to textItemOverlayOffset
67		else if textOverlayDefaultPosition is 3 then
68		-- bottom left
69		set x to textItemOverlayOffset
70		set y to documentHeight - textItemHeight - textItemOverlayOffset
71		else if textOverlayDefaultPosition is 4 then
72		-- bottom right
73		set x to documentWidth - textItemWidth - textItemOverlayOffset
74		set y to documentHeight - textItemHeight - textItemOverlayOffset
75		end if
76		set position to {x, y}
77		end tell
78		end tell
79		end repeat
80		else
81		delete (every text item of every slide whose object text of it is textOverlayString)
82		end if
83		end tell
84		end tell