AppleScript and Keynote: Translation Helper Scripts

Translation Helper Scripts

Large international corporations often create sales and marketing materials that are replicated by their marketing and communications teams into publications designed for use with various languages.

But for smaller organizations or individuals, translating materials can be a challenging process. This tutorial features two Applescript scripts that will make is easier for you to translate a presentation’s presenter notes using the online Google Translate service.

NOTE: These scripts are compelling examples of how AppleScript can dynamically create and interact with HTML content via the Safari web-browser application.

DOWNLOAD an archive containing three scripts and the example presentation file. In the unpacked archive folder, launch the “Automation Tools Installer” applet to install the scripts.

Setup Presenter Notes for Translation

property sourceLanguageID : "en" -- (en=English, fr=French, es=Spanish, de=German, it=Italian, sv=Swedish, nl=Dutch)

property destinationLanguageID : "es"

property bodyStyleCSS : "margin-left:36px;-webkit-user-select:none;width:50%;background-color:#555;color:white;"

property slideIdentiferOpeningTag : "<h4 style=\"margin-bottom:4px;margin:0;\">"

property slideIdentiferClosingTag : "</h4>"

property noteOpeningTag : "<textarea rows=\"5\" id=\"txtareaXXXX\" onClick=\"SelectAll('txtareaXXXX');\">"

property noteClosingTag : "</textarea>"

property blankLineHTML : "<hr>"

property introductionOpeningTag : "<h3 style=\"margin-bottom:0;font-style:italic;\">"

property introductionClosingTag : "</h3>"

property documentTitleHTMLOpeningTag : "<h2 style=\"margin-left:24px;margin-bottom:12px;margin-top:8px;\">"

property documentTitleHTMLClosingTag : "</h2>"

property instructionsOpeningTag : "<p style=\"font-size:small;font-style:italic;\">"

property instructionsClosingTag : "</p>"

tell application "Keynote"

activate

if not (exists document 1) then error number -128

tell the front document

set thisDocumentName to the name of it

set the HTMLBody to ¬

introductionOpeningTag & "Presenter notes for:" & ¬

introductionClosingTag & linefeed & ¬

documentTitleHTMLOpeningTag & "“" & thisDocumentName & ¬

"”" & documentTitleHTMLClosingTag & linefeed & ¬

instructionsOpeningTag & "(Click the text of a presenter note to select it)" & ¬

instructionsClosingTag

repeat with i from 1 to the count of slides

tell slide i

if skipped is false then

set thisSlideNotes to its presenter notes

set thisSlideNotesHTML to thisSlideNotes

set thisnoteOpeningTag to my replaceText(noteOpeningTag, "XXXX", (i as string))

set the HTMLBody to ¬

HTMLBody & linefeed & ¬

blankLineHTML & linefeed & ¬

slideIdentiferOpeningTag & "Slide " & (i as string) & ¬

slideIdentiferClosingTag & linefeed & ¬

thisnoteOpeningTag & thisSlideNotesHTML & noteClosingTag

end if

end tell

end repeat

end tell

-- MERGE HTML CONTENT

set HTMLOutline to "<!DOCTYPE html>

<head>

<title>" & thisDocumentName & "</title>

function SelectAll(id)

{

document.getElementById(id).focus();

document.getElementById(id).select();

}

</script>

<style>

textarea {width:96%;}

</style>

</head>

<body style=\"" & bodyStyleCSS & "\">" & linefeed & HTMLBody & ¬

linefeed & "</body>" & linefeed & "</html>"

-- CREATE THE HTML FILE

set fileName to (do shell script "uuidgen") & ".html"

set temporaryFolder to (path to temporary items folder from user domain)

set targetFileHFSPath to (temporaryFolder as string) & fileName

if my writeToFile(HTMLOutline, targetFileHFSPath, false) is true then

tell application "System Events"

set thisURL to the URL of disk item targetFileHFSPath

end tell

else

beep

error number -128

end if

-- OPEN HTML FILE IN NEW 2-TAB WINDOW WITH GOOGLE TRANSLATE <https://translate.google.com/#en/es/>

set GoogleTranslateURL to ¬

"https://translate.google.com/#" & sourceLanguageID & ¬

"/" & destinationLanguageID & "/"

tell application "Safari"

activate

set thisWindow to make new document with properties {URL:thisURL}

tell window 1

make new tab with properties {URL:GoogleTranslateURL}

end tell

on writeToFile(thisData, targetFile, appendData)

100

try

101

set the targetFile to the targetFile as string

102

set the openTargetFile to ¬

103

open for access file targetFile with write permission

104

if appendData is false then set eof of the opentargetFile to 0

105

write thisData to the openTargetFile starting at eof as «class utf8»

106

close access the openTargetFile

107

return true

108

on error

109

try

110

close access file targetFile

111

end try

112

return false

113

end try

114

end writeToFile

115

116

on replaceText(sourceText, searchString, replacementString)

117

set AppleScript's text item delimiters to the searchString

118

set the itemList to every text item of sourceText

119

set AppleScript's text item delimiters to the replacementString

120

set sourceText to the itemList as string

121

set AppleScript's text item delimiters to ""

122

return sourceText

123

end replaceText

Running the Setup Script

With the installation of the scripts completed, and the presentation opened in Keynote, you are now ready to begin the process of translating the document’s presenter notes.

DO THIS ►Select the installed script “Setup Presenter Notes for Translation” from the system-wide Script Menu. A confirmation dialog will appear:

(⬇ see below ) The opening dialog of the “Setup Presenter Notes for Translation” script. Click the “Set Prefs” button to select the languages to be translated from and to.

When run, the script will open a new window in Safari containing two tabs:

(⬆ see above ) The new Safari browser window with two tabs: the current tab displaying the presenter notes of the frontmost presentation, and second tab displaying the Google Translate website.

(⬇ see below ) The second browser tab displaying the Google Translate website, with two text fields: the left for entering the text to be translated, and the right containing the translation of the source text.

Translating the Slide Notes

Translating the slide presenter notes involves following these simple steps for each slide note:

Select & Copy the Slide’s Notes • Select the text of a slide note by clicking in the text area of the note. The text will auto-select. Copy the selected text to the clipboard (⌘C).
Paste & Translate • In the browser window select the Google Translate tab, and paste the copied text into the text input field on the left. Click the Translate button over the right text field to translate the text.
Select, Copy, & Replace • Under the text field containing the translation, click the button for selecting the text. Copy the selected text to the clipboard (⌘C). Click the inactive browser window tab to reveal the slide notes, and replace the selected text of the source slide note with the translation text that’s currently on the clipboard (⌘V).

Repeat these steps for each slide note.

Replacing Existing Presenter Notes

Once the slide notes in the browser window have been replaced with their translations, they can be used to replace the presenter notes in the open Keynote presentation file. This process can be completed quickly using the script provided here.

DO THIS ►Select the installed script “Replace Notes with Localized Notes” from the system-wide Script Menu. A confirmation dialog will appear:

Replace Notes with Localized Notes

tell application "Keynote"

set KeynoteStatus to (exists document 1)

end tell

tell application "Safari"

activate

if KeynoteStatus is false then "There is no document in Keynote."

if not (exists document 1) then error "There is no document open in Safari."

display dialog "This script will replace the presenter notes in the current Keynote document with the notes from this webpage." with icon 1

try

set pageSource to source of current tab of window 1

if pageSource contains "Page Generated for Translation" then

set elementCount to ¬

(do JavaScript "document.getElementsByTagName('textarea').length;" in current tab of window 1) as integer

set translatedNotes to {}

repeat with i from 1 to elementCount

set thisNote to ¬

(do JavaScript "document.getElementById('txtarea" & (i as string) & "').value;" in current tab of window 1)

set the end of translatedNotes to thisNote

end repeat

else

display alert "INCORRECT PAGE" message "The current page was not generated by the translation script."

error number -128

end if

display dialog "Notes extraction complete. Click “Continue” to switch to Keynote and replace the notes in the current document." buttons {"Cancel", "Continue"} default button 2 with icon 1

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert "EXTRACTION ERROR" message errorMessage

end if

error number -128

end try

end tell

tell application "Keynote"

activate

try

tell document 1

repeat with i from 1 to the count of translatedNotes

set targetSlide to (the first slide whose slide number is i)

tell targetSlide

set presenter notes to (item i of translatedNotes)

end tell

end repeat

end tell

on error errorMessage number errorNumber

if errorNumber is not -128 then

display alert "ERROR" message errorMessage

end if

error number -128

end try

end tell

Once the script has finished, the presenter notes in the frontmost Keynote document will be replaced with the translations entered in the Safari browser tab.

TIP: You can use the Simple Play & Say script (included with the installer) to have your slideshow spoken and presented to you using the default system voice. Upgrade your system voices to the free high-quality voices in multiple languages available from the Speech & Dictation system preference pane.

TOP | CONTINUE

KEYNOTE SCRIPTING

Overview
Automation Utilities

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.