AppleScript and Numbers: Table with State Names as Headers

New Table with State Names as Headers

The following script is an example of how to use a defined set of header names as the row or column header for a new table. The user is prompted to choose row or column as the header orientation, and how many rows|columns to add below|to the right of the headers.

You can easily adapt this script to work with any set of headers, by replacing the list at the top of the script with the list of headers you want to use; and editing the prompt dialog to conform with the type of headers you’re using.

It provides examples of these techniques:

Interacting with the script user (9, 15, 19)
Building a table and populating it with data from a list (52-64)

Here’s the script:

New Table with State Names as Headers

set the headerTitles to {"Alabama", "Alaska", "Arizona", "Arkansas", "California", "Colorado", "Connecticut", "Delaware", "Florida", "Georgia", "Hawaii", "Idaho", "Illinois", "Indiana", "Iowa", "Kansas", "Kentucky", "Louisiana", "Maine", "Maryland", "Massachusetts", "Michigan", "Minnesota", "Mississippi", "Missouri", "Montana", "Nebraska", "Nevada", "New Hampshire", "New Jersey", "New Mexico", "New York", "North Carolina", "North Dakota", "Ohio", "Oklahoma", "Oregon", "Pennsylvania", "Rhode Island", "South Carolina", "South Dakota", "Tennessee", "Texas", "Utah", "Vermont", "Virginia", "Washington", "West Virginia", "Wisconsin", "Wyoming"}

tell application "Numbers"

activate

-- NOTE: This script assumes the use of 1 row header and 1 column header

-- prompt the user for whether the header titles are to used as row or column headers

display dialog "Use the state names as column headers or row headers?" buttons ¬

{"Cancel", "Row Headers", "Column Headers"}

set the userChoice to the button returned of the result

if the userChoice is "Row Headers" then

-- add one for the header

set rowCount to (length of the headerTitles) + 1

set the dialogMessage to "Enter the number of columns to add:"

else

-- add one for the header

set columnCount to (length of the headerTitles) + 1

set the dialogMessage to "Enter the number of rows to add:"

end if

-- prompt for the number of rows or columns to add

repeat

try

display dialog dialogMessage default answer "3"

set the elementCount to the text returned of the result as integer

if the elementCount is greater than 0 then

if the userChoice is "Row Headers" then

-- add one for the header

set columnCount to elementCount + 1

else

-- add one for the header

set rowCount to elementCount + 1

end if

exit repeat

end if

on error number errorNumber

if errorNumber is -128 then error number -128

end try

end repeat

-- build and populate the table

tell the front document

tell the active sheet

set thisTable to ¬

make new table with properties ¬

{row count:rowCount, column count:columnCount}

tell thisTable

if the userChoice is "Row Headers" then

repeat with i from 1 to the count of the headerTitles

set thisHeaderTitle to item i of the headerTitles

set the value of cell 1 of row (i + 1) to thisHeaderTitle

end repeat

else

repeat with i from 1 to the count of the headerTitles

set thisHeaderTitle to item i of the headerTitles

set the value of cell 1 of column (i + 1) to thisHeaderTitle

end repeat

set the alignment of row 1 to center

end if

end tell

TOP | CONTINUE

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.