Here’s an example AppleScript script that transforms the selected row data in a Numbers table to a vertical bar chart on a new slide in Keynote.

DO THIS ► DOWNLOAD the simple example Numbers document.

Simply select one or more rows in a Numbers table and run the script. The row data will be extracted and used to create a vertical bar chart on a new slide in the frontmost Keynote document. In addition, the name of the selected table will be used as the title for the created slide.

New Bar Chart in Keynote using Data From Selected Rows
Open in AppleScript Editor
01		tell application "Numbers"
02		activate
03		try
04		-- check for document
05		if not (exists document 1) then error number 1000
06		tell document 1
07		try -- check for selected table
08		tell active sheet
09		set the selectedTable to ¬
10		(the first table whose class of selection range is range)
11		end tell
12		on error
13		error number 1001
14		end try
15		tell selectedTable
16		set thisTableName to its name
17		-- get the count fo the various headers and footers
18		set the headercolumnCount to header column count
19		set the headerrowCount to header row count
20		set the footerrowCount to footer row count
21		-- store references to the intersecting columns and rows
22		set theseRows to the rows of the selection range
23		set theseColumns to the columns of the selection range
24		-- get the row and column counts
25		set rowCount to (count of theseRows)
26		set columnCount to (count of theseColumns)
27		-- get the column names
28		set columnNames to {}
29		if headercolumnCount is 1 then
30		repeat with i from 1 to the count of theseColumns
31		set thisValue to (the value of the first cell of (item i of theseColumns))
32		if thisValue is not missing value then
33		set the end of columnNames to thisValue
34		end if
35		end repeat
36		else -- use the Column IDs
37		repeat with i from 1 to the count of theseColumns
38		set thisValue to the name of (item i of theseColumns)
39		if thisValue is not missing value then
40		set the end of columnNames to thisValue
41		end if
42		end repeat
43		end if
44		-- get the row names
45		set rowNames to {}
46		if headerrowCount is 1 then
47		repeat with i from 1 to the count of theseRows
48		set thisValue to (the value of the first cell of (item i of theseRows))
49		if thisValue is not missing value then
50		set the end of rowNames to thisValue
51		end if
52		end repeat
53		else -- use row IDs
54		repeat with i from 1 to the count of theseRows
55		set thisValue to the name of (item i of theseRows)
56		if thisValue is not missing value then
57		set the end of rowNames to thisValue
58		end if
59		end repeat
60		end if
61		end tell
62
63		set dataSets to {}
64		repeat with i from 1 to rowCount
65		set thisRow to item i of theseRows
66		set thisDataSet to ¬
67		(the value of cells (headerrowCount + 1) thru -1 of thisRow)
68		set the end of the dataSets to thisDataSet
69		end repeat
70		end tell
71		on error errorMessage number errorNumber
72		if errorNumber is 1000 then
73		set alertString to "MISSING RESOURCE"
74		set errorMessage to ¬
75		"Please create or open a document before running this script."
76		else if errorNumber is 1001 then
77		set alertString to "SELECTION ERROR"
78		set errorMessage to "Please select a table before running this script."
79		else
80		set alertString to "EXECUTION ERROR"
81		end if
82		if errorNumber is not -128 then
83		display alert alertString message errorMessage buttons {"Cancel"}
84		end if
85		error number -128
86		end try
87		end tell
88
89		tell application "Keynote"
90		activate
91		try
92		if not (exists document 1) then make new document
93		tell the front document
94		set thisSlide to ¬
95		make new slide at after (get current slide) with properties ¬
96		{base slide:master slide "Title - Top"}
97		tell thisSlide
98		set slideTitle to thisTableName
99		set the object text of the default title item to slideTitle
100		add chart row names rowNames column names columnNames ¬
101		data dataSets type vertical_bar_2d group by chart column
102		end tell
103		end tell
104		on error errorMessage number errorNumber
105		if errorNumber is not -128 then
106		display alert alertString message errorMessage buttons {"Cancel"}
107		end if
108		end try
109		end tell